source: rfc2629xslt/clean-for-DTD.xslt @ 308

Last change on this file since 308 was 308, checked in by julian.reschke@…, 11 years ago

update to latest version of rfc2629.xslt, annotate spec with intended maturity level

  • Property svn:eol-style set to native
File size: 18.0 KB
Line 
1<!--
2    Strip rfc2629.xslt extensions, generating XML input for MTR's xml2rfc
3
4    Copyright (c) 2006-2008, Julian Reschke (julian.reschke@greenbytes.de)
5    All rights reserved.
6
7    Redistribution and use in source and binary forms, with or without
8    modification, are permitted provided that the following conditions are met:
9
10    * Redistributions of source code must retain the above copyright notice,
11      this list of conditions and the following disclaimer.
12    * Redistributions in binary form must reproduce the above copyright notice,
13      this list of conditions and the following disclaimer in the documentation
14      and/or other materials provided with the distribution.
15    * Neither the name of Julian Reschke nor the names of its contributors
16      may be used to endorse or promote products derived from this software
17      without specific prior written permission.
18
19    THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
20    AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
21    IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
22    ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR CONTRIBUTORS BE
23    LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
24    CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
25    SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
26    INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
27    CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
28    ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
29    POSSIBILITY OF SUCH DAMAGE.
30-->
31
32<xsl:transform xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
33                version="1.0"
34                xmlns:ed="http://greenbytes.de/2002/rfcedit"
35                xmlns:grddl="http://www.w3.org/2003/g/data-view#"
36                xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#"
37                xmlns:x="http://purl.org/net/xml2rfc/ext"
38                xmlns:xhtml="http://www.w3.org/1999/xhtml"
39                exclude-result-prefixes="ed grddl rdf x xhtml"
40>
41
42<!-- re-use some of the default RFC2629.xslt rules -->
43<xsl:import href="rfc2629.xslt"/>
44
45<!-- undo strip-space decls -->
46<xsl:preserve-space elements="*"/>
47
48<!-- generate DTD-valid output, override all values imported from rfc2629.xslt -->
49<xsl:output doctype-system="rfc2629.dtd" doctype-public="" method="xml" version="1.0" encoding="UTF-8" cdata-section-elements="artwork" />
50
51<!-- kick into cleanup mode -->
52<xsl:template match="/">
53  <xsl:text>&#10;</xsl:text>
54  <xsl:comment>
55    This XML document is the output of clean-for-DTD.xslt; a tool that strips
56    extensions to RFC2629(bis) from documents for processing with xml2rfc.
57</xsl:comment>
58  <xsl:apply-templates select="/" mode="cleanup"/>
59</xsl:template>
60
61<!-- rules for identity transformations -->
62
63<xsl:template match="processing-instruction()" mode="cleanup">
64  <xsl:text>&#10;</xsl:text>
65  <xsl:copy/>
66</xsl:template>
67
68<xsl:template match="comment()|@*" mode="cleanup"><xsl:copy/></xsl:template>
69
70<xsl:template match="text()" mode="cleanup"><xsl:copy/></xsl:template>
71
72<xsl:template match="/" mode="cleanup">
73        <xsl:copy><xsl:apply-templates select="node()" mode="cleanup" /></xsl:copy>
74</xsl:template>
75
76<xsl:template match="*" mode="cleanup">
77  <xsl:element name="{local-name()}">
78        <xsl:apply-templates select="node()|@*" mode="cleanup" />
79  </xsl:element>
80</xsl:template>
81
82
83<!-- remove PI extensions -->
84
85<xsl:template match="processing-instruction('rfc-ext')" mode="cleanup"/>
86
87<!-- add issues appendix -->
88
89<xsl:template match="back" mode="cleanup">
90  <back>
91    <xsl:apply-templates select="node()|@*" mode="cleanup" />
92    <xsl:if test="not(/*/@ed:suppress-issue-appendix='yes') and //ed:issue[@status='closed']">
93      <section title="Resolved issues (to be removed by RFC Editor before publication)">
94        <t>
95          Issues that were either rejected or resolved in this version of this
96          document.
97        </t>
98        <xsl:apply-templates select="//ed:issue[@status='closed']" mode="issues" />
99      </section>
100    </xsl:if>
101    <xsl:if test="not(/*/@ed:suppress-issue-appendix='yes') and //ed:issue[@status='open']">
102      <section title="Open issues (to be removed by RFC Editor prior to publication)">
103        <xsl:apply-templates select="//ed:issue[@status!='closed']" mode="issues" />
104      </section>
105    </xsl:if>
106  </back>
107</xsl:template>
108
109
110
111
112<!-- extensions -->
113
114<xsl:template match="x:abnf-char-sequence" mode="cleanup">
115  <xsl:choose>
116    <xsl:when test="substring(.,1,1) != '&quot;' or substring(.,string-length(.),1) != '&quot;'">
117      <xsl:call-template name="error">
118        <xsl:with-param name="msg" select="'contents of x:abnf-char-sequence needs to be quoted.'" />
119      </xsl:call-template>
120    </xsl:when>
121    <xsl:otherwise>
122      <xsl:text>%x</xsl:text>
123      <xsl:call-template name="to-abnf-char-sequence">
124        <xsl:with-param name="chars" select="substring(.,2,string-length(.)-2)"/>
125      </xsl:call-template>
126    </xsl:otherwise>
127  </xsl:choose>
128</xsl:template>
129
130<xsl:template match="x:anchor-alias" mode="cleanup"/>
131
132<xsl:template match="x:bcp14" mode="cleanup">
133  <xsl:apply-templates/>
134</xsl:template>
135
136<xsl:template match="x:assign-section-number" mode="cleanup"/> 
137<xsl:template match="x:link" mode="cleanup"/>
138<xsl:template match="x:source" mode="cleanup"/>
139
140<xsl:template match="x:parse-xml" mode="cleanup">
141  <xsl:apply-templates/>
142</xsl:template>
143
144<xsl:template match="x:ref" mode="cleanup">
145  <xsl:variable name="val" select="."/>
146  <xsl:variable name="target" select="//*[@anchor and (@anchor=$val or x:anchor-alias/@value=$val)]"/>
147  <xsl:choose>
148    <xsl:when test="$target">
149      <xsl:variable name="current" select="."/>
150      <xsl:for-each select="$target">
151        <!-- make it the context -->
152        <xsl:choose>
153          <xsl:when test="self::preamble">
154            <!-- it's not an element we can link to -->
155            <xsl:comment>clean-for-DTD.xslt warning: couldn't create the link as <xsl:value-of select="name()"/> does not support the anchor attribute.</xsl:comment>
156            <xsl:value-of select="$current"/>
157          </xsl:when>
158          <xsl:otherwise>
159            <xref target="{$target/@anchor}" format="none"><xsl:value-of select="$current"/></xref>
160          </xsl:otherwise>
161        </xsl:choose>
162      </xsl:for-each>
163    </xsl:when>
164    <xsl:otherwise>
165      <xsl:message>WARNING: internal link target for '<xsl:value-of select="."/>' does not exist.</xsl:message>
166      <xsl:value-of select="."/>
167    </xsl:otherwise>
168  </xsl:choose>
169</xsl:template>
170
171<xsl:template match="x:blockquote" mode="cleanup">
172  <t><list>
173    <xsl:apply-templates mode="cleanup" />
174  </list></t>
175</xsl:template>
176
177<xsl:template match="x:h" mode="cleanup">
178  <xsl:apply-templates mode="cleanup" />
179</xsl:template>
180
181<xsl:template match="x:lt" mode="cleanup">
182  <t>
183    <xsl:apply-templates select="@hangText|@anchor" mode="cleanup"/>
184    <xsl:for-each select="t">
185      <xsl:apply-templates mode="cleanup"/>
186      <xsl:if test="position()!=last()">
187        <vspace blankLines="1"/>
188      </xsl:if>
189    </xsl:for-each>
190  </t>
191</xsl:template>
192
193<xsl:template match="x:q" mode="cleanup">
194  <xsl:text>"</xsl:text>
195  <xsl:apply-templates mode="cleanup"/>
196  <xsl:text>"</xsl:text>
197</xsl:template>
198
199<xsl:template match="x:dfn" mode="cleanup">
200  <xsl:apply-templates mode="cleanup"/>
201</xsl:template>
202
203<xsl:template match="x:sup" mode="cleanup">
204  <xsl:text>^</xsl:text>
205  <xsl:apply-templates mode="cleanup" />
206</xsl:template>
207
208<!-- extended reference formatting -->
209
210<xsl:template match="xref[@x:* and not(node())]" mode="cleanup">
211  <xsl:variable name="node" select="$src//*[@anchor=current()/@target]" />
212
213  <xsl:variable name="sec">
214    <xsl:choose>
215      <xsl:when test="starts-with(@x:rel,'#') and not(@x:sec) and $node/x:source/@href">
216        <xsl:variable name="extdoc" select="document($node/x:source/@href)"/>
217        <xsl:for-each select="$extdoc//*[@anchor=substring-after(current()/@x:rel,'#')]">
218          <xsl:call-template name="get-section-number"/>
219        </xsl:for-each>
220      </xsl:when>
221      <xsl:otherwise>
222        <xsl:value-of select="@x:sec"/>
223      </xsl:otherwise>
224    </xsl:choose>
225  </xsl:variable>
226
227  <xsl:variable name="secterm">
228    <xsl:choose>
229      <!-- starts with letter? -->
230      <xsl:when test="translate(substring($sec,1,1),$ucase,'')=''">Appendix</xsl:when>
231      <xsl:otherwise>Section</xsl:otherwise>
232    </xsl:choose>
233  </xsl:variable>
234
235  <xsl:variable name="fmt">
236    <xsl:choose>
237      <xsl:when test="@x:fmt!=''"><xsl:value-of select="@x:fmt"/></xsl:when>
238      <xsl:when test="ancestor::artwork">,</xsl:when>
239      <xsl:otherwise>of</xsl:otherwise>
240    </xsl:choose>
241  </xsl:variable>
242
243  <xsl:choose>
244    <xsl:when test="$fmt=','">
245      <xref>
246        <xsl:apply-templates select="@target|@format|@pageno|text()|*" mode="cleanup"/>
247      </xref>
248      <xsl:text>, </xsl:text>
249      <xsl:value-of select="$secterm"/>
250      <xsl:text> </xsl:text>
251      <xsl:value-of select="$sec"/>
252    </xsl:when>
253    <xsl:when test="$fmt='sec'">
254      <xsl:value-of select="$secterm"/>
255      <xsl:text> </xsl:text>
256      <xsl:value-of select="$sec"/>
257    </xsl:when>
258    <xsl:when test="$fmt='number'">
259      <xsl:value-of select="$sec"/>
260    </xsl:when>
261    <xsl:when test="$fmt='()'">
262      <xref>
263        <xsl:apply-templates select="@target|@format|@pageno|text()|*" mode="cleanup"/>
264      </xref>
265      <xsl:text> (</xsl:text>
266      <xsl:value-of select="$secterm"/>
267      <xsl:text> </xsl:text>
268      <xsl:value-of select="$sec"/>
269      <xsl:text>)</xsl:text>
270    </xsl:when>
271    <xsl:when test="$fmt='of'">
272      <xsl:value-of select="$secterm"/>
273      <xsl:text> </xsl:text>
274      <xsl:value-of select="$sec"/>
275      <xsl:text> of </xsl:text>
276      <xref>
277        <xsl:apply-templates select="@target|@format|@pageno|text()|*" mode="cleanup"/>
278      </xref>
279    </xsl:when>
280    <xsl:when test="$fmt='anchor'">
281      <xsl:variable name="val">
282        <xsl:call-template name="referencename">
283          <xsl:with-param name="node" select="$node" />
284        </xsl:call-template>
285      </xsl:variable>
286      <!-- remove brackets -->
287      <xsl:value-of select="substring($val,2,string-length($val)-2)"/>
288    </xsl:when>
289    <xsl:otherwise>
290      <xsl:copy>
291        <xsl:apply-templates select="node()" mode="cleanup"/>
292      </xsl:copy>
293    </xsl:otherwise>
294  </xsl:choose>
295</xsl:template>
296
297<xsl:template match="xref[@x:fmt and node()]" mode="cleanup">
298  <xsl:choose>
299    <xsl:when test="@x:fmt='none'">
300      <xsl:apply-templates mode="cleanup"/>
301    </xsl:when>
302    <xsl:when test="not(@x:fmt)">
303      <xref>
304        <xsl:copy-of select="@target|@format"/>
305        <xsl:apply-templates mode="cleanup"/>
306      </xref>
307    </xsl:when>
308    <xsl:otherwise>
309      <xsl:message>Unsupported x:fmt attribute.</xsl:message>
310    </xsl:otherwise>
311  </xsl:choose>
312</xsl:template>
313
314<xsl:template match="xref[node() and @target=//preamble/@anchor]" mode="cleanup">
315  <!-- remove the link -->
316  <xsl:apply-templates select="node()" mode="cleanup"/>
317</xsl:template>
318
319<xsl:template match="xref[not(node()) and @target=//preamble/@anchor]" mode="cleanup">
320  <!-- fatal -->
321  <xsl:message>Broken xref due to target being filtered out.</xsl:message>
322</xsl:template>
323
324<!-- issue tracking extensions -->
325
326<xsl:template match="@xml:lang" mode="cleanup"/>
327<xsl:template match="@xml:lang" />
328
329<xsl:template match="ed:*" mode="cleanup"/>
330<xsl:template match="ed:*" />
331
332<xsl:template match="@ed:*" mode="cleanup"/>
333<xsl:template match="@ed:*" />
334
335<xsl:template match="ed:annotation" mode="cleanup" />
336
337<xsl:template match="ed:replace" mode="cleanup">
338  <xsl:apply-templates mode="cleanup" />
339</xsl:template>
340
341<xsl:template match="ed:replace">
342  <xsl:apply-templates/>
343</xsl:template>
344
345<xsl:template match="ed:ins" mode="cleanup">
346  <xsl:apply-templates mode="cleanup"/>
347</xsl:template>
348
349<xsl:template match="ed:ins">
350  <xsl:apply-templates/>
351</xsl:template>
352
353<xsl:template match="ed:issue" mode="issues">
354  <section title="{@name}">
355    <xsl:variable name="sec">
356      <xsl:call-template name="get-section-number"/>
357    </xsl:variable>
358
359    <xsl:if test="$sec!=''">
360      <t>
361        In Section <xsl:value-of select="$sec"/>:
362      </t>
363    </xsl:if>
364   
365    <t>
366      Type: <xsl:value-of select="@type" />
367    </t>
368    <xsl:if test="@href">
369      <t>
370        <!-- temp. removed because of xml2rfc's handling of erefs when producing TXT-->
371        <!--<eref target="{@href}" /> -->
372        <xsl:text>&lt;</xsl:text>
373        <xsl:value-of select="@href"/>
374        <xsl:text>></xsl:text>
375        <xsl:if test="@alternate-href">
376          <xsl:text>, &lt;</xsl:text>
377          <xsl:value-of select="@alternate-href"/>
378          <xsl:text>></xsl:text>
379        </xsl:if>
380      </t>
381    </xsl:if>
382    <xsl:for-each select="ed:item">
383      <t>
384        <xsl:if test="@entered-by or @date">
385          <xsl:choose>
386            <xsl:when test="not(@entered-by)">
387              <xsl:value-of select="concat('(',@date,') ')" />
388            </xsl:when>
389            <xsl:when test="not(@date)">
390              <xsl:value-of select="concat(@entered-by,': ')" />
391            </xsl:when>
392            <xsl:otherwise>
393              <xsl:value-of select="concat(@entered-by,' (',@date,'): ')" />
394            </xsl:otherwise>
395          </xsl:choose>     
396        </xsl:if>
397        <xsl:if test="not(xhtml:p)">
398          <xsl:apply-templates select="node()" mode="issues"/>
399        </xsl:if>
400      </t>
401      <xsl:if test="xhtml:p|xhtml:pre">
402        <xsl:for-each select="node()">
403          <xsl:choose>
404            <xsl:when test="self::xhtml:p">
405              <t>
406                <xsl:apply-templates select="node()" mode="issues"/>
407              </t>
408            </xsl:when>
409            <xsl:when test="self::xhtml:pre">
410              <figure>
411                <artwork><xsl:apply-templates select="node()" mode="issues"/></artwork>
412              </figure>
413            </xsl:when>
414            <xsl:otherwise>
415              <t>
416                <xsl:apply-templates select="." mode="issues"/>
417              </t>
418            </xsl:otherwise>
419          </xsl:choose>
420        </xsl:for-each>
421      </xsl:if>
422    </xsl:for-each> 
423    <xsl:if test="ed:resolution">
424      <t>
425        <xsl:text>Resolution</xsl:text>
426        <xsl:if test="ed:resolution/@datetime"> (<xsl:value-of select="ed:resolution/@datetime"/>)</xsl:if>
427        <xsl:text>: </xsl:text>
428        <xsl:value-of select="ed:resolution" />
429      </t>
430    </xsl:if>
431  </section>
432</xsl:template>
433
434<xsl:template match="ed:issueref" mode="cleanup">
435  <xsl:apply-templates mode="cleanup"/>
436</xsl:template>
437
438<xsl:template match="*" mode="issues">
439  <xsl:apply-templates mode="issues"/>
440</xsl:template>
441
442<xsl:template match="xhtml:q" mode="issues">
443  <list><t>
444    <xsl:text>"</xsl:text>
445    <xsl:apply-templates mode="issues"/>
446    <xsl:text>"</xsl:text>
447    <xsl:if test="@cite">
448      <xsl:text> -- </xsl:text>
449      <eref target="{@cite}"><xsl:value-of select="@cite"/></eref>
450    </xsl:if>
451  </t></list>
452</xsl:template>
453
454<xsl:template match="xhtml:br" mode="issues">
455  <vspace/>
456</xsl:template>
457
458<xsl:template match="xhtml:del" mode="issues">
459  <xsl:text>&lt;del></xsl:text>
460    <xsl:apply-templates mode="issues"/>
461  <xsl:text>&lt;/del></xsl:text>
462</xsl:template>
463
464<xsl:template match="xhtml:em" mode="issues">
465  <spanx style="emph">
466    <xsl:apply-templates mode="issues"/>
467  </spanx>
468</xsl:template>
469
470<xsl:template match="xhtml:ins" mode="issues">
471  <xsl:text>&lt;ins></xsl:text>
472    <xsl:apply-templates mode="issues"/>
473  <xsl:text>&lt;/ins></xsl:text>
474</xsl:template>
475
476<xsl:template match="xhtml:tt" mode="issues">
477  <xsl:apply-templates mode="issues"/>
478</xsl:template>
479
480<xsl:template match="ed:eref" mode="issues">
481  <xsl:text>&lt;</xsl:text>
482  <xsl:value-of select="."/>
483  <xsl:text>&gt;</xsl:text>
484</xsl:template>
485
486<xsl:template match="ed:issueref" mode="issues">
487  <xsl:apply-templates mode="issues"/>
488</xsl:template>
489
490<xsl:template match="text()" mode="issues">
491  <xsl:value-of select="." />
492</xsl:template>
493
494
495
496<!-- markup inside artwork element -->
497
498<xsl:template match="figure[.//artwork//iref]" mode="cleanup">
499  <!-- move up iref elements -->
500  <figure>
501    <xsl:apply-templates select="@*" mode="cleanup" />
502    <xsl:apply-templates select=".//artwork//iref" mode="cleanup"/>
503    <xsl:apply-templates select="iref|preamble|artwork|postamble" mode="cleanup" />
504  </figure>
505</xsl:template>
506
507<xsl:template match="artwork" mode="cleanup">
508  <xsl:variable name="content"><xsl:apply-templates select="."/></xsl:variable>
509  <artwork>
510    <xsl:apply-templates select="@*" mode="cleanup" />
511    <xsl:if test="starts-with(.,'&#10;')">
512      <xsl:text>&#10;</xsl:text>
513    </xsl:if>
514    <xsl:value-of select="translate($content,'&#160;&#x2500;&#x2502;&#x2508;&#x250c;&#x2510;&#x2514;&#x2518;&#x251c;&#x2524;',' -|+++++++')"/>
515  </artwork> 
516</xsl:template>
517
518<!-- email repititions -->
519<xsl:template match="email" mode="cleanup">
520  <!-- combine in a single element -->
521  <xsl:if test="not(preceding-sibling::email)">
522    <email>
523      <xsl:for-each select="../email">
524        <xsl:value-of select="."/>
525        <xsl:if test="position()!=last()">
526          <xsl:text>, </xsl:text>
527        </xsl:if>
528      </xsl:for-each>
529    </email>
530  </xsl:if>
531</xsl:template>
532
533<!-- markup inside cref -->
534<xsl:template match="cref//eref" mode="cleanup">
535  <xsl:text>&lt;</xsl:text>
536  <xsl:value-of select="@target"/>
537  <xsl:text>&gt;</xsl:text>
538</xsl:template>
539
540<!-- artwork extensions -->
541<xsl:template match="artwork/@x:extraction-note" mode="cleanup"/>
542
543<!-- list formatting -->
544<xsl:template match="list/@x:indent" mode="cleanup"/>
545
546<!-- referencing extensions -->
547<xsl:template match="iref/@x:for-anchor" mode="cleanup"/>
548
549<!-- table styles -->
550<xsl:template match="texttable/@style" mode="cleanup"/>
551
552<!-- anchor extensions -->
553<xsl:template match="preamble/@anchor" mode="cleanup"/>
554
555<!-- section numbering -->
556<xsl:template match="section/@x:fixed-section-number" mode="cleanup"/>
557
558<!-- GRRDL info stripped -->
559<xsl:template match="@grddl:transformation" mode="cleanup"/>
560
561<!-- maturity level stripped -->
562<xsl:template match="@x:maturity-level" mode="cleanup"/>
563
564<!-- RDF info stripped -->
565<xsl:template match="rdf:*" mode="cleanup"/>
566
567</xsl:transform>
Note: See TracBrowser for help on using the repository browser.