source: rfc2629xslt/clean-for-DTD.xslt @ 643

Last change on this file since 643 was 588, checked in by julian.reschke@…, 11 years ago

Update to latest version of rfc2629.xslt and bump up document dates.

  • Property svn:eol-style set to native
File size: 21.3 KB
Line 
1<!--
2    Strip rfc2629.xslt extensions, generating XML input for MTR's xml2rfc
3
4    Copyright (c) 2006-2009, Julian Reschke (julian.reschke@greenbytes.de)
5    All rights reserved.
6
7    Redistribution and use in source and binary forms, with or without
8    modification, are permitted provided that the following conditions are met:
9
10    * Redistributions of source code must retain the above copyright notice,
11      this list of conditions and the following disclaimer.
12    * Redistributions in binary form must reproduce the above copyright notice,
13      this list of conditions and the following disclaimer in the documentation
14      and/or other materials provided with the distribution.
15    * Neither the name of Julian Reschke nor the names of its contributors
16      may be used to endorse or promote products derived from this software
17      without specific prior written permission.
18
19    THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
20    AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
21    IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
22    ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR CONTRIBUTORS BE
23    LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
24    CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
25    SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
26    INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
27    CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
28    ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
29    POSSIBILITY OF SUCH DAMAGE.
30-->
31
32<xsl:transform xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
33                version="1.0"
34                xmlns:ed="http://greenbytes.de/2002/rfcedit"
35                xmlns:grddl="http://www.w3.org/2003/g/data-view#"
36                xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#"
37                xmlns:x="http://purl.org/net/xml2rfc/ext"
38                xmlns:xhtml="http://www.w3.org/1999/xhtml"
39                exclude-result-prefixes="ed grddl rdf x xhtml"
40>
41
42<!-- re-use some of the default RFC2629.xslt rules -->
43<xsl:import href="rfc2629.xslt"/>
44
45<!-- undo strip-space decls -->
46<xsl:preserve-space elements="*"/>
47
48<!-- generate DTD-valid output, override all values imported from rfc2629.xslt -->
49<xsl:output doctype-system="rfc2629.dtd" doctype-public="" method="xml" version="1.0" encoding="UTF-8" cdata-section-elements="artwork" />
50
51<!-- kick into cleanup mode -->
52<xsl:template match="/">
53  <xsl:text>&#10;</xsl:text>
54  <xsl:comment>
55    This XML document is the output of clean-for-DTD.xslt; a tool that strips
56    extensions to RFC2629(bis) from documents for processing with xml2rfc.
57</xsl:comment>
58  <xsl:apply-templates select="/" mode="cleanup"/>
59</xsl:template>
60
61<!-- rules for identity transformations -->
62
63<xsl:template match="processing-instruction()" mode="cleanup">
64  <xsl:text>&#10;</xsl:text>
65  <xsl:copy/>
66</xsl:template>
67
68<xsl:template match="comment()|@*" mode="cleanup"><xsl:copy/></xsl:template>
69
70<xsl:template match="text()" mode="cleanup"><xsl:copy/></xsl:template>
71
72<xsl:template match="/" mode="cleanup">
73        <xsl:copy><xsl:apply-templates select="node()" mode="cleanup" /></xsl:copy>
74</xsl:template>
75
76<xsl:template match="*" mode="cleanup">
77  <xsl:element name="{local-name()}">
78        <xsl:apply-templates select="node()|@*" mode="cleanup" />
79  </xsl:element>
80</xsl:template>
81
82
83<!-- remove PI extensions -->
84
85<xsl:template match="processing-instruction('rfc-ext')" mode="cleanup"/>
86
87<!-- add issues appendix -->
88
89<xsl:template match="back" mode="cleanup">
90  <back>
91    <xsl:apply-templates select="node()|@*" mode="cleanup" />
92    <xsl:if test="not(/*/@ed:suppress-issue-appendix='yes') and //ed:issue[@status='closed']">
93      <section title="Resolved issues (to be removed by RFC Editor before publication)">
94        <t>
95          Issues that were either rejected or resolved in this version of this
96          document.
97        </t>
98        <xsl:apply-templates select="//ed:issue[@status='closed']" mode="issues" />
99      </section>
100    </xsl:if>
101    <xsl:if test="not(/*/@ed:suppress-issue-appendix='yes') and //ed:issue[@status='open']">
102      <section title="Open issues (to be removed by RFC Editor prior to publication)">
103        <xsl:apply-templates select="//ed:issue[@status!='closed']" mode="issues" />
104      </section>
105    </xsl:if>
106  </back>
107</xsl:template>
108
109
110
111
112<!-- extensions -->
113
114<xsl:template match="x:abnf-char-sequence" mode="cleanup">
115  <xsl:choose>
116    <xsl:when test="substring(.,1,1) != '&quot;' or substring(.,string-length(.),1) != '&quot;'">
117      <xsl:call-template name="error">
118        <xsl:with-param name="msg" select="'contents of x:abnf-char-sequence needs to be quoted.'" />
119      </xsl:call-template>
120    </xsl:when>
121    <xsl:otherwise>
122      <xsl:text>%x</xsl:text>
123      <xsl:call-template name="to-abnf-char-sequence">
124        <xsl:with-param name="chars" select="substring(.,2,string-length(.)-2)"/>
125      </xsl:call-template>
126    </xsl:otherwise>
127  </xsl:choose>
128</xsl:template>
129
130<xsl:template match="x:anchor-alias" mode="cleanup"/>
131
132<xsl:template match="x:bcp14" mode="cleanup">
133  <xsl:apply-templates/>
134</xsl:template>
135
136<xsl:template match="x:assign-section-number" mode="cleanup"/> 
137<xsl:template match="x:link" mode="cleanup"/>
138<xsl:template match="x:source" mode="cleanup"/>
139
140<xsl:template match="x:parse-xml" mode="cleanup">
141  <xsl:apply-templates/>
142</xsl:template>
143
144<xsl:template match="x:ref" mode="cleanup">
145  <xsl:variable name="val" select="."/>
146  <xsl:variable name="target" select="//*[@anchor and (@anchor=$val or x:anchor-alias/@value=$val)]"/>
147  <xsl:choose>
148    <xsl:when test="$target">
149      <xsl:variable name="current" select="."/>
150      <xsl:for-each select="$target">
151        <!-- make it the context -->
152        <xsl:choose>
153          <xsl:when test="self::preamble">
154            <!-- it's not an element we can link to -->
155            <xsl:call-template name="warning">
156              <xsl:with-param name="inline" select="'no'"/>
157              <xsl:with-param name="msg">couldn't create the link as <xsl:value-of select="name()"/> does not support the anchor attribute.</xsl:with-param>
158            </xsl:call-template>
159            <xsl:value-of select="$current"/>
160          </xsl:when>
161          <xsl:otherwise>
162            <xref target="{$target/@anchor}" format="none"><xsl:value-of select="$current"/></xref>
163          </xsl:otherwise>
164        </xsl:choose>
165      </xsl:for-each>
166    </xsl:when>
167    <xsl:otherwise>
168      <xsl:call-template name="warning">
169        <xsl:with-param name="inline" select="'no'"/>
170        <xsl:with-param name="msg">internal link target for '<xsl:value-of select="."/>' does not exist.</xsl:with-param>
171      </xsl:call-template>
172      <xsl:value-of select="."/>
173    </xsl:otherwise>
174  </xsl:choose>
175</xsl:template>
176
177<xsl:template match="x:blockquote" mode="cleanup">
178  <t><list>
179    <xsl:apply-templates mode="cleanup" />
180  </list></t>
181</xsl:template>
182
183<xsl:template match="x:h" mode="cleanup">
184  <xsl:apply-templates mode="cleanup" />
185</xsl:template>
186
187<xsl:template match="x:highlight" mode="cleanup">
188  <xsl:apply-templates mode="cleanup" />
189</xsl:template>
190
191<xsl:template match="x:lt" mode="cleanup">
192  <t>
193    <xsl:apply-templates select="@hangText|@anchor" mode="cleanup"/>
194    <xsl:for-each select="t">
195      <xsl:apply-templates mode="cleanup"/>
196      <xsl:if test="position()!=last()">
197        <vspace blankLines="1"/>
198      </xsl:if>
199    </xsl:for-each>
200  </t>
201</xsl:template>
202
203<xsl:template match="x:note" mode="cleanup">
204  <t>
205    <list>
206      <xsl:apply-templates mode="cleanup"/>
207    </list>
208  </t>
209</xsl:template>
210
211<xsl:template match="x:q" mode="cleanup">
212  <xsl:text>"</xsl:text>
213  <xsl:apply-templates mode="cleanup"/>
214  <xsl:text>"</xsl:text>
215</xsl:template>
216
217<xsl:template match="x:dfn" mode="cleanup">
218  <!-- help xml2rfc to keep dfn and following text on the same page -->
219  <xsl:if test="not(preceding-sibling::x:dfn) and count(following-sibling::list)=1">
220    <xsl:processing-instruction name="rfc">needLines="4"</xsl:processing-instruction>
221  </xsl:if>
222  <xsl:apply-templates mode="cleanup"/>
223</xsl:template>
224
225<xsl:template match="x:sup" mode="cleanup">
226  <xsl:text>^</xsl:text>
227  <xsl:apply-templates mode="cleanup" />
228</xsl:template>
229
230<xsl:template match="author/@anchor" mode="cleanup"/>
231<xsl:template match="x:include-author" mode="cleanup">
232  <t>
233    <xsl:value-of select="/*/front/author[@anchor=current()/@target]"/>
234  </t>
235  <t>
236    (see Authors Section)
237  </t>
238</xsl:template>
239
240<!-- extended reference formatting -->
241
242<xsl:template match="xref[@x:* and not(node())]" mode="cleanup">
243  <xsl:call-template name="insert-iref-for-xref"/>
244  <xsl:variable name="node" select="$src//*[@anchor=current()/@target]" />
245
246  <xsl:variable name="sec">
247    <xsl:choose>
248      <xsl:when test="starts-with(@x:rel,'#') and not(@x:sec) and $node/x:source/@href">
249        <xsl:variable name="extdoc" select="document($node/x:source/@href)"/>
250        <xsl:for-each select="$extdoc//*[@anchor=substring-after(current()/@x:rel,'#')]">
251          <xsl:call-template name="get-section-number"/>
252        </xsl:for-each>
253      </xsl:when>
254      <xsl:otherwise>
255        <xsl:value-of select="@x:sec"/>
256      </xsl:otherwise>
257    </xsl:choose>
258  </xsl:variable>
259
260  <xsl:variable name="secterm">
261    <xsl:choose>
262      <!-- starts with letter? -->
263      <xsl:when test="translate(substring($sec,1,1),$ucase,'')=''">Appendix</xsl:when>
264      <xsl:otherwise>Section</xsl:otherwise>
265    </xsl:choose>
266  </xsl:variable>
267
268  <xsl:variable name="fmt">
269    <xsl:choose>
270      <xsl:when test="@x:fmt!=''"><xsl:value-of select="@x:fmt"/></xsl:when>
271      <xsl:when test="ancestor::artwork">,</xsl:when>
272      <xsl:otherwise>of</xsl:otherwise>
273    </xsl:choose>
274  </xsl:variable>
275
276  <xsl:choose>
277    <xsl:when test="$fmt=','">
278      <xref>
279        <xsl:apply-templates select="@target|@format|@pageno|text()|*" mode="cleanup"/>
280      </xref>
281      <xsl:text>, </xsl:text>
282      <xsl:value-of select="$secterm"/>
283      <xsl:text> </xsl:text>
284      <xsl:value-of select="$sec"/>
285    </xsl:when>
286    <xsl:when test="$fmt='sec'">
287      <xsl:value-of select="$secterm"/>
288      <xsl:text> </xsl:text>
289      <xsl:value-of select="$sec"/>
290    </xsl:when>
291    <xsl:when test="$fmt='number'">
292      <xsl:value-of select="$sec"/>
293    </xsl:when>
294    <xsl:when test="$fmt='()'">
295      <xref>
296        <xsl:apply-templates select="@target|@format|@pageno|text()|*" mode="cleanup"/>
297      </xref>
298      <xsl:text> (</xsl:text>
299      <xsl:value-of select="$secterm"/>
300      <xsl:text> </xsl:text>
301      <xsl:value-of select="$sec"/>
302      <xsl:text>)</xsl:text>
303    </xsl:when>
304    <xsl:when test="$fmt='of'">
305      <xsl:value-of select="$secterm"/>
306      <xsl:text> </xsl:text>
307      <xsl:value-of select="$sec"/>
308      <xsl:text> of </xsl:text>
309      <xref>
310        <xsl:apply-templates select="@target|@format|@pageno|text()|*" mode="cleanup"/>
311      </xref>
312    </xsl:when>
313    <xsl:when test="$fmt='anchor'">
314      <xsl:variable name="val">
315        <xsl:call-template name="referencename">
316          <xsl:with-param name="node" select="$node" />
317        </xsl:call-template>
318      </xsl:variable>
319      <!-- remove brackets -->
320      <xsl:value-of select="substring($val,2,string-length($val)-2)"/>
321    </xsl:when>
322    <xsl:otherwise>
323      <xsl:copy>
324        <xsl:apply-templates select="node()" mode="cleanup"/>
325      </xsl:copy>
326    </xsl:otherwise>
327  </xsl:choose>
328</xsl:template>
329
330<xsl:template match="xref[@x:fmt and node()]" mode="cleanup">
331  <xsl:call-template name="insert-iref-for-xref"/>
332  <xsl:choose>
333    <xsl:when test="@x:fmt='none'">
334      <xsl:apply-templates mode="cleanup"/>
335    </xsl:when>
336    <xsl:when test="not(@x:fmt)">
337      <xref>
338        <xsl:copy-of select="@target|@format"/>
339        <xsl:apply-templates mode="cleanup"/>
340      </xref>
341    </xsl:when>
342    <xsl:otherwise>
343      <xsl:message>Unsupported x:fmt attribute.</xsl:message>
344    </xsl:otherwise>
345  </xsl:choose>
346</xsl:template>
347
348<xsl:template match="xref[node() and (@target=//preamble/@anchor or @target=//spanx/@anchor)]" mode="cleanup">
349  <!-- remove the link -->
350  <xsl:apply-templates select="node()" mode="cleanup"/>
351</xsl:template>
352
353<xsl:template match="xref[not(node()) and (@target=//preamble/@anchor or @target=//spanx/@anchor)]" mode="cleanup">
354  <!-- fatal -->
355  <xsl:message terminate="yes">Broken xref <xsl:value-of select="@target"/> due to target being filtered out.</xsl:message>
356</xsl:template>
357
358<xsl:template match="xref" mode="cleanup" priority="0">
359  <xsl:call-template name="insert-iref-for-xref"/>
360  <xref>
361    <xsl:copy-of select="@target|@format"/>
362    <xsl:apply-templates mode="cleanup"/>
363  </xref>
364</xsl:template>
365
366<xsl:template name="insert-iref-for-xref">
367  <xsl:if test="$xml2rfc-ext-include-references-in-index='yesxxx'">
368    <xsl:if test="@target=/rfc/back//reference/@anchor">
369      <iref item="{@target}"/>
370      <xsl:if test="@x:sec">
371        <xsl:choose>
372          <xsl:when test="translate(substring(@x:sec,1,1),$ucase,'')=''">
373            <iref item="{@target}" subitem="Appendix {@x:sec}"/>
374          </xsl:when>
375          <xsl:otherwise>
376            <iref item="{@target}" subitem="Section {@x:sec}"/>
377          </xsl:otherwise>
378        </xsl:choose>
379      </xsl:if>
380    </xsl:if>
381  </xsl:if>
382</xsl:template>
383
384<!-- issue tracking extensions -->
385
386<xsl:template match="@xml:lang" mode="cleanup"/>
387<xsl:template match="@xml:lang" />
388
389<xsl:template match="ed:*" mode="cleanup"/>
390<xsl:template match="ed:*" />
391
392<xsl:template match="@ed:*" mode="cleanup"/>
393<xsl:template match="@ed:*" />
394
395<xsl:template match="ed:annotation" mode="cleanup" />
396
397<xsl:template match="ed:replace" mode="cleanup">
398  <xsl:apply-templates mode="cleanup" />
399</xsl:template>
400
401<xsl:template match="ed:replace">
402  <xsl:apply-templates/>
403</xsl:template>
404
405<xsl:template match="ed:ins" mode="cleanup">
406  <xsl:apply-templates mode="cleanup"/>
407</xsl:template>
408
409<xsl:template match="ed:ins">
410  <xsl:apply-templates/>
411</xsl:template>
412
413<xsl:template match="ed:issue" mode="issues">
414  <section title="{@name}">
415    <xsl:variable name="sec">
416      <xsl:call-template name="get-section-number"/>
417    </xsl:variable>
418
419    <xsl:if test="$sec!=''">
420      <t>
421        In Section <xsl:value-of select="$sec"/>:
422      </t>
423    </xsl:if>
424   
425    <t>
426      Type: <xsl:value-of select="@type" />
427    </t>
428    <xsl:if test="@href">
429      <t>
430        <!-- temp. removed because of xml2rfc's handling of erefs when producing TXT-->
431        <!--<eref target="{@href}" /> -->
432        <xsl:text>&lt;</xsl:text>
433        <xsl:value-of select="@href"/>
434        <xsl:text>></xsl:text>
435        <xsl:if test="@alternate-href">
436          <xsl:text>, &lt;</xsl:text>
437          <xsl:value-of select="@alternate-href"/>
438          <xsl:text>></xsl:text>
439        </xsl:if>
440      </t>
441    </xsl:if>
442    <xsl:for-each select="ed:item">
443      <t>
444        <xsl:if test="@entered-by or @date">
445          <xsl:choose>
446            <xsl:when test="not(@entered-by)">
447              <xsl:value-of select="concat('(',@date,') ')" />
448            </xsl:when>
449            <xsl:when test="not(@date)">
450              <xsl:value-of select="concat(@entered-by,': ')" />
451            </xsl:when>
452            <xsl:otherwise>
453              <xsl:value-of select="concat(@entered-by,' (',@date,'): ')" />
454            </xsl:otherwise>
455          </xsl:choose>     
456        </xsl:if>
457        <xsl:if test="not(xhtml:p)">
458          <xsl:apply-templates select="node()" mode="issues"/>
459        </xsl:if>
460      </t>
461      <xsl:if test="xhtml:p|xhtml:pre">
462        <xsl:for-each select="node()">
463          <xsl:choose>
464            <xsl:when test="self::xhtml:p">
465              <t>
466                <xsl:apply-templates select="node()" mode="issues"/>
467              </t>
468            </xsl:when>
469            <xsl:when test="self::xhtml:pre">
470              <figure>
471                <artwork><xsl:apply-templates select="node()" mode="issues"/></artwork>
472              </figure>
473            </xsl:when>
474            <xsl:otherwise>
475              <t>
476                <xsl:apply-templates select="." mode="issues"/>
477              </t>
478            </xsl:otherwise>
479          </xsl:choose>
480        </xsl:for-each>
481      </xsl:if>
482    </xsl:for-each> 
483    <xsl:if test="ed:resolution">
484      <t>
485        <xsl:text>Resolution</xsl:text>
486        <xsl:if test="ed:resolution/@datetime"> (<xsl:value-of select="ed:resolution/@datetime"/>)</xsl:if>
487        <xsl:text>: </xsl:text>
488        <xsl:value-of select="ed:resolution" />
489      </t>
490    </xsl:if>
491  </section>
492</xsl:template>
493
494<xsl:template match="ed:issueref" mode="cleanup">
495  <xsl:apply-templates mode="cleanup"/>
496</xsl:template>
497
498<xsl:template match="*" mode="issues">
499  <xsl:apply-templates mode="issues"/>
500</xsl:template>
501
502<xsl:template match="xhtml:q" mode="issues">
503  <list><t>
504    <xsl:text>"</xsl:text>
505    <xsl:apply-templates mode="issues"/>
506    <xsl:text>"</xsl:text>
507    <xsl:if test="@cite">
508      <xsl:text> -- </xsl:text>
509      <eref target="{@cite}"><xsl:value-of select="@cite"/></eref>
510    </xsl:if>
511  </t></list>
512</xsl:template>
513
514<xsl:template match="xhtml:br" mode="issues">
515  <vspace/>
516</xsl:template>
517
518<xsl:template match="xhtml:del" mode="issues">
519  <xsl:text>&lt;del></xsl:text>
520    <xsl:apply-templates mode="issues"/>
521  <xsl:text>&lt;/del></xsl:text>
522</xsl:template>
523
524<xsl:template match="xhtml:em" mode="issues">
525  <spanx style="emph">
526    <xsl:apply-templates mode="issues"/>
527  </spanx>
528</xsl:template>
529
530<xsl:template match="xhtml:ins" mode="issues">
531  <xsl:text>&lt;ins></xsl:text>
532    <xsl:apply-templates mode="issues"/>
533  <xsl:text>&lt;/ins></xsl:text>
534</xsl:template>
535
536<xsl:template match="xhtml:tt" mode="issues">
537  <xsl:apply-templates mode="issues"/>
538</xsl:template>
539
540<xsl:template match="ed:eref" mode="issues">
541  <xsl:text>&lt;</xsl:text>
542  <xsl:value-of select="."/>
543  <xsl:text>&gt;</xsl:text>
544</xsl:template>
545
546<xsl:template match="ed:issueref" mode="issues">
547  <xsl:apply-templates mode="issues"/>
548</xsl:template>
549
550<xsl:template match="text()" mode="issues">
551  <xsl:value-of select="." />
552</xsl:template>
553
554
555
556<!-- markup inside artwork element -->
557
558<xsl:template match="figure[.//artwork//iref | .//artwork//xref]" mode="cleanup">
559  <!-- move up iref elements -->
560  <xsl:for-each select=".//artwork//xref">
561    <xsl:if test="not(ancestor::ed:del)">
562      <xsl:call-template name="insert-iref-for-xref"/>
563    </xsl:if>
564  </xsl:for-each>
565  <figure>
566    <xsl:apply-templates select="@*" mode="cleanup" />
567    <xsl:apply-templates select=".//artwork//iref" mode="cleanup"/>
568    <xsl:apply-templates select="iref|preamble|artwork|postamble|ed:replace|ed:ins|ed:del" mode="cleanup" />
569  </figure>
570</xsl:template>
571
572<xsl:template match="artwork" mode="cleanup">
573  <xsl:variable name="content2"><xsl:apply-templates select="."/></xsl:variable>
574  <xsl:variable name="content" select="translate($content2,'&#160;&#x2500;&#x2502;&#x2508;&#x250c;&#x2510;&#x2514;&#x2518;&#x251c;&#x2524;',' -|+++++++')"/>
575  <artwork>
576    <xsl:apply-templates select="@*" mode="cleanup" />
577    <xsl:if test="starts-with(.,'&#10;')">
578      <xsl:text>&#10;</xsl:text>
579      <xsl:value-of select="@x:indent-with"/>
580    </xsl:if>
581    <xsl:choose>
582      <xsl:when test="@x:indent-with!=''">
583        <xsl:call-template name="indent">
584          <xsl:with-param name="content" select="$content"/>
585          <xsl:with-param name="with" select="@x:indent-with"/>
586        </xsl:call-template>
587      </xsl:when>
588      <xsl:otherwise>
589        <xsl:value-of select="$content"/>
590      </xsl:otherwise>
591    </xsl:choose>
592  </artwork> 
593</xsl:template>
594
595<xsl:template match="@x:indent-with" mode="cleanup"/>
596
597<xsl:template name="indent">
598  <xsl:param name="content"/>
599  <xsl:param name="with"/>
600
601  <xsl:value-of select="substring($content,1,1)"/>
602  <xsl:if test="substring($content,1,1)='&#10;'">
603    <xsl:value-of select="$with"/>
604  </xsl:if>
605 
606  <xsl:choose>
607    <xsl:when test="$content=''" />
608    <xsl:otherwise>
609      <xsl:call-template name="indent">
610        <xsl:with-param name="content" select="substring($content,2)"/>
611        <xsl:with-param name="with" select="$with"/>
612      </xsl:call-template>
613    </xsl:otherwise>
614  </xsl:choose>
615 
616</xsl:template>
617
618<!-- email repititions -->
619<xsl:template match="email" mode="cleanup">
620  <!-- combine in a single element -->
621  <xsl:if test="not(preceding-sibling::email)">
622    <email>
623      <xsl:for-each select="../email">
624        <xsl:value-of select="."/>
625        <xsl:if test="position()!=last()">
626          <xsl:text>, </xsl:text>
627        </xsl:if>
628      </xsl:for-each>
629    </email>
630  </xsl:if>
631</xsl:template>
632
633<!-- markup inside cref -->
634<xsl:template match="cref//eref" mode="cleanup">
635  <xsl:text>&lt;</xsl:text>
636  <xsl:value-of select="@target"/>
637  <xsl:text>&gt;</xsl:text>
638</xsl:template>
639
640<!-- artwork extensions -->
641<xsl:template match="artwork/@x:extraction-note" mode="cleanup"/>
642
643<!-- list formatting -->
644<xsl:template match="list/@x:indent" mode="cleanup"/>
645
646<!-- referencing extensions -->
647<xsl:template match="iref/@x:for-anchor" mode="cleanup"/>
648
649<!-- table styles -->
650<xsl:template match="texttable/@style" mode="cleanup"/>
651
652<!-- section numbering -->
653<xsl:template match="section/@x:fixed-section-number" mode="cleanup"/>
654
655<!-- GRRDL info stripped -->
656<xsl:template match="@grddl:transformation" mode="cleanup"/>
657
658<!-- maturity level stripped -->
659<xsl:template match="@x:maturity-level" mode="cleanup"/>
660
661<!-- RDF info stripped -->
662<xsl:template match="rdf:*" mode="cleanup"/>
663
664<!-- cases where xml2rfc does not allow anchors -->
665<xsl:template match="preamble/@anchor" mode="cleanup"/>
666<xsl:template match="spanx/@anchor" mode="cleanup"/>
667
668</xsl:transform>
Note: See TracBrowser for help on using the repository browser.