source: rfc2629xslt/clean-for-DTD.xslt @ 832

Last change on this file since 832 was 814, checked in by julian.reschke@…, 10 years ago

latest version of rfc2629.xslt, bump up document dates

  • Property svn:eol-style set to native
File size: 22.9 KB
Line 
1<!--
2    Strip rfc2629.xslt extensions, generating XML input for MTR's xml2rfc
3
4    Copyright (c) 2006-2010, Julian Reschke (julian.reschke@greenbytes.de)
5    All rights reserved.
6
7    Redistribution and use in source and binary forms, with or without
8    modification, are permitted provided that the following conditions are met:
9
10    * Redistributions of source code must retain the above copyright notice,
11      this list of conditions and the following disclaimer.
12    * Redistributions in binary form must reproduce the above copyright notice,
13      this list of conditions and the following disclaimer in the documentation
14      and/or other materials provided with the distribution.
15    * Neither the name of Julian Reschke nor the names of its contributors
16      may be used to endorse or promote products derived from this software
17      without specific prior written permission.
18
19    THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
20    AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
21    IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
22    ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR CONTRIBUTORS BE
23    LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
24    CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
25    SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
26    INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
27    CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
28    ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
29    POSSIBILITY OF SUCH DAMAGE.
30-->
31
32<xsl:transform xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
33                version="1.0"
34                xmlns:ed="http://greenbytes.de/2002/rfcedit"
35                xmlns:grddl="http://www.w3.org/2003/g/data-view#"
36                xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#"
37                xmlns:x="http://purl.org/net/xml2rfc/ext"
38                xmlns:xhtml="http://www.w3.org/1999/xhtml"
39                exclude-result-prefixes="ed grddl rdf x xhtml"
40>
41
42<!-- re-use some of the default RFC2629.xslt rules -->
43<xsl:import href="rfc2629.xslt"/>
44
45<!-- undo strip-space decls -->
46<xsl:preserve-space elements="*"/>
47
48<!-- generate DTD-valid output, override all values imported from rfc2629.xslt -->
49<xsl:output doctype-system="rfc2629.dtd" doctype-public="" method="xml" version="1.0" encoding="UTF-8" cdata-section-elements="artwork" />
50
51<!-- kick into cleanup mode -->
52<xsl:template match="/">
53  <xsl:text>&#10;</xsl:text>
54  <xsl:comment>
55    This XML document is the output of clean-for-DTD.xslt; a tool that strips
56    extensions to RFC2629(bis) from documents for processing with xml2rfc.
57</xsl:comment>
58  <xsl:apply-templates select="/" mode="cleanup"/>
59</xsl:template>
60
61<!-- rules for identity transformations -->
62
63<xsl:template match="processing-instruction()" mode="cleanup">
64  <xsl:text>&#10;</xsl:text>
65  <xsl:copy/>
66</xsl:template>
67
68<xsl:template match="comment()|@*" mode="cleanup"><xsl:copy/></xsl:template>
69
70<xsl:template match="text()" mode="cleanup"><xsl:copy/></xsl:template>
71
72<xsl:template match="/" mode="cleanup">
73        <xsl:copy><xsl:apply-templates select="node()" mode="cleanup" /></xsl:copy>
74</xsl:template>
75
76<xsl:template match="*" mode="cleanup">
77  <xsl:element name="{local-name()}">
78        <xsl:apply-templates select="node()|@*" mode="cleanup" />
79  </xsl:element>
80</xsl:template>
81
82
83<!-- remove PI extensions -->
84
85<xsl:template match="processing-instruction('rfc-ext')" mode="cleanup"/>
86<xsl:template match="processing-instruction('BEGININC')" mode="cleanup"/>
87<xsl:template match="processing-instruction('ENDINC')" mode="cleanup"/>
88
89<!-- add issues appendix -->
90
91<xsl:template match="back" mode="cleanup">
92  <back>
93    <xsl:apply-templates select="node()|@*" mode="cleanup" />
94    <xsl:if test="not(/*/@ed:suppress-issue-appendix='yes') and //ed:issue[@status='closed']">
95      <section title="Resolved issues (to be removed by RFC Editor before publication)">
96        <t>
97          Issues that were either rejected or resolved in this version of this
98          document.
99        </t>
100        <xsl:apply-templates select="//ed:issue[@status='closed']" mode="issues" />
101      </section>
102    </xsl:if>
103    <xsl:if test="not(/*/@ed:suppress-issue-appendix='yes') and //ed:issue[@status='open']">
104      <section title="Open issues (to be removed by RFC Editor prior to publication)">
105        <xsl:apply-templates select="//ed:issue[@status!='closed']" mode="issues" />
106      </section>
107    </xsl:if>
108  </back>
109</xsl:template>
110
111
112
113
114<!-- extensions -->
115
116<xsl:template match="x:abnf-char-sequence" mode="cleanup">
117  <xsl:choose>
118    <xsl:when test="substring(.,1,1) != '&quot;' or substring(.,string-length(.),1) != '&quot;'">
119      <xsl:call-template name="error">
120        <xsl:with-param name="msg" select="'contents of x:abnf-char-sequence needs to be quoted.'" />
121      </xsl:call-template>
122    </xsl:when>
123    <xsl:otherwise>
124      <xsl:text>%x</xsl:text>
125      <xsl:call-template name="to-abnf-char-sequence">
126        <xsl:with-param name="chars" select="substring(.,2,string-length(.)-2)"/>
127      </xsl:call-template>
128    </xsl:otherwise>
129  </xsl:choose>
130</xsl:template>
131
132<xsl:template match="x:anchor-alias" mode="cleanup"/>
133
134<xsl:template match="x:bcp14" mode="cleanup">
135  <xsl:apply-templates/>
136</xsl:template>
137
138<xsl:template match="x:assign-section-number" mode="cleanup"/> 
139<xsl:template match="x:link" mode="cleanup"/>
140<xsl:template match="x:source" mode="cleanup"/>
141
142<xsl:template match="x:parse-xml" mode="cleanup">
143  <xsl:apply-templates/>
144</xsl:template>
145
146<xsl:template match="x:ref" mode="cleanup">
147  <xsl:variable name="val" select="."/>
148  <xsl:variable name="target" select="//*[@anchor and (@anchor=$val or x:anchor-alias/@value=$val)][not(ancestor::ed:del)]"/>
149  <xsl:choose>
150    <xsl:when test="$target">
151      <xsl:if test="count($target)!=1">
152        <xsl:message terminate="yes">FATAL: multiple x:ref targets found for <xsl:value-of select="$val"/>.</xsl:message>
153      </xsl:if>
154      <xsl:variable name="current" select="."/>
155      <xsl:for-each select="$target">
156        <!-- make it the context -->
157        <xsl:choose>
158          <xsl:when test="self::preamble">
159            <!-- it's not an element we can link to -->
160            <xsl:call-template name="warning">
161              <xsl:with-param name="inline" select="'no'"/>
162              <xsl:with-param name="msg">couldn't create the link as <xsl:value-of select="name()"/> does not support the anchor attribute.</xsl:with-param>
163            </xsl:call-template>
164            <xsl:value-of select="$current"/>
165          </xsl:when>
166          <xsl:otherwise>
167            <xref target="{$target/@anchor}" format="none"><xsl:value-of select="$current"/></xref>
168          </xsl:otherwise>
169        </xsl:choose>
170      </xsl:for-each>
171    </xsl:when>
172    <xsl:otherwise>
173      <xsl:call-template name="warning">
174        <xsl:with-param name="inline" select="'no'"/>
175        <xsl:with-param name="msg">internal link target for '<xsl:value-of select="."/>' does not exist.</xsl:with-param>
176      </xsl:call-template>
177      <xsl:value-of select="."/>
178    </xsl:otherwise>
179  </xsl:choose>
180</xsl:template>
181
182<xsl:template match="x:blockquote" mode="cleanup">
183  <t><list>
184    <xsl:apply-templates mode="cleanup" />
185  </list></t>
186</xsl:template>
187
188<xsl:template match="x:h" mode="cleanup">
189  <xsl:apply-templates mode="cleanup" />
190</xsl:template>
191
192<xsl:template match="x:highlight" mode="cleanup">
193  <xsl:apply-templates mode="cleanup" />
194</xsl:template>
195
196<xsl:template match="x:lt" mode="cleanup">
197  <t>
198    <xsl:apply-templates select="@hangText|@anchor" mode="cleanup"/>
199    <xsl:for-each select="t">
200      <xsl:apply-templates mode="cleanup"/>
201      <xsl:if test="position()!=last()">
202        <vspace blankLines="1"/>
203      </xsl:if>
204    </xsl:for-each>
205  </t>
206</xsl:template>
207
208<xsl:template match="x:note" mode="cleanup">
209  <t>
210    <list>
211      <xsl:apply-templates mode="cleanup"/>
212    </list>
213  </t>
214</xsl:template>
215
216<xsl:template match="x:q" mode="cleanup">
217  <xsl:text>"</xsl:text>
218  <xsl:apply-templates mode="cleanup"/>
219  <xsl:text>"</xsl:text>
220</xsl:template>
221
222<xsl:template match="x:dfn" mode="cleanup">
223  <!-- help xml2rfc to keep dfn and following text on the same page -->
224  <xsl:if test="not(preceding-sibling::x:dfn) and count(following-sibling::list)=1">
225    <xsl:processing-instruction name="rfc">needLines="4"</xsl:processing-instruction>
226  </xsl:if>
227  <xsl:apply-templates mode="cleanup"/>
228</xsl:template>
229
230<xsl:template match="x:sup" mode="cleanup">
231  <xsl:text>^</xsl:text>
232  <xsl:apply-templates mode="cleanup" />
233</xsl:template>
234
235<xsl:template match="x:span" mode="cleanup">
236  <xsl:apply-templates mode="cleanup" />
237</xsl:template>
238<xsl:template match="x:span/@anchor" mode="cleanup"/>
239
240<xsl:template match="author/@anchor" mode="cleanup"/>
241<xsl:template match="x:include-author" mode="cleanup">
242  <t>
243    <xsl:value-of select="/*/front/author[@anchor=current()/@target]"/>
244  </t>
245  <t>
246    (see Authors Section)
247  </t>
248</xsl:template>
249
250<!-- extended reference formatting -->
251
252<xsl:template match="xref[(@x:fmt or @x:sec or @x:rel) and not(node())]" mode="cleanup">
253  <xsl:call-template name="insert-iref-for-xref"/>
254  <xsl:variable name="node" select="$src//*[@anchor=current()/@target]" />
255
256  <xsl:variable name="sec">
257    <xsl:choose>
258      <xsl:when test="starts-with(@x:rel,'#') and not(@x:sec) and $node/x:source/@href">
259        <xsl:variable name="extdoc" select="document($node/x:source/@href)"/>
260        <xsl:for-each select="$extdoc//*[@anchor=substring-after(current()/@x:rel,'#')]">
261          <xsl:call-template name="get-section-number"/>
262        </xsl:for-each>
263      </xsl:when>
264      <xsl:otherwise>
265        <xsl:value-of select="@x:sec"/>
266      </xsl:otherwise>
267    </xsl:choose>
268  </xsl:variable>
269
270  <xsl:variable name="secterm">
271    <xsl:choose>
272      <!-- starts with letter? -->
273      <xsl:when test="translate(substring($sec,1,1),$ucase,'')=''">Appendix</xsl:when>
274      <xsl:otherwise>Section</xsl:otherwise>
275    </xsl:choose>
276  </xsl:variable>
277
278  <xsl:variable name="fmt">
279    <xsl:choose>
280      <xsl:when test="@x:fmt!=''"><xsl:value-of select="@x:fmt"/></xsl:when>
281      <xsl:when test="ancestor::artwork">,</xsl:when>
282      <xsl:otherwise>of</xsl:otherwise>
283    </xsl:choose>
284  </xsl:variable>
285
286  <xsl:choose>
287    <xsl:when test="$fmt=','">
288      <xref>
289        <xsl:apply-templates select="@target|@format|@pageno|text()|*" mode="cleanup"/>
290      </xref>
291      <xsl:text>, </xsl:text>
292      <xsl:value-of select="$secterm"/>
293      <xsl:text> </xsl:text>
294      <xsl:value-of select="$sec"/>
295    </xsl:when>
296    <xsl:when test="$fmt='sec'">
297      <xsl:value-of select="$secterm"/>
298      <xsl:text> </xsl:text>
299      <xsl:value-of select="$sec"/>
300    </xsl:when>
301    <xsl:when test="$fmt='number'">
302      <xsl:value-of select="$sec"/>
303    </xsl:when>
304    <xsl:when test="$fmt='()'">
305      <xref>
306        <xsl:apply-templates select="@target|@format|@pageno|text()|*" mode="cleanup"/>
307      </xref>
308      <xsl:text> (</xsl:text>
309      <xsl:value-of select="$secterm"/>
310      <xsl:text> </xsl:text>
311      <xsl:value-of select="$sec"/>
312      <xsl:text>)</xsl:text>
313    </xsl:when>
314    <xsl:when test="$fmt='of'">
315      <xsl:value-of select="$secterm"/>
316      <xsl:text> </xsl:text>
317      <xsl:value-of select="$sec"/>
318      <xsl:text> of </xsl:text>
319      <xref>
320        <xsl:apply-templates select="@target|@format|@pageno|text()|*" mode="cleanup"/>
321      </xref>
322    </xsl:when>
323    <xsl:when test="$fmt='anchor'">
324      <xsl:variable name="val">
325        <xsl:call-template name="referencename">
326          <xsl:with-param name="node" select="$node" />
327        </xsl:call-template>
328      </xsl:variable>
329      <!-- remove brackets -->
330      <xsl:value-of select="substring($val,2,string-length($val)-2)"/>
331    </xsl:when>
332    <xsl:otherwise>
333      <xsl:copy>
334        <xsl:apply-templates select="node()" mode="cleanup"/>
335      </xsl:copy>
336    </xsl:otherwise>
337  </xsl:choose>
338</xsl:template>
339
340<xsl:template match="xref[(@x:fmt or @x:sec or @x:rel) and node()]" mode="cleanup">
341  <xsl:call-template name="insert-iref-for-xref"/>
342  <xsl:choose>
343    <xsl:when test="@x:fmt='none'">
344      <xsl:apply-templates mode="cleanup"/>
345    </xsl:when>
346    <xsl:when test="not(@x:fmt)">
347      <xref>
348        <xsl:copy-of select="@target|@format"/>
349        <xsl:apply-templates mode="cleanup"/>
350      </xref>
351    </xsl:when>
352    <xsl:otherwise>
353      <xsl:message>Unsupported x:fmt attribute.</xsl:message>
354    </xsl:otherwise>
355  </xsl:choose>
356</xsl:template>
357
358<xsl:template match="xref[node() and (@target=//preamble/@anchor or @target=//spanx/@anchor)]" mode="cleanup">
359  <!-- remove the link -->
360  <xsl:apply-templates select="node()" mode="cleanup"/>
361</xsl:template>
362
363<xsl:template match="xref[not(node()) and (@target=//preamble/@anchor or @target=//spanx/@anchor)]" mode="cleanup">
364  <!-- fatal -->
365  <xsl:message terminate="yes">Broken xref <xsl:value-of select="@target"/> due to target being filtered out.</xsl:message>
366</xsl:template>
367
368<xsl:template match="xref" mode="cleanup" priority="0">
369  <xsl:call-template name="insert-iref-for-xref"/>
370  <xref>
371    <xsl:copy-of select="@target|@format"/>
372    <xsl:apply-templates mode="cleanup"/>
373  </xref>
374</xsl:template>
375
376<xsl:template name="insert-iref-for-xref">
377  <xsl:if test="$xml2rfc-ext-include-references-in-index='yesxxx'">
378    <xsl:if test="@target=/rfc/back//reference/@anchor">
379      <iref item="{@target}"/>
380      <xsl:if test="@x:sec">
381        <xsl:choose>
382          <xsl:when test="translate(substring(@x:sec,1,1),$ucase,'')=''">
383            <iref item="{@target}" subitem="Appendix {@x:sec}"/>
384          </xsl:when>
385          <xsl:otherwise>
386            <iref item="{@target}" subitem="Section {@x:sec}"/>
387          </xsl:otherwise>
388        </xsl:choose>
389      </xsl:if>
390    </xsl:if>
391  </xsl:if>
392</xsl:template>
393
394<!-- issue tracking extensions -->
395
396<xsl:template match="@xml:lang" mode="cleanup"/>
397<xsl:template match="@xml:lang" />
398
399<xsl:template match="ed:*" mode="cleanup"/>
400<xsl:template match="ed:*" />
401
402<xsl:template match="@ed:*" mode="cleanup"/>
403<xsl:template match="@ed:*" />
404
405<xsl:template match="ed:annotation" mode="cleanup" />
406
407<xsl:template match="ed:replace" mode="cleanup">
408  <xsl:apply-templates mode="cleanup" />
409</xsl:template>
410
411<xsl:template match="ed:replace">
412  <xsl:apply-templates/>
413</xsl:template>
414
415<xsl:template match="ed:ins" mode="cleanup">
416  <xsl:apply-templates mode="cleanup"/>
417</xsl:template>
418
419<xsl:template match="ed:ins">
420  <xsl:apply-templates/>
421</xsl:template>
422
423<xsl:template match="ed:issue" mode="issues">
424  <section title="{@name}">
425    <xsl:variable name="sec">
426      <xsl:call-template name="get-section-number"/>
427    </xsl:variable>
428
429    <xsl:if test="$sec!=''">
430      <t>
431        In Section <xsl:value-of select="$sec"/>:
432      </t>
433    </xsl:if>
434   
435    <t>
436      Type: <xsl:value-of select="@type" />
437    </t>
438    <xsl:if test="@href">
439      <t>
440        <!-- temp. removed because of xml2rfc's handling of erefs when producing TXT-->
441        <!--<eref target="{@href}" /> -->
442        <xsl:text>&lt;</xsl:text>
443        <xsl:value-of select="@href"/>
444        <xsl:text>></xsl:text>
445        <xsl:if test="@alternate-href">
446          <xsl:text>, &lt;</xsl:text>
447          <xsl:value-of select="@alternate-href"/>
448          <xsl:text>></xsl:text>
449        </xsl:if>
450      </t>
451    </xsl:if>
452    <xsl:for-each select="ed:item">
453      <t>
454        <xsl:if test="@entered-by or @date">
455          <xsl:choose>
456            <xsl:when test="not(@entered-by)">
457              <xsl:value-of select="concat('(',@date,') ')" />
458            </xsl:when>
459            <xsl:when test="not(@date)">
460              <xsl:value-of select="concat(@entered-by,': ')" />
461            </xsl:when>
462            <xsl:otherwise>
463              <xsl:value-of select="concat(@entered-by,' (',@date,'): ')" />
464            </xsl:otherwise>
465          </xsl:choose>     
466        </xsl:if>
467        <xsl:if test="not(xhtml:p)">
468          <xsl:apply-templates select="node()" mode="issues"/>
469        </xsl:if>
470      </t>
471      <xsl:if test="xhtml:p|xhtml:pre">
472        <xsl:for-each select="node()">
473          <xsl:choose>
474            <xsl:when test="self::xhtml:p">
475              <t>
476                <xsl:apply-templates select="node()" mode="issues"/>
477              </t>
478            </xsl:when>
479            <xsl:when test="self::xhtml:pre">
480              <figure>
481                <artwork><xsl:apply-templates select="node()" mode="issues"/></artwork>
482              </figure>
483            </xsl:when>
484            <xsl:otherwise>
485              <t>
486                <xsl:apply-templates select="." mode="issues"/>
487              </t>
488            </xsl:otherwise>
489          </xsl:choose>
490        </xsl:for-each>
491      </xsl:if>
492    </xsl:for-each> 
493    <xsl:if test="ed:resolution">
494      <t>
495        <xsl:text>Resolution</xsl:text>
496        <xsl:if test="ed:resolution/@datetime"> (<xsl:value-of select="ed:resolution/@datetime"/>)</xsl:if>
497        <xsl:text>: </xsl:text>
498        <xsl:value-of select="ed:resolution" />
499      </t>
500    </xsl:if>
501  </section>
502</xsl:template>
503
504<xsl:template match="ed:issueref" mode="cleanup">
505  <xsl:apply-templates mode="cleanup"/>
506</xsl:template>
507
508<xsl:template match="*" mode="issues">
509  <xsl:apply-templates mode="issues"/>
510</xsl:template>
511
512<xsl:template match="xhtml:q" mode="issues">
513  <list><t>
514    <xsl:text>"</xsl:text>
515    <xsl:apply-templates mode="issues"/>
516    <xsl:text>"</xsl:text>
517    <xsl:if test="@cite">
518      <xsl:text> -- </xsl:text>
519      <eref target="{@cite}"><xsl:value-of select="@cite"/></eref>
520    </xsl:if>
521  </t></list>
522</xsl:template>
523
524<xsl:template match="xhtml:br" mode="issues">
525  <vspace/>
526</xsl:template>
527
528<xsl:template match="xhtml:del" mode="issues">
529  <xsl:text>&lt;del></xsl:text>
530    <xsl:apply-templates mode="issues"/>
531  <xsl:text>&lt;/del></xsl:text>
532</xsl:template>
533
534<xsl:template match="xhtml:em" mode="issues">
535  <spanx style="emph">
536    <xsl:apply-templates mode="issues"/>
537  </spanx>
538</xsl:template>
539
540<xsl:template match="xhtml:ins" mode="issues">
541  <xsl:text>&lt;ins></xsl:text>
542    <xsl:apply-templates mode="issues"/>
543  <xsl:text>&lt;/ins></xsl:text>
544</xsl:template>
545
546<xsl:template match="xhtml:tt" mode="issues">
547  <xsl:apply-templates mode="issues"/>
548</xsl:template>
549
550<xsl:template match="ed:eref" mode="issues">
551  <xsl:text>&lt;</xsl:text>
552  <xsl:value-of select="."/>
553  <xsl:text>&gt;</xsl:text>
554</xsl:template>
555
556<xsl:template match="ed:issueref" mode="issues">
557  <xsl:apply-templates mode="issues"/>
558</xsl:template>
559
560<xsl:template match="text()" mode="issues">
561  <xsl:value-of select="." />
562</xsl:template>
563
564
565
566<!-- markup inside artwork element -->
567
568<xsl:template match="figure[.//artwork//iref | .//artwork//xref]" mode="cleanup">
569  <!-- move up iref elements -->
570  <xsl:for-each select=".//artwork//xref">
571    <xsl:if test="not(ancestor::ed:del)">
572      <xsl:call-template name="insert-iref-for-xref"/>
573    </xsl:if>
574  </xsl:for-each>
575  <figure>
576    <xsl:apply-templates select="@*" mode="cleanup" />
577    <xsl:apply-templates select=".//artwork//iref" mode="cleanup"/>
578    <xsl:apply-templates select="iref|preamble|artwork|postamble|ed:replace|ed:ins|ed:del" mode="cleanup" />
579  </figure>
580</xsl:template>
581
582<xsl:template name="insert-begin-code"/>
583<xsl:template name="insert-end-code"/>
584<xsl:template match="@x:isCodeComponent" mode="cleanup"/>
585
586<xsl:template match="artwork" mode="cleanup">
587  <xsl:variable name="content2"><xsl:apply-templates select="."/></xsl:variable>
588  <xsl:variable name="content" select="translate($content2,'&#160;&#x2500;&#x2502;&#x2508;&#x250c;&#x2510;&#x2514;&#x2518;&#x251c;&#x2524;',' -|+++++++')"/>
589  <artwork>
590    <xsl:apply-templates select="@*" mode="cleanup" />
591    <xsl:if test="@x:isCodeComponent='yes'">
592      <xsl:if test="starts-with(.,'&#10;')">
593        <xsl:text>&#10;</xsl:text>
594      </xsl:if>
595      <xsl:value-of select="@x:indent-with"/>
596      <xsl:text>&lt;CODE BEGINS&gt;&#10;</xsl:text>
597    </xsl:if>
598    <xsl:if test="starts-with(.,'&#10;')">
599      <xsl:text>&#10;</xsl:text>
600      <xsl:value-of select="@x:indent-with"/>
601    </xsl:if>
602    <xsl:choose>
603      <xsl:when test="@x:indent-with!=''">
604        <xsl:call-template name="indent">
605          <xsl:with-param name="content" select="$content"/>
606          <xsl:with-param name="with" select="@x:indent-with"/>
607        </xsl:call-template>
608      </xsl:when>
609      <xsl:otherwise>
610        <xsl:value-of select="$content"/>
611      </xsl:otherwise>
612    </xsl:choose>
613    <xsl:if test="@x:isCodeComponent='yes'">&#10;&lt;CODE ENDS&gt;&#10;</xsl:if>
614  </artwork> 
615</xsl:template>
616
617<xsl:template match="@x:indent-with" mode="cleanup"/>
618
619<xsl:template name="indent">
620  <xsl:param name="content"/>
621  <xsl:param name="with"/>
622
623  <xsl:value-of select="substring($content,1,1)"/>
624  <xsl:if test="substring($content,1,1)='&#10;'">
625    <xsl:value-of select="$with"/>
626  </xsl:if>
627 
628  <xsl:choose>
629    <xsl:when test="$content=''" />
630    <xsl:otherwise>
631      <xsl:call-template name="indent">
632        <xsl:with-param name="content" select="substring($content,2)"/>
633        <xsl:with-param name="with" select="$with"/>
634      </xsl:call-template>
635    </xsl:otherwise>
636  </xsl:choose>
637 
638</xsl:template>
639
640<!-- email repetitions -->
641<xsl:template match="email" mode="cleanup">
642  <!-- combine in a single element -->
643  <xsl:if test="not(preceding-sibling::email)">
644    <email>
645      <xsl:for-each select="../email">
646        <xsl:value-of select="."/>
647        <xsl:if test="position()!=last()">
648          <xsl:text>, </xsl:text>
649        </xsl:if>
650      </xsl:for-each>
651    </email>
652  </xsl:if>
653</xsl:template>
654
655<!-- markup inside cref -->
656<xsl:template match="cref//eref" mode="cleanup">
657  <xsl:text>&lt;</xsl:text>
658  <xsl:value-of select="@target"/>
659  <xsl:text>&gt;</xsl:text>
660</xsl:template>
661
662<xsl:template match="cref//xref" mode="cleanup" priority="9">
663  <xsl:variable name="text">
664    <xsl:apply-templates select="."/>
665  </xsl:variable>
666  <xsl:value-of select="$text"/>
667</xsl:template>
668
669<!-- annotations -->
670<xsl:template match="@x:annotation" mode="cleanup">
671  <xsl:comment>
672    <xsl:value-of select="."/>
673  </xsl:comment>
674  <xsl:call-template name="warning">
675    <xsl:with-param name="inline" select="'no'"/>
676    <xsl:with-param name="msg">Dropping annotation on <xsl:value-of select="local-name(..)"/> element.</xsl:with-param>
677  </xsl:call-template>
678</xsl:template>
679
680<!-- artwork extensions -->
681<xsl:template match="artwork/@x:extraction-note" mode="cleanup"/>
682
683<!-- list formatting -->
684<xsl:template match="list/@x:indent" mode="cleanup"/>
685
686<!-- referencing extensions -->
687<xsl:template match="iref/@x:for-anchor" mode="cleanup"/>
688
689<!-- table styles -->
690<xsl:template match="texttable/@style" mode="cleanup"/>
691
692<!-- section numbering -->
693<xsl:template match="section/@x:fixed-section-number" mode="cleanup"/>
694
695<!-- GRRDL info stripped -->
696<xsl:template match="@grddl:transformation" mode="cleanup"/>
697
698<!-- maturity level stripped -->
699<xsl:template match="@x:maturity-level" mode="cleanup"/>
700
701<!-- normativity stripped -->
702<xsl:template match="@x:nrm" mode="cleanup"/>
703
704<!-- RDF info stripped -->
705<xsl:template match="rdf:*" mode="cleanup"/>
706
707<!-- cases where xml2rfc does not allow anchors -->
708<xsl:template match="preamble/@anchor" mode="cleanup"/>
709<xsl:template match="spanx/@anchor" mode="cleanup"/>
710
711</xsl:transform>
Note: See TracBrowser for help on using the repository browser.