source: rfc2629xslt/clean-for-DTD.xslt @ 213

Last change on this file since 213 was 204, checked in by julian.reschke@…, 12 years ago

Update to latest version of rfc2629.xslt.

  • Property svn:eol-style set to native
File size: 16.5 KB
Line 
1<!--
2    Strip rfc2629.xslt extensions, generating XML input for MTR's xml2rfc
3
4    Copyright (c) 2006-2008, Julian Reschke (julian.reschke@greenbytes.de)
5    All rights reserved.
6
7    Redistribution and use in source and binary forms, with or without
8    modification, are permitted provided that the following conditions are met:
9
10    * Redistributions of source code must retain the above copyright notice,
11      this list of conditions and the following disclaimer.
12    * Redistributions in binary form must reproduce the above copyright notice,
13      this list of conditions and the following disclaimer in the documentation
14      and/or other materials provided with the distribution.
15    * Neither the name of Julian Reschke nor the names of its contributors
16      may be used to endorse or promote products derived from this software
17      without specific prior written permission.
18
19    THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
20    AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
21    IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
22    ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR CONTRIBUTORS BE
23    LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
24    CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
25    SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
26    INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
27    CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
28    ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
29    POSSIBILITY OF SUCH DAMAGE.
30-->
31
32<xsl:transform xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
33                version="1.0"
34                xmlns:ed="http://greenbytes.de/2002/rfcedit"
35                xmlns:grddl="http://www.w3.org/2003/g/data-view#"
36                xmlns:x="http://purl.org/net/xml2rfc/ext"
37                xmlns:xhtml="http://www.w3.org/1999/xhtml"
38                exclude-result-prefixes="ed grddl x xhtml"
39>
40
41<!-- re-use some of the default RFC2629.xslt rules -->
42<xsl:import href="rfc2629.xslt"/>
43
44<!-- undo strip-space decls -->
45<xsl:preserve-space elements="*"/>
46
47<!-- generate DTD-valid output, override all values imported from rfc2629.xslt -->
48<xsl:output doctype-system="rfc2629.dtd" doctype-public="" method="xml" version="1.0" encoding="UTF-8" cdata-section-elements="artwork" />
49
50<!-- kick into cleanup mode -->
51<xsl:template match="/">
52  <xsl:text>&#10;</xsl:text>
53  <xsl:comment>
54    This XML document is the output of clean-for-DTD.xslt; a tool that strips
55    extensions to RFC2629(bis) from documents for processing with xml2rfc.
56</xsl:comment>
57  <xsl:apply-templates select="/" mode="cleanup"/>
58</xsl:template>
59
60<!-- rules for identity transformations -->
61
62<xsl:template match="processing-instruction()" mode="cleanup">
63  <xsl:text>&#10;</xsl:text>
64  <xsl:copy/>
65</xsl:template>
66
67<xsl:template match="comment()|@*" mode="cleanup"><xsl:copy/></xsl:template>
68
69<xsl:template match="text()" mode="cleanup"><xsl:copy/></xsl:template>
70
71<xsl:template match="/" mode="cleanup">
72        <xsl:copy><xsl:apply-templates select="node()" mode="cleanup" /></xsl:copy>
73</xsl:template>
74
75<xsl:template match="*" mode="cleanup">
76  <xsl:element name="{local-name()}">
77        <xsl:apply-templates select="node()|@*" mode="cleanup" />
78  </xsl:element>
79</xsl:template>
80
81
82<!-- remove PI extensions -->
83
84<xsl:template match="processing-instruction('rfc-ext')" mode="cleanup"/>
85
86<!-- add issues appendix -->
87
88<xsl:template match="back" mode="cleanup">
89  <back>
90    <xsl:apply-templates select="node()|@*" mode="cleanup" />
91    <xsl:if test="not(/*/@ed:suppress-issue-appendix='yes') and //ed:issue[@status='closed']">
92      <section title="Resolved issues (to be removed by RFC Editor before publication)">
93        <t>
94          Issues that were either rejected or resolved in this version of this
95          document.
96        </t>
97        <xsl:apply-templates select="//ed:issue[@status='closed']" mode="issues" />
98      </section>
99    </xsl:if>
100    <xsl:if test="not(/*/@ed:suppress-issue-appendix='yes') and //ed:issue[@status='open']">
101      <section title="Open issues (to be removed by RFC Editor prior to publication)">
102        <xsl:apply-templates select="//ed:issue[@status!='closed']" mode="issues" />
103      </section>
104    </xsl:if>
105  </back>
106</xsl:template>
107
108
109
110
111<!-- extensions -->
112
113<xsl:template match="x:anchor-alias" mode="cleanup"/>
114
115<xsl:template match="x:bcp14" mode="cleanup">
116  <xsl:apply-templates/>
117</xsl:template>
118
119<xsl:template match="x:assign-section-number" mode="cleanup"/> 
120<xsl:template match="x:link" mode="cleanup"/>
121<xsl:template match="x:source" mode="cleanup"/>
122
123<xsl:template match="x:ref" mode="cleanup">
124  <xsl:variable name="val" select="."/>
125  <xsl:variable name="target" select="//*[@anchor and (@anchor=$val or x:anchor-alias/@value=$val)]"/>
126  <xsl:choose>
127    <xsl:when test="$target">
128      <xsl:variable name="current" select="."/>
129      <xsl:for-each select="$target">
130        <!-- make it the context -->
131        <xsl:choose>
132          <xsl:when test="self::preamble">
133            <!-- it's not an element we can link to -->
134            <xsl:comment>clean-for-DTD.xslt warning: couldn't create the link as <xsl:value-of select="name()"/> does not support the anchor attribute.</xsl:comment>
135            <xsl:value-of select="$current"/>
136          </xsl:when>
137          <xsl:otherwise>
138            <xref target="{$target/@anchor}" format="none"><xsl:value-of select="$current"/></xref>
139          </xsl:otherwise>
140        </xsl:choose>
141      </xsl:for-each>
142    </xsl:when>
143    <xsl:otherwise>
144      <xsl:message>WARNING: internal link target for '<xsl:value-of select="."/>' does not exist.</xsl:message>
145      <xsl:value-of select="."/>
146    </xsl:otherwise>
147  </xsl:choose>
148</xsl:template>
149
150<xsl:template match="x:blockquote" mode="cleanup">
151  <t><list>
152    <xsl:apply-templates mode="cleanup" />
153  </list></t>
154</xsl:template>
155
156<xsl:template match="x:h" mode="cleanup">
157  <xsl:apply-templates mode="cleanup" />
158</xsl:template>
159
160<xsl:template match="x:lt" mode="cleanup">
161  <t>
162    <xsl:apply-templates select="@hangText|@anchor" mode="cleanup"/>
163    <xsl:for-each select="t">
164      <xsl:apply-templates mode="cleanup"/>
165      <xsl:if test="position()!=last()">
166        <vspace blankLines="1"/>
167      </xsl:if>
168    </xsl:for-each>
169  </t>
170</xsl:template>
171
172<xsl:template match="x:q" mode="cleanup">
173  <xsl:text>"</xsl:text>
174  <xsl:apply-templates mode="cleanup"/>
175  <xsl:text>"</xsl:text>
176</xsl:template>
177
178<xsl:template match="x:dfn" mode="cleanup">
179  <xsl:apply-templates mode="cleanup"/>
180</xsl:template>
181
182<!-- extended reference formatting -->
183
184<xsl:template match="xref[@x:* and not(node())]" mode="cleanup">
185  <xsl:variable name="node" select="$src//*[@anchor=current()/@target]" />
186
187  <xsl:variable name="sec">
188    <xsl:choose>
189      <xsl:when test="starts-with(@x:rel,'#') and not(@x:sec) and $node/x:source/@href">
190        <xsl:variable name="extdoc" select="document($node/x:source/@href)"/>
191        <xsl:for-each select="$extdoc//*[@anchor=substring-after(current()/@x:rel,'#')]">
192          <xsl:call-template name="get-section-number"/>
193        </xsl:for-each>
194      </xsl:when>
195      <xsl:otherwise>
196        <xsl:value-of select="@x:sec"/>
197      </xsl:otherwise>
198    </xsl:choose>
199  </xsl:variable>
200
201  <xsl:variable name="secterm">
202    <xsl:choose>
203      <!-- starts with letter? -->
204      <xsl:when test="translate(substring($sec,1,1),$ucase,'')=''">Appendix</xsl:when>
205      <xsl:otherwise>Section</xsl:otherwise>
206    </xsl:choose>
207  </xsl:variable>
208
209  <xsl:variable name="fmt">
210    <xsl:choose>
211      <xsl:when test="@x:fmt!=''"><xsl:value-of select="@x:fmt"/></xsl:when>
212      <xsl:when test="ancestor::artwork">,</xsl:when>
213      <xsl:otherwise>of</xsl:otherwise>
214    </xsl:choose>
215  </xsl:variable>
216
217  <xsl:choose>
218    <xsl:when test="$fmt=','">
219      <xref>
220        <xsl:apply-templates select="@target|@format|@pageno|text()|*" mode="cleanup"/>
221      </xref>
222      <xsl:text>, </xsl:text>
223      <xsl:value-of select="$secterm"/>
224      <xsl:text> </xsl:text>
225      <xsl:value-of select="$sec"/>
226    </xsl:when>
227    <xsl:when test="$fmt='sec'">
228      <xsl:value-of select="$secterm"/>
229      <xsl:text> </xsl:text>
230      <xsl:value-of select="$sec"/>
231    </xsl:when>
232    <xsl:when test="$fmt='number'">
233      <xsl:value-of select="$sec"/>
234    </xsl:when>
235    <xsl:when test="$fmt='()'">
236      <xref>
237        <xsl:apply-templates select="@target|@format|@pageno|text()|*" mode="cleanup"/>
238      </xref>
239      <xsl:text> (</xsl:text>
240      <xsl:value-of select="$secterm"/>
241      <xsl:text> </xsl:text>
242      <xsl:value-of select="$sec"/>
243      <xsl:text>)</xsl:text>
244    </xsl:when>
245    <xsl:when test="$fmt='of'">
246      <xsl:value-of select="$secterm"/>
247      <xsl:text> </xsl:text>
248      <xsl:value-of select="$sec"/>
249      <xsl:text> of </xsl:text>
250      <xref>
251        <xsl:apply-templates select="@target|@format|@pageno|text()|*" mode="cleanup"/>
252      </xref>
253    </xsl:when>
254    <xsl:when test="$fmt='anchor'">
255      <xsl:variable name="val">
256        <xsl:call-template name="referencename">
257          <xsl:with-param name="node" select="$node" />
258        </xsl:call-template>
259      </xsl:variable>
260      <!-- remove brackets -->
261      <xsl:value-of select="substring($val,2,string-length($val)-2)"/>
262    </xsl:when>
263    <xsl:otherwise>
264      <xsl:copy>
265        <xsl:apply-templates select="node()" mode="cleanup"/>
266      </xsl:copy>
267    </xsl:otherwise>
268  </xsl:choose>
269</xsl:template>
270
271<xsl:template match="xref[@x:fmt and node()]" mode="cleanup">
272  <xsl:choose>
273    <xsl:when test="@x:fmt='none'">
274      <xsl:apply-templates mode="cleanup"/>
275    </xsl:when>
276    <xsl:when test="not(@x:fmt)">
277      <xref>
278        <xsl:copy-of select="@target|@format"/>
279        <xsl:apply-templates mode="cleanup"/>
280      </xref>
281    </xsl:when>
282    <xsl:otherwise>
283      <xsl:message>Unsupported x:fmt attribute.</xsl:message>
284    </xsl:otherwise>
285  </xsl:choose>
286</xsl:template>
287
288<xsl:template match="xref[node() and @target=//preamble/@anchor]" mode="cleanup">
289  <!-- remove the link -->
290  <xsl:apply-templates select="node()" mode="cleanup"/>
291</xsl:template>
292
293<xsl:template match="xref[not(node()) and @target=//preamble/@anchor]" mode="cleanup">
294  <!-- fatal -->
295  <xsl:message>Broken xref due to target being filtered out.</xsl:message>
296</xsl:template>
297
298<!-- issue tracking extensions -->
299
300<xsl:template match="@xml:lang" mode="cleanup"/>
301<xsl:template match="@xml:lang" />
302
303<xsl:template match="ed:*" mode="cleanup"/>
304<xsl:template match="ed:*" />
305
306<xsl:template match="@ed:*" mode="cleanup"/>
307<xsl:template match="@ed:*" />
308
309<xsl:template match="ed:annotation" mode="cleanup" />
310
311<xsl:template match="ed:replace" mode="cleanup">
312  <xsl:apply-templates mode="cleanup" />
313</xsl:template>
314
315<xsl:template match="ed:replace">
316  <xsl:apply-templates/>
317</xsl:template>
318
319<xsl:template match="ed:ins" mode="cleanup">
320  <xsl:apply-templates mode="cleanup"/>
321</xsl:template>
322
323<xsl:template match="ed:ins">
324  <xsl:apply-templates/>
325</xsl:template>
326
327<xsl:template match="ed:issue" mode="issues">
328  <section title="{@name}">
329    <xsl:variable name="sec">
330      <xsl:call-template name="get-section-number"/>
331    </xsl:variable>
332
333    <xsl:if test="$sec!=''">
334      <t>
335        In Section <xsl:value-of select="$sec"/>:
336      </t>
337    </xsl:if>
338   
339    <t>
340      Type: <xsl:value-of select="@type" />
341    </t>
342    <xsl:if test="@href">
343      <t>
344        <!-- temp. removed because of xml2rfc's handling of erefs when producing TXT-->
345        <!--<eref target="{@href}" /> -->
346        <xsl:text>&lt;</xsl:text>
347        <xsl:value-of select="@href"/>
348        <xsl:text>></xsl:text>
349        <xsl:if test="@alternate-href">
350          <xsl:text>, &lt;</xsl:text>
351          <xsl:value-of select="@alternate-href"/>
352          <xsl:text>></xsl:text>
353        </xsl:if>
354      </t>
355    </xsl:if>
356    <xsl:for-each select="ed:item">
357      <t>
358        <xsl:if test="@entered-by or @date">
359          <xsl:choose>
360            <xsl:when test="not(@entered-by)">
361              <xsl:value-of select="concat('(',@date,') ')" />
362            </xsl:when>
363            <xsl:when test="not(@date)">
364              <xsl:value-of select="concat(@entered-by,': ')" />
365            </xsl:when>
366            <xsl:otherwise>
367              <xsl:value-of select="concat(@entered-by,' (',@date,'): ')" />
368            </xsl:otherwise>
369          </xsl:choose>     
370        </xsl:if>
371        <xsl:if test="not(xhtml:p)">
372          <xsl:apply-templates select="node()" mode="issues"/>
373        </xsl:if>
374      </t>
375      <xsl:if test="xhtml:p|xhtml:pre">
376        <xsl:for-each select="node()">
377          <xsl:choose>
378            <xsl:when test="self::xhtml:p">
379              <t>
380                <xsl:apply-templates select="node()" mode="issues"/>
381              </t>
382            </xsl:when>
383            <xsl:when test="self::xhtml:pre">
384              <figure>
385                <artwork><xsl:apply-templates select="node()" mode="issues"/></artwork>
386              </figure>
387            </xsl:when>
388            <xsl:otherwise>
389              <t>
390                <xsl:apply-templates select="." mode="issues"/>
391              </t>
392            </xsl:otherwise>
393          </xsl:choose>
394        </xsl:for-each>
395      </xsl:if>
396    </xsl:for-each> 
397    <xsl:if test="ed:resolution">
398      <t>
399        <xsl:text>Resolution</xsl:text>
400        <xsl:if test="ed:resolution/@datetime"> (<xsl:value-of select="ed:resolution/@datetime"/>)</xsl:if>
401        <xsl:text>: </xsl:text>
402        <xsl:value-of select="ed:resolution" />
403      </t>
404    </xsl:if>
405  </section>
406</xsl:template>
407
408<xsl:template match="ed:issueref" mode="cleanup">
409  <xsl:apply-templates mode="cleanup"/>
410</xsl:template>
411
412<xsl:template match="*" mode="issues">
413  <xsl:apply-templates mode="issues"/>
414</xsl:template>
415
416<xsl:template match="xhtml:q" mode="issues">
417  <list><t>
418    <xsl:text>"</xsl:text>
419    <xsl:apply-templates mode="issues"/>
420    <xsl:text>"</xsl:text>
421    <xsl:if test="@cite">
422      <xsl:text> -- </xsl:text>
423      <eref target="{@cite}"><xsl:value-of select="@cite"/></eref>
424    </xsl:if>
425  </t></list>
426</xsl:template>
427
428<xsl:template match="xhtml:br" mode="issues">
429  <vspace/>
430</xsl:template>
431
432<xsl:template match="xhtml:del" mode="issues">
433  <xsl:text>&lt;del></xsl:text>
434    <xsl:apply-templates mode="issues"/>
435  <xsl:text>&lt;/del></xsl:text>
436</xsl:template>
437
438<xsl:template match="xhtml:em" mode="issues">
439  <spanx style="emph">
440    <xsl:apply-templates mode="issues"/>
441  </spanx>
442</xsl:template>
443
444<xsl:template match="xhtml:ins" mode="issues">
445  <xsl:text>&lt;ins></xsl:text>
446    <xsl:apply-templates mode="issues"/>
447  <xsl:text>&lt;/ins></xsl:text>
448</xsl:template>
449
450<xsl:template match="xhtml:tt" mode="issues">
451  <xsl:apply-templates mode="issues"/>
452</xsl:template>
453
454<xsl:template match="ed:eref" mode="issues">
455  <xsl:text>&lt;</xsl:text>
456  <xsl:value-of select="."/>
457  <xsl:text>&gt;</xsl:text>
458</xsl:template>
459
460<xsl:template match="ed:issueref" mode="issues">
461  <xsl:apply-templates mode="issues"/>
462</xsl:template>
463
464<xsl:template match="text()" mode="issues">
465  <xsl:value-of select="." />
466</xsl:template>
467
468
469
470<!-- markup inside artwork element -->
471
472<xsl:template match="figure[.//artwork//iref]" mode="cleanup">
473  <!-- move up iref elements -->
474  <figure>
475    <xsl:apply-templates select="@*" mode="cleanup" />
476    <xsl:apply-templates select=".//artwork//iref" mode="cleanup"/>
477    <xsl:apply-templates select="iref|preamble|artwork|postamble" mode="cleanup" />
478  </figure>
479</xsl:template>
480
481<xsl:template match="artwork" mode="cleanup">
482  <xsl:variable name="content"><xsl:apply-templates select="."/></xsl:variable>
483  <artwork>
484    <xsl:apply-templates select="@*" mode="cleanup" />
485    <xsl:if test="starts-with(.,'&#10;')">
486      <xsl:text>&#10;</xsl:text>
487    </xsl:if>
488    <xsl:value-of select="translate($content,'&#160;&#x2500;&#x2502;&#x2508;&#x250c;&#x2510;&#x2514;&#x2518;&#x251c;&#x2524;',' -|+++++++')"/>
489  </artwork> 
490</xsl:template>
491
492<!-- markup inside cref -->
493<xsl:template match="cref//eref" mode="cleanup">
494  <xsl:text>&lt;</xsl:text>
495  <xsl:value-of select="@target"/>
496  <xsl:text>&gt;</xsl:text>
497</xsl:template>
498
499
500<!-- artwork extensions -->
501<xsl:template match="artwork/@x:extraction-note" mode="cleanup"/>
502
503<!-- list formatting -->
504<xsl:template match="list/@x:indent" mode="cleanup"/>
505
506<!-- referencing extensions -->
507<xsl:template match="iref/@x:for-anchor" mode="cleanup"/>
508
509<!-- table styles -->
510<xsl:template match="texttable/@style" mode="cleanup"/>
511
512<!-- anchor extensions -->
513<xsl:template match="preamble/@anchor" mode="cleanup"/>
514
515<!-- section numbering -->
516<xsl:template match="section/@x:fixed-section-number" mode="cleanup"/>
517
518<!-- GRRDL info stripped -->
519<xsl:template match="@grddl:transformation" mode="cleanup"/>
520
521</xsl:transform>
Note: See TracBrowser for help on using the repository browser.