source: rfc2629xslt/clean-for-DTD.xslt @ 272

Last change on this file since 272 was 272, checked in by julian.reschke@…, 12 years ago

Update to latest version of rfc2629.xslt, and take advantage of it.

  • Property svn:eol-style set to native
File size: 17.8 KB
Line 
1<!--
2    Strip rfc2629.xslt extensions, generating XML input for MTR's xml2rfc
3
4    Copyright (c) 2006-2008, Julian Reschke (julian.reschke@greenbytes.de)
5    All rights reserved.
6
7    Redistribution and use in source and binary forms, with or without
8    modification, are permitted provided that the following conditions are met:
9
10    * Redistributions of source code must retain the above copyright notice,
11      this list of conditions and the following disclaimer.
12    * Redistributions in binary form must reproduce the above copyright notice,
13      this list of conditions and the following disclaimer in the documentation
14      and/or other materials provided with the distribution.
15    * Neither the name of Julian Reschke nor the names of its contributors
16      may be used to endorse or promote products derived from this software
17      without specific prior written permission.
18
19    THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
20    AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
21    IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
22    ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR CONTRIBUTORS BE
23    LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
24    CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
25    SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
26    INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
27    CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
28    ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
29    POSSIBILITY OF SUCH DAMAGE.
30-->
31
32<xsl:transform xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
33                version="1.0"
34                xmlns:ed="http://greenbytes.de/2002/rfcedit"
35                xmlns:grddl="http://www.w3.org/2003/g/data-view#"
36                xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#"
37                xmlns:x="http://purl.org/net/xml2rfc/ext"
38                xmlns:xhtml="http://www.w3.org/1999/xhtml"
39                exclude-result-prefixes="ed grddl rdf x xhtml"
40>
41
42<!-- re-use some of the default RFC2629.xslt rules -->
43<xsl:import href="rfc2629.xslt"/>
44
45<!-- undo strip-space decls -->
46<xsl:preserve-space elements="*"/>
47
48<!-- generate DTD-valid output, override all values imported from rfc2629.xslt -->
49<xsl:output doctype-system="rfc2629.dtd" doctype-public="" method="xml" version="1.0" encoding="UTF-8" cdata-section-elements="artwork" />
50
51<!-- kick into cleanup mode -->
52<xsl:template match="/">
53  <xsl:text>&#10;</xsl:text>
54  <xsl:comment>
55    This XML document is the output of clean-for-DTD.xslt; a tool that strips
56    extensions to RFC2629(bis) from documents for processing with xml2rfc.
57</xsl:comment>
58  <xsl:apply-templates select="/" mode="cleanup"/>
59</xsl:template>
60
61<!-- rules for identity transformations -->
62
63<xsl:template match="processing-instruction()" mode="cleanup">
64  <xsl:text>&#10;</xsl:text>
65  <xsl:copy/>
66</xsl:template>
67
68<xsl:template match="comment()|@*" mode="cleanup"><xsl:copy/></xsl:template>
69
70<xsl:template match="text()" mode="cleanup"><xsl:copy/></xsl:template>
71
72<xsl:template match="/" mode="cleanup">
73        <xsl:copy><xsl:apply-templates select="node()" mode="cleanup" /></xsl:copy>
74</xsl:template>
75
76<xsl:template match="*" mode="cleanup">
77  <xsl:element name="{local-name()}">
78        <xsl:apply-templates select="node()|@*" mode="cleanup" />
79  </xsl:element>
80</xsl:template>
81
82
83<!-- remove PI extensions -->
84
85<xsl:template match="processing-instruction('rfc-ext')" mode="cleanup"/>
86
87<!-- add issues appendix -->
88
89<xsl:template match="back" mode="cleanup">
90  <back>
91    <xsl:apply-templates select="node()|@*" mode="cleanup" />
92    <xsl:if test="not(/*/@ed:suppress-issue-appendix='yes') and //ed:issue[@status='closed']">
93      <section title="Resolved issues (to be removed by RFC Editor before publication)">
94        <t>
95          Issues that were either rejected or resolved in this version of this
96          document.
97        </t>
98        <xsl:apply-templates select="//ed:issue[@status='closed']" mode="issues" />
99      </section>
100    </xsl:if>
101    <xsl:if test="not(/*/@ed:suppress-issue-appendix='yes') and //ed:issue[@status='open']">
102      <section title="Open issues (to be removed by RFC Editor prior to publication)">
103        <xsl:apply-templates select="//ed:issue[@status!='closed']" mode="issues" />
104      </section>
105    </xsl:if>
106  </back>
107</xsl:template>
108
109
110
111
112<!-- extensions -->
113
114<xsl:template match="x:abnf-char-sequence" mode="cleanup">
115  <xsl:choose>
116    <xsl:when test="substring(.,1,1) != '&quot;' or substring(.,string-length(.),1) != '&quot;'">
117      <xsl:call-template name="error">
118        <xsl:with-param name="msg" select="'contents of x:abnf-char-sequence needs to be quoted.'" />
119      </xsl:call-template>
120    </xsl:when>
121    <xsl:otherwise>
122      <xsl:text>%x</xsl:text>
123      <xsl:call-template name="to-abnf-char-sequence">
124        <xsl:with-param name="chars" select="substring(.,2,string-length(.)-2)"/>
125      </xsl:call-template>
126    </xsl:otherwise>
127  </xsl:choose>
128</xsl:template>
129
130<xsl:template match="x:anchor-alias" mode="cleanup"/>
131
132<xsl:template match="x:bcp14" mode="cleanup">
133  <xsl:apply-templates/>
134</xsl:template>
135
136<xsl:template match="x:assign-section-number" mode="cleanup"/> 
137<xsl:template match="x:link" mode="cleanup"/>
138<xsl:template match="x:source" mode="cleanup"/>
139
140<xsl:template match="x:ref" mode="cleanup">
141  <xsl:variable name="val" select="."/>
142  <xsl:variable name="target" select="//*[@anchor and (@anchor=$val or x:anchor-alias/@value=$val)]"/>
143  <xsl:choose>
144    <xsl:when test="$target">
145      <xsl:variable name="current" select="."/>
146      <xsl:for-each select="$target">
147        <!-- make it the context -->
148        <xsl:choose>
149          <xsl:when test="self::preamble">
150            <!-- it's not an element we can link to -->
151            <xsl:comment>clean-for-DTD.xslt warning: couldn't create the link as <xsl:value-of select="name()"/> does not support the anchor attribute.</xsl:comment>
152            <xsl:value-of select="$current"/>
153          </xsl:when>
154          <xsl:otherwise>
155            <xref target="{$target/@anchor}" format="none"><xsl:value-of select="$current"/></xref>
156          </xsl:otherwise>
157        </xsl:choose>
158      </xsl:for-each>
159    </xsl:when>
160    <xsl:otherwise>
161      <xsl:message>WARNING: internal link target for '<xsl:value-of select="."/>' does not exist.</xsl:message>
162      <xsl:value-of select="."/>
163    </xsl:otherwise>
164  </xsl:choose>
165</xsl:template>
166
167<xsl:template match="x:blockquote" mode="cleanup">
168  <t><list>
169    <xsl:apply-templates mode="cleanup" />
170  </list></t>
171</xsl:template>
172
173<xsl:template match="x:h" mode="cleanup">
174  <xsl:apply-templates mode="cleanup" />
175</xsl:template>
176
177<xsl:template match="x:lt" mode="cleanup">
178  <t>
179    <xsl:apply-templates select="@hangText|@anchor" mode="cleanup"/>
180    <xsl:for-each select="t">
181      <xsl:apply-templates mode="cleanup"/>
182      <xsl:if test="position()!=last()">
183        <vspace blankLines="1"/>
184      </xsl:if>
185    </xsl:for-each>
186  </t>
187</xsl:template>
188
189<xsl:template match="x:q" mode="cleanup">
190  <xsl:text>"</xsl:text>
191  <xsl:apply-templates mode="cleanup"/>
192  <xsl:text>"</xsl:text>
193</xsl:template>
194
195<xsl:template match="x:dfn" mode="cleanup">
196  <xsl:apply-templates mode="cleanup"/>
197</xsl:template>
198
199<xsl:template match="x:sup" mode="cleanup">
200  <xsl:text>^</xsl:text>
201  <xsl:apply-templates mode="cleanup" />
202</xsl:template>
203
204<!-- extended reference formatting -->
205
206<xsl:template match="xref[@x:* and not(node())]" mode="cleanup">
207  <xsl:variable name="node" select="$src//*[@anchor=current()/@target]" />
208
209  <xsl:variable name="sec">
210    <xsl:choose>
211      <xsl:when test="starts-with(@x:rel,'#') and not(@x:sec) and $node/x:source/@href">
212        <xsl:variable name="extdoc" select="document($node/x:source/@href)"/>
213        <xsl:for-each select="$extdoc//*[@anchor=substring-after(current()/@x:rel,'#')]">
214          <xsl:call-template name="get-section-number"/>
215        </xsl:for-each>
216      </xsl:when>
217      <xsl:otherwise>
218        <xsl:value-of select="@x:sec"/>
219      </xsl:otherwise>
220    </xsl:choose>
221  </xsl:variable>
222
223  <xsl:variable name="secterm">
224    <xsl:choose>
225      <!-- starts with letter? -->
226      <xsl:when test="translate(substring($sec,1,1),$ucase,'')=''">Appendix</xsl:when>
227      <xsl:otherwise>Section</xsl:otherwise>
228    </xsl:choose>
229  </xsl:variable>
230
231  <xsl:variable name="fmt">
232    <xsl:choose>
233      <xsl:when test="@x:fmt!=''"><xsl:value-of select="@x:fmt"/></xsl:when>
234      <xsl:when test="ancestor::artwork">,</xsl:when>
235      <xsl:otherwise>of</xsl:otherwise>
236    </xsl:choose>
237  </xsl:variable>
238
239  <xsl:choose>
240    <xsl:when test="$fmt=','">
241      <xref>
242        <xsl:apply-templates select="@target|@format|@pageno|text()|*" mode="cleanup"/>
243      </xref>
244      <xsl:text>, </xsl:text>
245      <xsl:value-of select="$secterm"/>
246      <xsl:text> </xsl:text>
247      <xsl:value-of select="$sec"/>
248    </xsl:when>
249    <xsl:when test="$fmt='sec'">
250      <xsl:value-of select="$secterm"/>
251      <xsl:text> </xsl:text>
252      <xsl:value-of select="$sec"/>
253    </xsl:when>
254    <xsl:when test="$fmt='number'">
255      <xsl:value-of select="$sec"/>
256    </xsl:when>
257    <xsl:when test="$fmt='()'">
258      <xref>
259        <xsl:apply-templates select="@target|@format|@pageno|text()|*" mode="cleanup"/>
260      </xref>
261      <xsl:text> (</xsl:text>
262      <xsl:value-of select="$secterm"/>
263      <xsl:text> </xsl:text>
264      <xsl:value-of select="$sec"/>
265      <xsl:text>)</xsl:text>
266    </xsl:when>
267    <xsl:when test="$fmt='of'">
268      <xsl:value-of select="$secterm"/>
269      <xsl:text> </xsl:text>
270      <xsl:value-of select="$sec"/>
271      <xsl:text> of </xsl:text>
272      <xref>
273        <xsl:apply-templates select="@target|@format|@pageno|text()|*" mode="cleanup"/>
274      </xref>
275    </xsl:when>
276    <xsl:when test="$fmt='anchor'">
277      <xsl:variable name="val">
278        <xsl:call-template name="referencename">
279          <xsl:with-param name="node" select="$node" />
280        </xsl:call-template>
281      </xsl:variable>
282      <!-- remove brackets -->
283      <xsl:value-of select="substring($val,2,string-length($val)-2)"/>
284    </xsl:when>
285    <xsl:otherwise>
286      <xsl:copy>
287        <xsl:apply-templates select="node()" mode="cleanup"/>
288      </xsl:copy>
289    </xsl:otherwise>
290  </xsl:choose>
291</xsl:template>
292
293<xsl:template match="xref[@x:fmt and node()]" mode="cleanup">
294  <xsl:choose>
295    <xsl:when test="@x:fmt='none'">
296      <xsl:apply-templates mode="cleanup"/>
297    </xsl:when>
298    <xsl:when test="not(@x:fmt)">
299      <xref>
300        <xsl:copy-of select="@target|@format"/>
301        <xsl:apply-templates mode="cleanup"/>
302      </xref>
303    </xsl:when>
304    <xsl:otherwise>
305      <xsl:message>Unsupported x:fmt attribute.</xsl:message>
306    </xsl:otherwise>
307  </xsl:choose>
308</xsl:template>
309
310<xsl:template match="xref[node() and @target=//preamble/@anchor]" mode="cleanup">
311  <!-- remove the link -->
312  <xsl:apply-templates select="node()" mode="cleanup"/>
313</xsl:template>
314
315<xsl:template match="xref[not(node()) and @target=//preamble/@anchor]" mode="cleanup">
316  <!-- fatal -->
317  <xsl:message>Broken xref due to target being filtered out.</xsl:message>
318</xsl:template>
319
320<!-- issue tracking extensions -->
321
322<xsl:template match="@xml:lang" mode="cleanup"/>
323<xsl:template match="@xml:lang" />
324
325<xsl:template match="ed:*" mode="cleanup"/>
326<xsl:template match="ed:*" />
327
328<xsl:template match="@ed:*" mode="cleanup"/>
329<xsl:template match="@ed:*" />
330
331<xsl:template match="ed:annotation" mode="cleanup" />
332
333<xsl:template match="ed:replace" mode="cleanup">
334  <xsl:apply-templates mode="cleanup" />
335</xsl:template>
336
337<xsl:template match="ed:replace">
338  <xsl:apply-templates/>
339</xsl:template>
340
341<xsl:template match="ed:ins" mode="cleanup">
342  <xsl:apply-templates mode="cleanup"/>
343</xsl:template>
344
345<xsl:template match="ed:ins">
346  <xsl:apply-templates/>
347</xsl:template>
348
349<xsl:template match="ed:issue" mode="issues">
350  <section title="{@name}">
351    <xsl:variable name="sec">
352      <xsl:call-template name="get-section-number"/>
353    </xsl:variable>
354
355    <xsl:if test="$sec!=''">
356      <t>
357        In Section <xsl:value-of select="$sec"/>:
358      </t>
359    </xsl:if>
360   
361    <t>
362      Type: <xsl:value-of select="@type" />
363    </t>
364    <xsl:if test="@href">
365      <t>
366        <!-- temp. removed because of xml2rfc's handling of erefs when producing TXT-->
367        <!--<eref target="{@href}" /> -->
368        <xsl:text>&lt;</xsl:text>
369        <xsl:value-of select="@href"/>
370        <xsl:text>></xsl:text>
371        <xsl:if test="@alternate-href">
372          <xsl:text>, &lt;</xsl:text>
373          <xsl:value-of select="@alternate-href"/>
374          <xsl:text>></xsl:text>
375        </xsl:if>
376      </t>
377    </xsl:if>
378    <xsl:for-each select="ed:item">
379      <t>
380        <xsl:if test="@entered-by or @date">
381          <xsl:choose>
382            <xsl:when test="not(@entered-by)">
383              <xsl:value-of select="concat('(',@date,') ')" />
384            </xsl:when>
385            <xsl:when test="not(@date)">
386              <xsl:value-of select="concat(@entered-by,': ')" />
387            </xsl:when>
388            <xsl:otherwise>
389              <xsl:value-of select="concat(@entered-by,' (',@date,'): ')" />
390            </xsl:otherwise>
391          </xsl:choose>     
392        </xsl:if>
393        <xsl:if test="not(xhtml:p)">
394          <xsl:apply-templates select="node()" mode="issues"/>
395        </xsl:if>
396      </t>
397      <xsl:if test="xhtml:p|xhtml:pre">
398        <xsl:for-each select="node()">
399          <xsl:choose>
400            <xsl:when test="self::xhtml:p">
401              <t>
402                <xsl:apply-templates select="node()" mode="issues"/>
403              </t>
404            </xsl:when>
405            <xsl:when test="self::xhtml:pre">
406              <figure>
407                <artwork><xsl:apply-templates select="node()" mode="issues"/></artwork>
408              </figure>
409            </xsl:when>
410            <xsl:otherwise>
411              <t>
412                <xsl:apply-templates select="." mode="issues"/>
413              </t>
414            </xsl:otherwise>
415          </xsl:choose>
416        </xsl:for-each>
417      </xsl:if>
418    </xsl:for-each> 
419    <xsl:if test="ed:resolution">
420      <t>
421        <xsl:text>Resolution</xsl:text>
422        <xsl:if test="ed:resolution/@datetime"> (<xsl:value-of select="ed:resolution/@datetime"/>)</xsl:if>
423        <xsl:text>: </xsl:text>
424        <xsl:value-of select="ed:resolution" />
425      </t>
426    </xsl:if>
427  </section>
428</xsl:template>
429
430<xsl:template match="ed:issueref" mode="cleanup">
431  <xsl:apply-templates mode="cleanup"/>
432</xsl:template>
433
434<xsl:template match="*" mode="issues">
435  <xsl:apply-templates mode="issues"/>
436</xsl:template>
437
438<xsl:template match="xhtml:q" mode="issues">
439  <list><t>
440    <xsl:text>"</xsl:text>
441    <xsl:apply-templates mode="issues"/>
442    <xsl:text>"</xsl:text>
443    <xsl:if test="@cite">
444      <xsl:text> -- </xsl:text>
445      <eref target="{@cite}"><xsl:value-of select="@cite"/></eref>
446    </xsl:if>
447  </t></list>
448</xsl:template>
449
450<xsl:template match="xhtml:br" mode="issues">
451  <vspace/>
452</xsl:template>
453
454<xsl:template match="xhtml:del" mode="issues">
455  <xsl:text>&lt;del></xsl:text>
456    <xsl:apply-templates mode="issues"/>
457  <xsl:text>&lt;/del></xsl:text>
458</xsl:template>
459
460<xsl:template match="xhtml:em" mode="issues">
461  <spanx style="emph">
462    <xsl:apply-templates mode="issues"/>
463  </spanx>
464</xsl:template>
465
466<xsl:template match="xhtml:ins" mode="issues">
467  <xsl:text>&lt;ins></xsl:text>
468    <xsl:apply-templates mode="issues"/>
469  <xsl:text>&lt;/ins></xsl:text>
470</xsl:template>
471
472<xsl:template match="xhtml:tt" mode="issues">
473  <xsl:apply-templates mode="issues"/>
474</xsl:template>
475
476<xsl:template match="ed:eref" mode="issues">
477  <xsl:text>&lt;</xsl:text>
478  <xsl:value-of select="."/>
479  <xsl:text>&gt;</xsl:text>
480</xsl:template>
481
482<xsl:template match="ed:issueref" mode="issues">
483  <xsl:apply-templates mode="issues"/>
484</xsl:template>
485
486<xsl:template match="text()" mode="issues">
487  <xsl:value-of select="." />
488</xsl:template>
489
490
491
492<!-- markup inside artwork element -->
493
494<xsl:template match="figure[.//artwork//iref]" mode="cleanup">
495  <!-- move up iref elements -->
496  <figure>
497    <xsl:apply-templates select="@*" mode="cleanup" />
498    <xsl:apply-templates select=".//artwork//iref" mode="cleanup"/>
499    <xsl:apply-templates select="iref|preamble|artwork|postamble" mode="cleanup" />
500  </figure>
501</xsl:template>
502
503<xsl:template match="artwork" mode="cleanup">
504  <xsl:variable name="content"><xsl:apply-templates select="."/></xsl:variable>
505  <artwork>
506    <xsl:apply-templates select="@*" mode="cleanup" />
507    <xsl:if test="starts-with(.,'&#10;')">
508      <xsl:text>&#10;</xsl:text>
509    </xsl:if>
510    <xsl:value-of select="translate($content,'&#160;&#x2500;&#x2502;&#x2508;&#x250c;&#x2510;&#x2514;&#x2518;&#x251c;&#x2524;',' -|+++++++')"/>
511  </artwork> 
512</xsl:template>
513
514<!-- email repititions -->
515<xsl:template match="email" mode="cleanup">
516  <!-- combine in a single element -->
517  <xsl:if test="not(preceding-sibling::email)">
518    <email>
519      <xsl:for-each select="../email">
520        <xsl:value-of select="."/>
521        <xsl:if test="position()!=last()">
522          <xsl:text>, </xsl:text>
523        </xsl:if>
524      </xsl:for-each>
525    </email>
526  </xsl:if>
527</xsl:template>
528
529<!-- markup inside cref -->
530<xsl:template match="cref//eref" mode="cleanup">
531  <xsl:text>&lt;</xsl:text>
532  <xsl:value-of select="@target"/>
533  <xsl:text>&gt;</xsl:text>
534</xsl:template>
535
536<!-- artwork extensions -->
537<xsl:template match="artwork/@x:extraction-note" mode="cleanup"/>
538
539<!-- list formatting -->
540<xsl:template match="list/@x:indent" mode="cleanup"/>
541
542<!-- referencing extensions -->
543<xsl:template match="iref/@x:for-anchor" mode="cleanup"/>
544
545<!-- table styles -->
546<xsl:template match="texttable/@style" mode="cleanup"/>
547
548<!-- anchor extensions -->
549<xsl:template match="preamble/@anchor" mode="cleanup"/>
550
551<!-- section numbering -->
552<xsl:template match="section/@x:fixed-section-number" mode="cleanup"/>
553
554<!-- GRRDL info stripped -->
555<xsl:template match="@grddl:transformation" mode="cleanup"/>
556
557<!-- RDF info stripped -->
558<xsl:template match="rdf:*" mode="cleanup"/>
559
560</xsl:transform>
Note: See TracBrowser for help on using the repository browser.