source: rfc2629xslt/clean-for-DTD.xslt @ 799

Last change on this file since 799 was 799, checked in by julian.reschke@…, 10 years ago

latest versions of rfc2629.xslt and xml2rfc.tcl, bump up document dates

  • Property svn:eol-style set to native
File size: 22.7 KB
Line 
1<!--
2    Strip rfc2629.xslt extensions, generating XML input for MTR's xml2rfc
3
4    Copyright (c) 2006-2010, Julian Reschke (julian.reschke@greenbytes.de)
5    All rights reserved.
6
7    Redistribution and use in source and binary forms, with or without
8    modification, are permitted provided that the following conditions are met:
9
10    * Redistributions of source code must retain the above copyright notice,
11      this list of conditions and the following disclaimer.
12    * Redistributions in binary form must reproduce the above copyright notice,
13      this list of conditions and the following disclaimer in the documentation
14      and/or other materials provided with the distribution.
15    * Neither the name of Julian Reschke nor the names of its contributors
16      may be used to endorse or promote products derived from this software
17      without specific prior written permission.
18
19    THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
20    AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
21    IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
22    ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR CONTRIBUTORS BE
23    LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
24    CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
25    SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
26    INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
27    CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
28    ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
29    POSSIBILITY OF SUCH DAMAGE.
30-->
31
32<xsl:transform xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
33                version="1.0"
34                xmlns:ed="http://greenbytes.de/2002/rfcedit"
35                xmlns:grddl="http://www.w3.org/2003/g/data-view#"
36                xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#"
37                xmlns:x="http://purl.org/net/xml2rfc/ext"
38                xmlns:xhtml="http://www.w3.org/1999/xhtml"
39                exclude-result-prefixes="ed grddl rdf x xhtml"
40>
41
42<!-- re-use some of the default RFC2629.xslt rules -->
43<xsl:import href="rfc2629.xslt"/>
44
45<!-- undo strip-space decls -->
46<xsl:preserve-space elements="*"/>
47
48<!-- generate DTD-valid output, override all values imported from rfc2629.xslt -->
49<xsl:output doctype-system="rfc2629.dtd" doctype-public="" method="xml" version="1.0" encoding="UTF-8" cdata-section-elements="artwork" />
50
51<!-- kick into cleanup mode -->
52<xsl:template match="/">
53  <xsl:text>&#10;</xsl:text>
54  <xsl:comment>
55    This XML document is the output of clean-for-DTD.xslt; a tool that strips
56    extensions to RFC2629(bis) from documents for processing with xml2rfc.
57</xsl:comment>
58  <xsl:apply-templates select="/" mode="cleanup"/>
59</xsl:template>
60
61<!-- rules for identity transformations -->
62
63<xsl:template match="processing-instruction()" mode="cleanup">
64  <xsl:text>&#10;</xsl:text>
65  <xsl:copy/>
66</xsl:template>
67
68<xsl:template match="comment()|@*" mode="cleanup"><xsl:copy/></xsl:template>
69
70<xsl:template match="text()" mode="cleanup"><xsl:copy/></xsl:template>
71
72<xsl:template match="/" mode="cleanup">
73        <xsl:copy><xsl:apply-templates select="node()" mode="cleanup" /></xsl:copy>
74</xsl:template>
75
76<xsl:template match="*" mode="cleanup">
77  <xsl:element name="{local-name()}">
78        <xsl:apply-templates select="node()|@*" mode="cleanup" />
79  </xsl:element>
80</xsl:template>
81
82
83<!-- remove PI extensions -->
84
85<xsl:template match="processing-instruction('rfc-ext')" mode="cleanup"/>
86<xsl:template match="processing-instruction('BEGININC')" mode="cleanup"/>
87<xsl:template match="processing-instruction('ENDINC')" mode="cleanup"/>
88
89<!-- add issues appendix -->
90
91<xsl:template match="back" mode="cleanup">
92  <back>
93    <xsl:apply-templates select="node()|@*" mode="cleanup" />
94    <xsl:if test="not(/*/@ed:suppress-issue-appendix='yes') and //ed:issue[@status='closed']">
95      <section title="Resolved issues (to be removed by RFC Editor before publication)">
96        <t>
97          Issues that were either rejected or resolved in this version of this
98          document.
99        </t>
100        <xsl:apply-templates select="//ed:issue[@status='closed']" mode="issues" />
101      </section>
102    </xsl:if>
103    <xsl:if test="not(/*/@ed:suppress-issue-appendix='yes') and //ed:issue[@status='open']">
104      <section title="Open issues (to be removed by RFC Editor prior to publication)">
105        <xsl:apply-templates select="//ed:issue[@status!='closed']" mode="issues" />
106      </section>
107    </xsl:if>
108  </back>
109</xsl:template>
110
111
112
113
114<!-- extensions -->
115
116<xsl:template match="x:abnf-char-sequence" mode="cleanup">
117  <xsl:choose>
118    <xsl:when test="substring(.,1,1) != '&quot;' or substring(.,string-length(.),1) != '&quot;'">
119      <xsl:call-template name="error">
120        <xsl:with-param name="msg" select="'contents of x:abnf-char-sequence needs to be quoted.'" />
121      </xsl:call-template>
122    </xsl:when>
123    <xsl:otherwise>
124      <xsl:text>%x</xsl:text>
125      <xsl:call-template name="to-abnf-char-sequence">
126        <xsl:with-param name="chars" select="substring(.,2,string-length(.)-2)"/>
127      </xsl:call-template>
128    </xsl:otherwise>
129  </xsl:choose>
130</xsl:template>
131
132<xsl:template match="x:anchor-alias" mode="cleanup"/>
133
134<xsl:template match="x:bcp14" mode="cleanup">
135  <xsl:apply-templates/>
136</xsl:template>
137
138<xsl:template match="x:assign-section-number" mode="cleanup"/> 
139<xsl:template match="x:link" mode="cleanup"/>
140<xsl:template match="x:source" mode="cleanup"/>
141
142<xsl:template match="x:parse-xml" mode="cleanup">
143  <xsl:apply-templates/>
144</xsl:template>
145
146<xsl:template match="x:ref" mode="cleanup">
147  <xsl:variable name="val" select="."/>
148  <xsl:variable name="target" select="//*[@anchor and (@anchor=$val or x:anchor-alias/@value=$val)]"/>
149  <xsl:choose>
150    <xsl:when test="$target">
151      <xsl:variable name="current" select="."/>
152      <xsl:for-each select="$target">
153        <!-- make it the context -->
154        <xsl:choose>
155          <xsl:when test="self::preamble">
156            <!-- it's not an element we can link to -->
157            <xsl:call-template name="warning">
158              <xsl:with-param name="inline" select="'no'"/>
159              <xsl:with-param name="msg">couldn't create the link as <xsl:value-of select="name()"/> does not support the anchor attribute.</xsl:with-param>
160            </xsl:call-template>
161            <xsl:value-of select="$current"/>
162          </xsl:when>
163          <xsl:otherwise>
164            <xref target="{$target/@anchor}" format="none"><xsl:value-of select="$current"/></xref>
165          </xsl:otherwise>
166        </xsl:choose>
167      </xsl:for-each>
168    </xsl:when>
169    <xsl:otherwise>
170      <xsl:call-template name="warning">
171        <xsl:with-param name="inline" select="'no'"/>
172        <xsl:with-param name="msg">internal link target for '<xsl:value-of select="."/>' does not exist.</xsl:with-param>
173      </xsl:call-template>
174      <xsl:value-of select="."/>
175    </xsl:otherwise>
176  </xsl:choose>
177</xsl:template>
178
179<xsl:template match="x:blockquote" mode="cleanup">
180  <t><list>
181    <xsl:apply-templates mode="cleanup" />
182  </list></t>
183</xsl:template>
184
185<xsl:template match="x:h" mode="cleanup">
186  <xsl:apply-templates mode="cleanup" />
187</xsl:template>
188
189<xsl:template match="x:highlight" mode="cleanup">
190  <xsl:apply-templates mode="cleanup" />
191</xsl:template>
192
193<xsl:template match="x:lt" mode="cleanup">
194  <t>
195    <xsl:apply-templates select="@hangText|@anchor" mode="cleanup"/>
196    <xsl:for-each select="t">
197      <xsl:apply-templates mode="cleanup"/>
198      <xsl:if test="position()!=last()">
199        <vspace blankLines="1"/>
200      </xsl:if>
201    </xsl:for-each>
202  </t>
203</xsl:template>
204
205<xsl:template match="x:note" mode="cleanup">
206  <t>
207    <list>
208      <xsl:apply-templates mode="cleanup"/>
209    </list>
210  </t>
211</xsl:template>
212
213<xsl:template match="x:q" mode="cleanup">
214  <xsl:text>"</xsl:text>
215  <xsl:apply-templates mode="cleanup"/>
216  <xsl:text>"</xsl:text>
217</xsl:template>
218
219<xsl:template match="x:dfn" mode="cleanup">
220  <!-- help xml2rfc to keep dfn and following text on the same page -->
221  <xsl:if test="not(preceding-sibling::x:dfn) and count(following-sibling::list)=1">
222    <xsl:processing-instruction name="rfc">needLines="4"</xsl:processing-instruction>
223  </xsl:if>
224  <xsl:apply-templates mode="cleanup"/>
225</xsl:template>
226
227<xsl:template match="x:sup" mode="cleanup">
228  <xsl:text>^</xsl:text>
229  <xsl:apply-templates mode="cleanup" />
230</xsl:template>
231
232<xsl:template match="x:span" mode="cleanup">
233  <xsl:apply-templates mode="cleanup" />
234</xsl:template>
235<xsl:template match="x:span/@anchor" mode="cleanup"/>
236
237<xsl:template match="author/@anchor" mode="cleanup"/>
238<xsl:template match="x:include-author" mode="cleanup">
239  <t>
240    <xsl:value-of select="/*/front/author[@anchor=current()/@target]"/>
241  </t>
242  <t>
243    (see Authors Section)
244  </t>
245</xsl:template>
246
247<!-- extended reference formatting -->
248
249<xsl:template match="xref[@x:* and not(node())]" mode="cleanup">
250  <xsl:call-template name="insert-iref-for-xref"/>
251  <xsl:variable name="node" select="$src//*[@anchor=current()/@target]" />
252
253  <xsl:variable name="sec">
254    <xsl:choose>
255      <xsl:when test="starts-with(@x:rel,'#') and not(@x:sec) and $node/x:source/@href">
256        <xsl:variable name="extdoc" select="document($node/x:source/@href)"/>
257        <xsl:for-each select="$extdoc//*[@anchor=substring-after(current()/@x:rel,'#')]">
258          <xsl:call-template name="get-section-number"/>
259        </xsl:for-each>
260      </xsl:when>
261      <xsl:otherwise>
262        <xsl:value-of select="@x:sec"/>
263      </xsl:otherwise>
264    </xsl:choose>
265  </xsl:variable>
266
267  <xsl:variable name="secterm">
268    <xsl:choose>
269      <!-- starts with letter? -->
270      <xsl:when test="translate(substring($sec,1,1),$ucase,'')=''">Appendix</xsl:when>
271      <xsl:otherwise>Section</xsl:otherwise>
272    </xsl:choose>
273  </xsl:variable>
274
275  <xsl:variable name="fmt">
276    <xsl:choose>
277      <xsl:when test="@x:fmt!=''"><xsl:value-of select="@x:fmt"/></xsl:when>
278      <xsl:when test="ancestor::artwork">,</xsl:when>
279      <xsl:otherwise>of</xsl:otherwise>
280    </xsl:choose>
281  </xsl:variable>
282
283  <xsl:choose>
284    <xsl:when test="$fmt=','">
285      <xref>
286        <xsl:apply-templates select="@target|@format|@pageno|text()|*" mode="cleanup"/>
287      </xref>
288      <xsl:text>, </xsl:text>
289      <xsl:value-of select="$secterm"/>
290      <xsl:text> </xsl:text>
291      <xsl:value-of select="$sec"/>
292    </xsl:when>
293    <xsl:when test="$fmt='sec'">
294      <xsl:value-of select="$secterm"/>
295      <xsl:text> </xsl:text>
296      <xsl:value-of select="$sec"/>
297    </xsl:when>
298    <xsl:when test="$fmt='number'">
299      <xsl:value-of select="$sec"/>
300    </xsl:when>
301    <xsl:when test="$fmt='()'">
302      <xref>
303        <xsl:apply-templates select="@target|@format|@pageno|text()|*" mode="cleanup"/>
304      </xref>
305      <xsl:text> (</xsl:text>
306      <xsl:value-of select="$secterm"/>
307      <xsl:text> </xsl:text>
308      <xsl:value-of select="$sec"/>
309      <xsl:text>)</xsl:text>
310    </xsl:when>
311    <xsl:when test="$fmt='of'">
312      <xsl:value-of select="$secterm"/>
313      <xsl:text> </xsl:text>
314      <xsl:value-of select="$sec"/>
315      <xsl:text> of </xsl:text>
316      <xref>
317        <xsl:apply-templates select="@target|@format|@pageno|text()|*" mode="cleanup"/>
318      </xref>
319    </xsl:when>
320    <xsl:when test="$fmt='anchor'">
321      <xsl:variable name="val">
322        <xsl:call-template name="referencename">
323          <xsl:with-param name="node" select="$node" />
324        </xsl:call-template>
325      </xsl:variable>
326      <!-- remove brackets -->
327      <xsl:value-of select="substring($val,2,string-length($val)-2)"/>
328    </xsl:when>
329    <xsl:otherwise>
330      <xsl:copy>
331        <xsl:apply-templates select="node()" mode="cleanup"/>
332      </xsl:copy>
333    </xsl:otherwise>
334  </xsl:choose>
335</xsl:template>
336
337<xsl:template match="xref[@x:fmt and node()]" mode="cleanup">
338  <xsl:call-template name="insert-iref-for-xref"/>
339  <xsl:choose>
340    <xsl:when test="@x:fmt='none'">
341      <xsl:apply-templates mode="cleanup"/>
342    </xsl:when>
343    <xsl:when test="not(@x:fmt)">
344      <xref>
345        <xsl:copy-of select="@target|@format"/>
346        <xsl:apply-templates mode="cleanup"/>
347      </xref>
348    </xsl:when>
349    <xsl:otherwise>
350      <xsl:message>Unsupported x:fmt attribute.</xsl:message>
351    </xsl:otherwise>
352  </xsl:choose>
353</xsl:template>
354
355<xsl:template match="xref[node() and (@target=//preamble/@anchor or @target=//spanx/@anchor)]" mode="cleanup">
356  <!-- remove the link -->
357  <xsl:apply-templates select="node()" mode="cleanup"/>
358</xsl:template>
359
360<xsl:template match="xref[not(node()) and (@target=//preamble/@anchor or @target=//spanx/@anchor)]" mode="cleanup">
361  <!-- fatal -->
362  <xsl:message terminate="yes">Broken xref <xsl:value-of select="@target"/> due to target being filtered out.</xsl:message>
363</xsl:template>
364
365<xsl:template match="xref" mode="cleanup" priority="0">
366  <xsl:call-template name="insert-iref-for-xref"/>
367  <xref>
368    <xsl:copy-of select="@target|@format"/>
369    <xsl:apply-templates mode="cleanup"/>
370  </xref>
371</xsl:template>
372
373<xsl:template name="insert-iref-for-xref">
374  <xsl:if test="$xml2rfc-ext-include-references-in-index='yesxxx'">
375    <xsl:if test="@target=/rfc/back//reference/@anchor">
376      <iref item="{@target}"/>
377      <xsl:if test="@x:sec">
378        <xsl:choose>
379          <xsl:when test="translate(substring(@x:sec,1,1),$ucase,'')=''">
380            <iref item="{@target}" subitem="Appendix {@x:sec}"/>
381          </xsl:when>
382          <xsl:otherwise>
383            <iref item="{@target}" subitem="Section {@x:sec}"/>
384          </xsl:otherwise>
385        </xsl:choose>
386      </xsl:if>
387    </xsl:if>
388  </xsl:if>
389</xsl:template>
390
391<!-- issue tracking extensions -->
392
393<xsl:template match="@xml:lang" mode="cleanup"/>
394<xsl:template match="@xml:lang" />
395
396<xsl:template match="ed:*" mode="cleanup"/>
397<xsl:template match="ed:*" />
398
399<xsl:template match="@ed:*" mode="cleanup"/>
400<xsl:template match="@ed:*" />
401
402<xsl:template match="ed:annotation" mode="cleanup" />
403
404<xsl:template match="ed:replace" mode="cleanup">
405  <xsl:apply-templates mode="cleanup" />
406</xsl:template>
407
408<xsl:template match="ed:replace">
409  <xsl:apply-templates/>
410</xsl:template>
411
412<xsl:template match="ed:ins" mode="cleanup">
413  <xsl:apply-templates mode="cleanup"/>
414</xsl:template>
415
416<xsl:template match="ed:ins">
417  <xsl:apply-templates/>
418</xsl:template>
419
420<xsl:template match="ed:issue" mode="issues">
421  <section title="{@name}">
422    <xsl:variable name="sec">
423      <xsl:call-template name="get-section-number"/>
424    </xsl:variable>
425
426    <xsl:if test="$sec!=''">
427      <t>
428        In Section <xsl:value-of select="$sec"/>:
429      </t>
430    </xsl:if>
431   
432    <t>
433      Type: <xsl:value-of select="@type" />
434    </t>
435    <xsl:if test="@href">
436      <t>
437        <!-- temp. removed because of xml2rfc's handling of erefs when producing TXT-->
438        <!--<eref target="{@href}" /> -->
439        <xsl:text>&lt;</xsl:text>
440        <xsl:value-of select="@href"/>
441        <xsl:text>></xsl:text>
442        <xsl:if test="@alternate-href">
443          <xsl:text>, &lt;</xsl:text>
444          <xsl:value-of select="@alternate-href"/>
445          <xsl:text>></xsl:text>
446        </xsl:if>
447      </t>
448    </xsl:if>
449    <xsl:for-each select="ed:item">
450      <t>
451        <xsl:if test="@entered-by or @date">
452          <xsl:choose>
453            <xsl:when test="not(@entered-by)">
454              <xsl:value-of select="concat('(',@date,') ')" />
455            </xsl:when>
456            <xsl:when test="not(@date)">
457              <xsl:value-of select="concat(@entered-by,': ')" />
458            </xsl:when>
459            <xsl:otherwise>
460              <xsl:value-of select="concat(@entered-by,' (',@date,'): ')" />
461            </xsl:otherwise>
462          </xsl:choose>     
463        </xsl:if>
464        <xsl:if test="not(xhtml:p)">
465          <xsl:apply-templates select="node()" mode="issues"/>
466        </xsl:if>
467      </t>
468      <xsl:if test="xhtml:p|xhtml:pre">
469        <xsl:for-each select="node()">
470          <xsl:choose>
471            <xsl:when test="self::xhtml:p">
472              <t>
473                <xsl:apply-templates select="node()" mode="issues"/>
474              </t>
475            </xsl:when>
476            <xsl:when test="self::xhtml:pre">
477              <figure>
478                <artwork><xsl:apply-templates select="node()" mode="issues"/></artwork>
479              </figure>
480            </xsl:when>
481            <xsl:otherwise>
482              <t>
483                <xsl:apply-templates select="." mode="issues"/>
484              </t>
485            </xsl:otherwise>
486          </xsl:choose>
487        </xsl:for-each>
488      </xsl:if>
489    </xsl:for-each> 
490    <xsl:if test="ed:resolution">
491      <t>
492        <xsl:text>Resolution</xsl:text>
493        <xsl:if test="ed:resolution/@datetime"> (<xsl:value-of select="ed:resolution/@datetime"/>)</xsl:if>
494        <xsl:text>: </xsl:text>
495        <xsl:value-of select="ed:resolution" />
496      </t>
497    </xsl:if>
498  </section>
499</xsl:template>
500
501<xsl:template match="ed:issueref" mode="cleanup">
502  <xsl:apply-templates mode="cleanup"/>
503</xsl:template>
504
505<xsl:template match="*" mode="issues">
506  <xsl:apply-templates mode="issues"/>
507</xsl:template>
508
509<xsl:template match="xhtml:q" mode="issues">
510  <list><t>
511    <xsl:text>"</xsl:text>
512    <xsl:apply-templates mode="issues"/>
513    <xsl:text>"</xsl:text>
514    <xsl:if test="@cite">
515      <xsl:text> -- </xsl:text>
516      <eref target="{@cite}"><xsl:value-of select="@cite"/></eref>
517    </xsl:if>
518  </t></list>
519</xsl:template>
520
521<xsl:template match="xhtml:br" mode="issues">
522  <vspace/>
523</xsl:template>
524
525<xsl:template match="xhtml:del" mode="issues">
526  <xsl:text>&lt;del></xsl:text>
527    <xsl:apply-templates mode="issues"/>
528  <xsl:text>&lt;/del></xsl:text>
529</xsl:template>
530
531<xsl:template match="xhtml:em" mode="issues">
532  <spanx style="emph">
533    <xsl:apply-templates mode="issues"/>
534  </spanx>
535</xsl:template>
536
537<xsl:template match="xhtml:ins" mode="issues">
538  <xsl:text>&lt;ins></xsl:text>
539    <xsl:apply-templates mode="issues"/>
540  <xsl:text>&lt;/ins></xsl:text>
541</xsl:template>
542
543<xsl:template match="xhtml:tt" mode="issues">
544  <xsl:apply-templates mode="issues"/>
545</xsl:template>
546
547<xsl:template match="ed:eref" mode="issues">
548  <xsl:text>&lt;</xsl:text>
549  <xsl:value-of select="."/>
550  <xsl:text>&gt;</xsl:text>
551</xsl:template>
552
553<xsl:template match="ed:issueref" mode="issues">
554  <xsl:apply-templates mode="issues"/>
555</xsl:template>
556
557<xsl:template match="text()" mode="issues">
558  <xsl:value-of select="." />
559</xsl:template>
560
561
562
563<!-- markup inside artwork element -->
564
565<xsl:template match="figure[.//artwork//iref | .//artwork//xref]" mode="cleanup">
566  <!-- move up iref elements -->
567  <xsl:for-each select=".//artwork//xref">
568    <xsl:if test="not(ancestor::ed:del)">
569      <xsl:call-template name="insert-iref-for-xref"/>
570    </xsl:if>
571  </xsl:for-each>
572  <figure>
573    <xsl:apply-templates select="@*" mode="cleanup" />
574    <xsl:apply-templates select=".//artwork//iref" mode="cleanup"/>
575    <xsl:apply-templates select="iref|preamble|artwork|postamble|ed:replace|ed:ins|ed:del" mode="cleanup" />
576  </figure>
577</xsl:template>
578
579<xsl:template name="insert-begin-code"/>
580<xsl:template name="insert-end-code"/>
581<xsl:template match="@x:isCodeComponent" mode="cleanup"/>
582
583<xsl:template match="artwork" mode="cleanup">
584  <xsl:variable name="content2"><xsl:apply-templates select="."/></xsl:variable>
585  <xsl:variable name="content" select="translate($content2,'&#160;&#x2500;&#x2502;&#x2508;&#x250c;&#x2510;&#x2514;&#x2518;&#x251c;&#x2524;',' -|+++++++')"/>
586  <artwork>
587    <xsl:apply-templates select="@*" mode="cleanup" />
588    <xsl:if test="@x:isCodeComponent='yes'">
589      <xsl:if test="starts-with(.,'&#10;')">
590        <xsl:text>&#10;</xsl:text>
591      </xsl:if>
592      <xsl:value-of select="@x:indent-with"/>
593      <xsl:text>&lt;CODE BEGINS&gt;&#10;</xsl:text>
594    </xsl:if>
595    <xsl:if test="starts-with(.,'&#10;')">
596      <xsl:text>&#10;</xsl:text>
597      <xsl:value-of select="@x:indent-with"/>
598    </xsl:if>
599    <xsl:choose>
600      <xsl:when test="@x:indent-with!=''">
601        <xsl:call-template name="indent">
602          <xsl:with-param name="content" select="$content"/>
603          <xsl:with-param name="with" select="@x:indent-with"/>
604        </xsl:call-template>
605      </xsl:when>
606      <xsl:otherwise>
607        <xsl:value-of select="$content"/>
608      </xsl:otherwise>
609    </xsl:choose>
610    <xsl:if test="@x:isCodeComponent='yes'">&#10;&lt;CODE ENDS&gt;&#10;</xsl:if>
611  </artwork> 
612</xsl:template>
613
614<xsl:template match="@x:indent-with" mode="cleanup"/>
615
616<xsl:template name="indent">
617  <xsl:param name="content"/>
618  <xsl:param name="with"/>
619
620  <xsl:value-of select="substring($content,1,1)"/>
621  <xsl:if test="substring($content,1,1)='&#10;'">
622    <xsl:value-of select="$with"/>
623  </xsl:if>
624 
625  <xsl:choose>
626    <xsl:when test="$content=''" />
627    <xsl:otherwise>
628      <xsl:call-template name="indent">
629        <xsl:with-param name="content" select="substring($content,2)"/>
630        <xsl:with-param name="with" select="$with"/>
631      </xsl:call-template>
632    </xsl:otherwise>
633  </xsl:choose>
634 
635</xsl:template>
636
637<!-- email repetitions -->
638<xsl:template match="email" mode="cleanup">
639  <!-- combine in a single element -->
640  <xsl:if test="not(preceding-sibling::email)">
641    <email>
642      <xsl:for-each select="../email">
643        <xsl:value-of select="."/>
644        <xsl:if test="position()!=last()">
645          <xsl:text>, </xsl:text>
646        </xsl:if>
647      </xsl:for-each>
648    </email>
649  </xsl:if>
650</xsl:template>
651
652<!-- markup inside cref -->
653<xsl:template match="cref//eref" mode="cleanup">
654  <xsl:text>&lt;</xsl:text>
655  <xsl:value-of select="@target"/>
656  <xsl:text>&gt;</xsl:text>
657</xsl:template>
658
659<xsl:template match="cref//xref" mode="cleanup" priority="9">
660  <xsl:variable name="text">
661    <xsl:apply-templates select="."/>
662  </xsl:variable>
663  <xsl:value-of select="$text"/>
664</xsl:template>
665
666<!-- annotations -->
667<xsl:template match="@x:annotation" mode="cleanup">
668  <xsl:comment>
669    <xsl:value-of select="."/>
670  </xsl:comment>
671  <xsl:call-template name="warning">
672    <xsl:with-param name="inline" select="'no'"/>
673    <xsl:with-param name="msg">Dropping annotation on <xsl:value-of select="local-name(..)"/> element.</xsl:with-param>
674  </xsl:call-template>
675</xsl:template>
676
677<!-- artwork extensions -->
678<xsl:template match="artwork/@x:extraction-note" mode="cleanup"/>
679
680<!-- list formatting -->
681<xsl:template match="list/@x:indent" mode="cleanup"/>
682
683<!-- referencing extensions -->
684<xsl:template match="iref/@x:for-anchor" mode="cleanup"/>
685
686<!-- table styles -->
687<xsl:template match="texttable/@style" mode="cleanup"/>
688
689<!-- section numbering -->
690<xsl:template match="section/@x:fixed-section-number" mode="cleanup"/>
691
692<!-- GRRDL info stripped -->
693<xsl:template match="@grddl:transformation" mode="cleanup"/>
694
695<!-- maturity level stripped -->
696<xsl:template match="@x:maturity-level" mode="cleanup"/>
697
698<!-- normativity stripped -->
699<xsl:template match="@x:nrm" mode="cleanup"/>
700
701<!-- RDF info stripped -->
702<xsl:template match="rdf:*" mode="cleanup"/>
703
704<!-- cases where xml2rfc does not allow anchors -->
705<xsl:template match="preamble/@anchor" mode="cleanup"/>
706<xsl:template match="spanx/@anchor" mode="cleanup"/>
707
708</xsl:transform>
Note: See TracBrowser for help on using the repository browser.