source: rfc2629xslt/clean-for-DTD.xslt @ 729

Last change on this file since 729 was 704, checked in by julian.reschke@…, 10 years ago

Bump up document dates, update to latest versions of rfc2629.xslt and xml2rfc.tcl

  • Property svn:eol-style set to native
File size: 22.1 KB
Line 
1<!--
2    Strip rfc2629.xslt extensions, generating XML input for MTR's xml2rfc
3
4    Copyright (c) 2006-2009, Julian Reschke (julian.reschke@greenbytes.de)
5    All rights reserved.
6
7    Redistribution and use in source and binary forms, with or without
8    modification, are permitted provided that the following conditions are met:
9
10    * Redistributions of source code must retain the above copyright notice,
11      this list of conditions and the following disclaimer.
12    * Redistributions in binary form must reproduce the above copyright notice,
13      this list of conditions and the following disclaimer in the documentation
14      and/or other materials provided with the distribution.
15    * Neither the name of Julian Reschke nor the names of its contributors
16      may be used to endorse or promote products derived from this software
17      without specific prior written permission.
18
19    THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
20    AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
21    IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
22    ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR CONTRIBUTORS BE
23    LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
24    CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
25    SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
26    INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
27    CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
28    ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
29    POSSIBILITY OF SUCH DAMAGE.
30-->
31
32<xsl:transform xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
33                version="1.0"
34                xmlns:ed="http://greenbytes.de/2002/rfcedit"
35                xmlns:grddl="http://www.w3.org/2003/g/data-view#"
36                xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#"
37                xmlns:x="http://purl.org/net/xml2rfc/ext"
38                xmlns:xhtml="http://www.w3.org/1999/xhtml"
39                exclude-result-prefixes="ed grddl rdf x xhtml"
40>
41
42<!-- re-use some of the default RFC2629.xslt rules -->
43<xsl:import href="rfc2629.xslt"/>
44
45<!-- undo strip-space decls -->
46<xsl:preserve-space elements="*"/>
47
48<!-- generate DTD-valid output, override all values imported from rfc2629.xslt -->
49<xsl:output doctype-system="rfc2629.dtd" doctype-public="" method="xml" version="1.0" encoding="UTF-8" cdata-section-elements="artwork" />
50
51<!-- kick into cleanup mode -->
52<xsl:template match="/">
53  <xsl:text>&#10;</xsl:text>
54  <xsl:comment>
55    This XML document is the output of clean-for-DTD.xslt; a tool that strips
56    extensions to RFC2629(bis) from documents for processing with xml2rfc.
57</xsl:comment>
58  <xsl:apply-templates select="/" mode="cleanup"/>
59</xsl:template>
60
61<!-- rules for identity transformations -->
62
63<xsl:template match="processing-instruction()" mode="cleanup">
64  <xsl:text>&#10;</xsl:text>
65  <xsl:copy/>
66</xsl:template>
67
68<xsl:template match="comment()|@*" mode="cleanup"><xsl:copy/></xsl:template>
69
70<xsl:template match="text()" mode="cleanup"><xsl:copy/></xsl:template>
71
72<xsl:template match="/" mode="cleanup">
73        <xsl:copy><xsl:apply-templates select="node()" mode="cleanup" /></xsl:copy>
74</xsl:template>
75
76<xsl:template match="*" mode="cleanup">
77  <xsl:element name="{local-name()}">
78        <xsl:apply-templates select="node()|@*" mode="cleanup" />
79  </xsl:element>
80</xsl:template>
81
82
83<!-- remove PI extensions -->
84
85<xsl:template match="processing-instruction('rfc-ext')" mode="cleanup"/>
86<xsl:template match="processing-instruction('BEGININC')" mode="cleanup"/>
87<xsl:template match="processing-instruction('ENDINC')" mode="cleanup"/>
88
89<!-- add issues appendix -->
90
91<xsl:template match="back" mode="cleanup">
92  <back>
93    <xsl:apply-templates select="node()|@*" mode="cleanup" />
94    <xsl:if test="not(/*/@ed:suppress-issue-appendix='yes') and //ed:issue[@status='closed']">
95      <section title="Resolved issues (to be removed by RFC Editor before publication)">
96        <t>
97          Issues that were either rejected or resolved in this version of this
98          document.
99        </t>
100        <xsl:apply-templates select="//ed:issue[@status='closed']" mode="issues" />
101      </section>
102    </xsl:if>
103    <xsl:if test="not(/*/@ed:suppress-issue-appendix='yes') and //ed:issue[@status='open']">
104      <section title="Open issues (to be removed by RFC Editor prior to publication)">
105        <xsl:apply-templates select="//ed:issue[@status!='closed']" mode="issues" />
106      </section>
107    </xsl:if>
108  </back>
109</xsl:template>
110
111
112
113
114<!-- extensions -->
115
116<xsl:template match="x:abnf-char-sequence" mode="cleanup">
117  <xsl:choose>
118    <xsl:when test="substring(.,1,1) != '&quot;' or substring(.,string-length(.),1) != '&quot;'">
119      <xsl:call-template name="error">
120        <xsl:with-param name="msg" select="'contents of x:abnf-char-sequence needs to be quoted.'" />
121      </xsl:call-template>
122    </xsl:when>
123    <xsl:otherwise>
124      <xsl:text>%x</xsl:text>
125      <xsl:call-template name="to-abnf-char-sequence">
126        <xsl:with-param name="chars" select="substring(.,2,string-length(.)-2)"/>
127      </xsl:call-template>
128    </xsl:otherwise>
129  </xsl:choose>
130</xsl:template>
131
132<xsl:template match="x:anchor-alias" mode="cleanup"/>
133
134<xsl:template match="x:bcp14" mode="cleanup">
135  <xsl:apply-templates/>
136</xsl:template>
137
138<xsl:template match="x:assign-section-number" mode="cleanup"/> 
139<xsl:template match="x:link" mode="cleanup"/>
140<xsl:template match="x:source" mode="cleanup"/>
141
142<xsl:template match="x:parse-xml" mode="cleanup">
143  <xsl:apply-templates/>
144</xsl:template>
145
146<xsl:template match="x:ref" mode="cleanup">
147  <xsl:variable name="val" select="."/>
148  <xsl:variable name="target" select="//*[@anchor and (@anchor=$val or x:anchor-alias/@value=$val)]"/>
149  <xsl:choose>
150    <xsl:when test="$target">
151      <xsl:variable name="current" select="."/>
152      <xsl:for-each select="$target">
153        <!-- make it the context -->
154        <xsl:choose>
155          <xsl:when test="self::preamble">
156            <!-- it's not an element we can link to -->
157            <xsl:call-template name="warning">
158              <xsl:with-param name="inline" select="'no'"/>
159              <xsl:with-param name="msg">couldn't create the link as <xsl:value-of select="name()"/> does not support the anchor attribute.</xsl:with-param>
160            </xsl:call-template>
161            <xsl:value-of select="$current"/>
162          </xsl:when>
163          <xsl:otherwise>
164            <xref target="{$target/@anchor}" format="none"><xsl:value-of select="$current"/></xref>
165          </xsl:otherwise>
166        </xsl:choose>
167      </xsl:for-each>
168    </xsl:when>
169    <xsl:otherwise>
170      <xsl:call-template name="warning">
171        <xsl:with-param name="inline" select="'no'"/>
172        <xsl:with-param name="msg">internal link target for '<xsl:value-of select="."/>' does not exist.</xsl:with-param>
173      </xsl:call-template>
174      <xsl:value-of select="."/>
175    </xsl:otherwise>
176  </xsl:choose>
177</xsl:template>
178
179<xsl:template match="x:blockquote" mode="cleanup">
180  <t><list>
181    <xsl:apply-templates mode="cleanup" />
182  </list></t>
183</xsl:template>
184
185<xsl:template match="x:h" mode="cleanup">
186  <xsl:apply-templates mode="cleanup" />
187</xsl:template>
188
189<xsl:template match="x:highlight" mode="cleanup">
190  <xsl:apply-templates mode="cleanup" />
191</xsl:template>
192
193<xsl:template match="x:lt" mode="cleanup">
194  <t>
195    <xsl:apply-templates select="@hangText|@anchor" mode="cleanup"/>
196    <xsl:for-each select="t">
197      <xsl:apply-templates mode="cleanup"/>
198      <xsl:if test="position()!=last()">
199        <vspace blankLines="1"/>
200      </xsl:if>
201    </xsl:for-each>
202  </t>
203</xsl:template>
204
205<xsl:template match="x:note" mode="cleanup">
206  <t>
207    <list>
208      <xsl:apply-templates mode="cleanup"/>
209    </list>
210  </t>
211</xsl:template>
212
213<xsl:template match="x:q" mode="cleanup">
214  <xsl:text>"</xsl:text>
215  <xsl:apply-templates mode="cleanup"/>
216  <xsl:text>"</xsl:text>
217</xsl:template>
218
219<xsl:template match="x:dfn" mode="cleanup">
220  <!-- help xml2rfc to keep dfn and following text on the same page -->
221  <xsl:if test="not(preceding-sibling::x:dfn) and count(following-sibling::list)=1">
222    <xsl:processing-instruction name="rfc">needLines="4"</xsl:processing-instruction>
223  </xsl:if>
224  <xsl:apply-templates mode="cleanup"/>
225</xsl:template>
226
227<xsl:template match="x:sup" mode="cleanup">
228  <xsl:text>^</xsl:text>
229  <xsl:apply-templates mode="cleanup" />
230</xsl:template>
231
232<xsl:template match="author/@anchor" mode="cleanup"/>
233<xsl:template match="x:include-author" mode="cleanup">
234  <t>
235    <xsl:value-of select="/*/front/author[@anchor=current()/@target]"/>
236  </t>
237  <t>
238    (see Authors Section)
239  </t>
240</xsl:template>
241
242<!-- extended reference formatting -->
243
244<xsl:template match="xref[@x:* and not(node())]" mode="cleanup">
245  <xsl:call-template name="insert-iref-for-xref"/>
246  <xsl:variable name="node" select="$src//*[@anchor=current()/@target]" />
247
248  <xsl:variable name="sec">
249    <xsl:choose>
250      <xsl:when test="starts-with(@x:rel,'#') and not(@x:sec) and $node/x:source/@href">
251        <xsl:variable name="extdoc" select="document($node/x:source/@href)"/>
252        <xsl:for-each select="$extdoc//*[@anchor=substring-after(current()/@x:rel,'#')]">
253          <xsl:call-template name="get-section-number"/>
254        </xsl:for-each>
255      </xsl:when>
256      <xsl:otherwise>
257        <xsl:value-of select="@x:sec"/>
258      </xsl:otherwise>
259    </xsl:choose>
260  </xsl:variable>
261
262  <xsl:variable name="secterm">
263    <xsl:choose>
264      <!-- starts with letter? -->
265      <xsl:when test="translate(substring($sec,1,1),$ucase,'')=''">Appendix</xsl:when>
266      <xsl:otherwise>Section</xsl:otherwise>
267    </xsl:choose>
268  </xsl:variable>
269
270  <xsl:variable name="fmt">
271    <xsl:choose>
272      <xsl:when test="@x:fmt!=''"><xsl:value-of select="@x:fmt"/></xsl:when>
273      <xsl:when test="ancestor::artwork">,</xsl:when>
274      <xsl:otherwise>of</xsl:otherwise>
275    </xsl:choose>
276  </xsl:variable>
277
278  <xsl:choose>
279    <xsl:when test="$fmt=','">
280      <xref>
281        <xsl:apply-templates select="@target|@format|@pageno|text()|*" mode="cleanup"/>
282      </xref>
283      <xsl:text>, </xsl:text>
284      <xsl:value-of select="$secterm"/>
285      <xsl:text> </xsl:text>
286      <xsl:value-of select="$sec"/>
287    </xsl:when>
288    <xsl:when test="$fmt='sec'">
289      <xsl:value-of select="$secterm"/>
290      <xsl:text> </xsl:text>
291      <xsl:value-of select="$sec"/>
292    </xsl:when>
293    <xsl:when test="$fmt='number'">
294      <xsl:value-of select="$sec"/>
295    </xsl:when>
296    <xsl:when test="$fmt='()'">
297      <xref>
298        <xsl:apply-templates select="@target|@format|@pageno|text()|*" mode="cleanup"/>
299      </xref>
300      <xsl:text> (</xsl:text>
301      <xsl:value-of select="$secterm"/>
302      <xsl:text> </xsl:text>
303      <xsl:value-of select="$sec"/>
304      <xsl:text>)</xsl:text>
305    </xsl:when>
306    <xsl:when test="$fmt='of'">
307      <xsl:value-of select="$secterm"/>
308      <xsl:text> </xsl:text>
309      <xsl:value-of select="$sec"/>
310      <xsl:text> of </xsl:text>
311      <xref>
312        <xsl:apply-templates select="@target|@format|@pageno|text()|*" mode="cleanup"/>
313      </xref>
314    </xsl:when>
315    <xsl:when test="$fmt='anchor'">
316      <xsl:variable name="val">
317        <xsl:call-template name="referencename">
318          <xsl:with-param name="node" select="$node" />
319        </xsl:call-template>
320      </xsl:variable>
321      <!-- remove brackets -->
322      <xsl:value-of select="substring($val,2,string-length($val)-2)"/>
323    </xsl:when>
324    <xsl:otherwise>
325      <xsl:copy>
326        <xsl:apply-templates select="node()" mode="cleanup"/>
327      </xsl:copy>
328    </xsl:otherwise>
329  </xsl:choose>
330</xsl:template>
331
332<xsl:template match="xref[@x:fmt and node()]" mode="cleanup">
333  <xsl:call-template name="insert-iref-for-xref"/>
334  <xsl:choose>
335    <xsl:when test="@x:fmt='none'">
336      <xsl:apply-templates mode="cleanup"/>
337    </xsl:when>
338    <xsl:when test="not(@x:fmt)">
339      <xref>
340        <xsl:copy-of select="@target|@format"/>
341        <xsl:apply-templates mode="cleanup"/>
342      </xref>
343    </xsl:when>
344    <xsl:otherwise>
345      <xsl:message>Unsupported x:fmt attribute.</xsl:message>
346    </xsl:otherwise>
347  </xsl:choose>
348</xsl:template>
349
350<xsl:template match="xref[node() and (@target=//preamble/@anchor or @target=//spanx/@anchor)]" mode="cleanup">
351  <!-- remove the link -->
352  <xsl:apply-templates select="node()" mode="cleanup"/>
353</xsl:template>
354
355<xsl:template match="xref[not(node()) and (@target=//preamble/@anchor or @target=//spanx/@anchor)]" mode="cleanup">
356  <!-- fatal -->
357  <xsl:message terminate="yes">Broken xref <xsl:value-of select="@target"/> due to target being filtered out.</xsl:message>
358</xsl:template>
359
360<xsl:template match="xref" mode="cleanup" priority="0">
361  <xsl:call-template name="insert-iref-for-xref"/>
362  <xref>
363    <xsl:copy-of select="@target|@format"/>
364    <xsl:apply-templates mode="cleanup"/>
365  </xref>
366</xsl:template>
367
368<xsl:template name="insert-iref-for-xref">
369  <xsl:if test="$xml2rfc-ext-include-references-in-index='yesxxx'">
370    <xsl:if test="@target=/rfc/back//reference/@anchor">
371      <iref item="{@target}"/>
372      <xsl:if test="@x:sec">
373        <xsl:choose>
374          <xsl:when test="translate(substring(@x:sec,1,1),$ucase,'')=''">
375            <iref item="{@target}" subitem="Appendix {@x:sec}"/>
376          </xsl:when>
377          <xsl:otherwise>
378            <iref item="{@target}" subitem="Section {@x:sec}"/>
379          </xsl:otherwise>
380        </xsl:choose>
381      </xsl:if>
382    </xsl:if>
383  </xsl:if>
384</xsl:template>
385
386<!-- issue tracking extensions -->
387
388<xsl:template match="@xml:lang" mode="cleanup"/>
389<xsl:template match="@xml:lang" />
390
391<xsl:template match="ed:*" mode="cleanup"/>
392<xsl:template match="ed:*" />
393
394<xsl:template match="@ed:*" mode="cleanup"/>
395<xsl:template match="@ed:*" />
396
397<xsl:template match="ed:annotation" mode="cleanup" />
398
399<xsl:template match="ed:replace" mode="cleanup">
400  <xsl:apply-templates mode="cleanup" />
401</xsl:template>
402
403<xsl:template match="ed:replace">
404  <xsl:apply-templates/>
405</xsl:template>
406
407<xsl:template match="ed:ins" mode="cleanup">
408  <xsl:apply-templates mode="cleanup"/>
409</xsl:template>
410
411<xsl:template match="ed:ins">
412  <xsl:apply-templates/>
413</xsl:template>
414
415<xsl:template match="ed:issue" mode="issues">
416  <section title="{@name}">
417    <xsl:variable name="sec">
418      <xsl:call-template name="get-section-number"/>
419    </xsl:variable>
420
421    <xsl:if test="$sec!=''">
422      <t>
423        In Section <xsl:value-of select="$sec"/>:
424      </t>
425    </xsl:if>
426   
427    <t>
428      Type: <xsl:value-of select="@type" />
429    </t>
430    <xsl:if test="@href">
431      <t>
432        <!-- temp. removed because of xml2rfc's handling of erefs when producing TXT-->
433        <!--<eref target="{@href}" /> -->
434        <xsl:text>&lt;</xsl:text>
435        <xsl:value-of select="@href"/>
436        <xsl:text>></xsl:text>
437        <xsl:if test="@alternate-href">
438          <xsl:text>, &lt;</xsl:text>
439          <xsl:value-of select="@alternate-href"/>
440          <xsl:text>></xsl:text>
441        </xsl:if>
442      </t>
443    </xsl:if>
444    <xsl:for-each select="ed:item">
445      <t>
446        <xsl:if test="@entered-by or @date">
447          <xsl:choose>
448            <xsl:when test="not(@entered-by)">
449              <xsl:value-of select="concat('(',@date,') ')" />
450            </xsl:when>
451            <xsl:when test="not(@date)">
452              <xsl:value-of select="concat(@entered-by,': ')" />
453            </xsl:when>
454            <xsl:otherwise>
455              <xsl:value-of select="concat(@entered-by,' (',@date,'): ')" />
456            </xsl:otherwise>
457          </xsl:choose>     
458        </xsl:if>
459        <xsl:if test="not(xhtml:p)">
460          <xsl:apply-templates select="node()" mode="issues"/>
461        </xsl:if>
462      </t>
463      <xsl:if test="xhtml:p|xhtml:pre">
464        <xsl:for-each select="node()">
465          <xsl:choose>
466            <xsl:when test="self::xhtml:p">
467              <t>
468                <xsl:apply-templates select="node()" mode="issues"/>
469              </t>
470            </xsl:when>
471            <xsl:when test="self::xhtml:pre">
472              <figure>
473                <artwork><xsl:apply-templates select="node()" mode="issues"/></artwork>
474              </figure>
475            </xsl:when>
476            <xsl:otherwise>
477              <t>
478                <xsl:apply-templates select="." mode="issues"/>
479              </t>
480            </xsl:otherwise>
481          </xsl:choose>
482        </xsl:for-each>
483      </xsl:if>
484    </xsl:for-each> 
485    <xsl:if test="ed:resolution">
486      <t>
487        <xsl:text>Resolution</xsl:text>
488        <xsl:if test="ed:resolution/@datetime"> (<xsl:value-of select="ed:resolution/@datetime"/>)</xsl:if>
489        <xsl:text>: </xsl:text>
490        <xsl:value-of select="ed:resolution" />
491      </t>
492    </xsl:if>
493  </section>
494</xsl:template>
495
496<xsl:template match="ed:issueref" mode="cleanup">
497  <xsl:apply-templates mode="cleanup"/>
498</xsl:template>
499
500<xsl:template match="*" mode="issues">
501  <xsl:apply-templates mode="issues"/>
502</xsl:template>
503
504<xsl:template match="xhtml:q" mode="issues">
505  <list><t>
506    <xsl:text>"</xsl:text>
507    <xsl:apply-templates mode="issues"/>
508    <xsl:text>"</xsl:text>
509    <xsl:if test="@cite">
510      <xsl:text> -- </xsl:text>
511      <eref target="{@cite}"><xsl:value-of select="@cite"/></eref>
512    </xsl:if>
513  </t></list>
514</xsl:template>
515
516<xsl:template match="xhtml:br" mode="issues">
517  <vspace/>
518</xsl:template>
519
520<xsl:template match="xhtml:del" mode="issues">
521  <xsl:text>&lt;del></xsl:text>
522    <xsl:apply-templates mode="issues"/>
523  <xsl:text>&lt;/del></xsl:text>
524</xsl:template>
525
526<xsl:template match="xhtml:em" mode="issues">
527  <spanx style="emph">
528    <xsl:apply-templates mode="issues"/>
529  </spanx>
530</xsl:template>
531
532<xsl:template match="xhtml:ins" mode="issues">
533  <xsl:text>&lt;ins></xsl:text>
534    <xsl:apply-templates mode="issues"/>
535  <xsl:text>&lt;/ins></xsl:text>
536</xsl:template>
537
538<xsl:template match="xhtml:tt" mode="issues">
539  <xsl:apply-templates mode="issues"/>
540</xsl:template>
541
542<xsl:template match="ed:eref" mode="issues">
543  <xsl:text>&lt;</xsl:text>
544  <xsl:value-of select="."/>
545  <xsl:text>&gt;</xsl:text>
546</xsl:template>
547
548<xsl:template match="ed:issueref" mode="issues">
549  <xsl:apply-templates mode="issues"/>
550</xsl:template>
551
552<xsl:template match="text()" mode="issues">
553  <xsl:value-of select="." />
554</xsl:template>
555
556
557
558<!-- markup inside artwork element -->
559
560<xsl:template match="figure[.//artwork//iref | .//artwork//xref]" mode="cleanup">
561  <!-- move up iref elements -->
562  <xsl:for-each select=".//artwork//xref">
563    <xsl:if test="not(ancestor::ed:del)">
564      <xsl:call-template name="insert-iref-for-xref"/>
565    </xsl:if>
566  </xsl:for-each>
567  <figure>
568    <xsl:apply-templates select="@*" mode="cleanup" />
569    <xsl:apply-templates select=".//artwork//iref" mode="cleanup"/>
570    <xsl:apply-templates select="iref|preamble|artwork|postamble|ed:replace|ed:ins|ed:del" mode="cleanup" />
571  </figure>
572</xsl:template>
573
574<xsl:template name="insert-begin-code"/>
575<xsl:template name="insert-end-code"/>
576<xsl:template match="@x:isCodeComponent" mode="cleanup"/>
577
578<xsl:template match="artwork" mode="cleanup">
579  <xsl:variable name="content2"><xsl:apply-templates select="."/></xsl:variable>
580  <xsl:variable name="content" select="translate($content2,'&#160;&#x2500;&#x2502;&#x2508;&#x250c;&#x2510;&#x2514;&#x2518;&#x251c;&#x2524;',' -|+++++++')"/>
581  <artwork>
582    <xsl:apply-templates select="@*" mode="cleanup" />
583    <xsl:if test="@x:isCodeComponent='yes'">
584      <xsl:if test="starts-with(.,'&#10;')">
585        <xsl:text>&#10;</xsl:text>
586      </xsl:if>
587      <xsl:value-of select="@x:indent-with"/>
588      <xsl:text>&lt;CODE BEGINS&gt;&#10;</xsl:text>
589    </xsl:if>
590    <xsl:if test="starts-with(.,'&#10;')">
591      <xsl:text>&#10;</xsl:text>
592      <xsl:value-of select="@x:indent-with"/>
593    </xsl:if>
594    <xsl:choose>
595      <xsl:when test="@x:indent-with!=''">
596        <xsl:call-template name="indent">
597          <xsl:with-param name="content" select="$content"/>
598          <xsl:with-param name="with" select="@x:indent-with"/>
599        </xsl:call-template>
600      </xsl:when>
601      <xsl:otherwise>
602        <xsl:value-of select="$content"/>
603      </xsl:otherwise>
604    </xsl:choose>
605    <xsl:if test="@x:isCodeComponent='yes'">&#10;&lt;CODE ENDS&gt;&#10;</xsl:if>
606  </artwork> 
607</xsl:template>
608
609<xsl:template match="@x:indent-with" mode="cleanup"/>
610
611<xsl:template name="indent">
612  <xsl:param name="content"/>
613  <xsl:param name="with"/>
614
615  <xsl:value-of select="substring($content,1,1)"/>
616  <xsl:if test="substring($content,1,1)='&#10;'">
617    <xsl:value-of select="$with"/>
618  </xsl:if>
619 
620  <xsl:choose>
621    <xsl:when test="$content=''" />
622    <xsl:otherwise>
623      <xsl:call-template name="indent">
624        <xsl:with-param name="content" select="substring($content,2)"/>
625        <xsl:with-param name="with" select="$with"/>
626      </xsl:call-template>
627    </xsl:otherwise>
628  </xsl:choose>
629 
630</xsl:template>
631
632<!-- email repetitions -->
633<xsl:template match="email" mode="cleanup">
634  <!-- combine in a single element -->
635  <xsl:if test="not(preceding-sibling::email)">
636    <email>
637      <xsl:for-each select="../email">
638        <xsl:value-of select="."/>
639        <xsl:if test="position()!=last()">
640          <xsl:text>, </xsl:text>
641        </xsl:if>
642      </xsl:for-each>
643    </email>
644  </xsl:if>
645</xsl:template>
646
647<!-- markup inside cref -->
648<xsl:template match="cref//eref" mode="cleanup">
649  <xsl:text>&lt;</xsl:text>
650  <xsl:value-of select="@target"/>
651  <xsl:text>&gt;</xsl:text>
652</xsl:template>
653
654<xsl:template match="cref//xref" mode="cleanup" priority="9">
655  <xsl:variable name="text">
656    <xsl:apply-templates select="."/>
657  </xsl:variable>
658  <xsl:value-of select="$text"/>
659</xsl:template>
660
661<!-- artwork extensions -->
662<xsl:template match="artwork/@x:extraction-note" mode="cleanup"/>
663
664<!-- list formatting -->
665<xsl:template match="list/@x:indent" mode="cleanup"/>
666
667<!-- referencing extensions -->
668<xsl:template match="iref/@x:for-anchor" mode="cleanup"/>
669
670<!-- table styles -->
671<xsl:template match="texttable/@style" mode="cleanup"/>
672
673<!-- section numbering -->
674<xsl:template match="section/@x:fixed-section-number" mode="cleanup"/>
675
676<!-- GRRDL info stripped -->
677<xsl:template match="@grddl:transformation" mode="cleanup"/>
678
679<!-- maturity level stripped -->
680<xsl:template match="@x:maturity-level" mode="cleanup"/>
681
682<!-- RDF info stripped -->
683<xsl:template match="rdf:*" mode="cleanup"/>
684
685<!-- cases where xml2rfc does not allow anchors -->
686<xsl:template match="preamble/@anchor" mode="cleanup"/>
687<xsl:template match="spanx/@anchor" mode="cleanup"/>
688
689</xsl:transform>
Note: See TracBrowser for help on using the repository browser.