source: rfc2629xslt/clean-for-DTD.xslt @ 1667

Last change on this file since 1667 was 1522, checked in by julian.reschke@…, 8 years ago

bump up document dates, update to latest version of rfc2629.xslt, add feedback links

  • Property svn:eol-style set to native
File size: 23.8 KB
Line 
1<!--
2    Strip rfc2629.xslt extensions, generating XML input for MTR's xml2rfc
3
4    Copyright (c) 2006-2011, Julian Reschke (julian.reschke@greenbytes.de)
5    All rights reserved.
6
7    Redistribution and use in source and binary forms, with or without
8    modification, are permitted provided that the following conditions are met:
9
10    * Redistributions of source code must retain the above copyright notice,
11      this list of conditions and the following disclaimer.
12    * Redistributions in binary form must reproduce the above copyright notice,
13      this list of conditions and the following disclaimer in the documentation
14      and/or other materials provided with the distribution.
15    * Neither the name of Julian Reschke nor the names of its contributors
16      may be used to endorse or promote products derived from this software
17      without specific prior written permission.
18
19    THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
20    AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
21    IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
22    ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR CONTRIBUTORS BE
23    LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
24    CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
25    SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
26    INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
27    CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
28    ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
29    POSSIBILITY OF SUCH DAMAGE.
30-->
31
32<xsl:transform xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
33                version="1.0"
34                xmlns:ed="http://greenbytes.de/2002/rfcedit"
35                xmlns:grddl="http://www.w3.org/2003/g/data-view#"
36                xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#"
37                xmlns:x="http://purl.org/net/xml2rfc/ext"
38                xmlns:xhtml="http://www.w3.org/1999/xhtml"
39                exclude-result-prefixes="ed grddl rdf x xhtml"
40>
41
42<!-- re-use some of the default RFC2629.xslt rules -->
43<xsl:import href="rfc2629.xslt"/>
44
45<!-- undo strip-space decls -->
46<xsl:preserve-space elements="*"/>
47
48<!-- generate DTD-valid output, override all values imported from rfc2629.xslt -->
49<xsl:output doctype-system="rfc2629.dtd" doctype-public="" method="xml" version="1.0" encoding="UTF-8" cdata-section-elements="artwork" />
50
51<!-- kick into cleanup mode -->
52<xsl:template match="/">
53  <xsl:text>&#10;</xsl:text>
54  <xsl:comment>
55    This XML document is the output of clean-for-DTD.xslt; a tool that strips
56    extensions to RFC2629(bis) from documents for processing with xml2rfc.
57</xsl:comment>
58  <xsl:apply-templates select="/" mode="cleanup"/>
59</xsl:template>
60
61<!-- rules for identity transformations -->
62
63<xsl:template match="processing-instruction()" mode="cleanup">
64  <xsl:text>&#10;</xsl:text>
65  <xsl:copy/>
66</xsl:template>
67
68<xsl:template match="comment()|@*" mode="cleanup"><xsl:copy/></xsl:template>
69
70<xsl:template match="text()" mode="cleanup"><xsl:copy/></xsl:template>
71
72<xsl:template match="/" mode="cleanup">
73        <xsl:copy><xsl:apply-templates select="node()" mode="cleanup" /></xsl:copy>
74</xsl:template>
75
76<xsl:template match="*" mode="cleanup">
77  <xsl:element name="{local-name()}">
78        <xsl:apply-templates select="node()|@*" mode="cleanup" />
79  </xsl:element>
80</xsl:template>
81
82
83<!-- remove PI extensions -->
84
85<xsl:template match="processing-instruction('rfc-ext')" mode="cleanup"/>
86<xsl:template match="processing-instruction('BEGININC')" mode="cleanup"/>
87<xsl:template match="processing-instruction('ENDINC')" mode="cleanup"/>
88
89<!-- add issues appendix -->
90
91<xsl:template match="back" mode="cleanup">
92  <back>
93    <xsl:apply-templates select="node()|@*" mode="cleanup" />
94    <xsl:if test="not(/*/@ed:suppress-issue-appendix='yes') and //ed:issue[@status='closed']">
95      <section title="Resolved issues (to be removed by RFC Editor before publication)">
96        <t>
97          Issues that were either rejected or resolved in this version of this
98          document.
99        </t>
100        <xsl:apply-templates select="//ed:issue[@status='closed']" mode="issues" />
101      </section>
102    </xsl:if>
103    <xsl:if test="not(/*/@ed:suppress-issue-appendix='yes') and //ed:issue[@status='open']">
104      <section title="Open issues (to be removed by RFC Editor prior to publication)">
105        <xsl:apply-templates select="//ed:issue[@status!='closed']" mode="issues" />
106      </section>
107    </xsl:if>
108  </back>
109</xsl:template>
110
111
112
113
114<!-- extensions -->
115
116<xsl:template match="x:abnf-char-sequence" mode="cleanup">
117  <xsl:choose>
118    <xsl:when test="substring(.,1,1) != '&quot;' or substring(.,string-length(.),1) != '&quot;'">
119      <xsl:call-template name="error">
120        <xsl:with-param name="msg" select="'contents of x:abnf-char-sequence needs to be quoted.'" />
121      </xsl:call-template>
122    </xsl:when>
123    <xsl:otherwise>
124      <xsl:text>%x</xsl:text>
125      <xsl:call-template name="to-abnf-char-sequence">
126        <xsl:with-param name="chars" select="substring(.,2,string-length(.)-2)"/>
127      </xsl:call-template>
128    </xsl:otherwise>
129  </xsl:choose>
130</xsl:template>
131
132<xsl:template match="x:anchor-alias" mode="cleanup"/>
133
134<xsl:template match="x:bcp14" mode="cleanup">
135  <xsl:apply-templates/>
136</xsl:template>
137
138<xsl:template match="x:assign-section-number" mode="cleanup"/> 
139<xsl:template match="x:link" mode="cleanup"/>
140<xsl:template match="x:source" mode="cleanup"/>
141<xsl:template match="x:feedback" mode="cleanup"/>
142
143<xsl:template match="x:parse-xml" mode="cleanup">
144  <xsl:apply-templates/>
145</xsl:template>
146
147<xsl:template match="x:prose" mode="cleanup">
148  <xsl:variable name="text" select="."/>
149  <xsl:comment>Converted from rfc2629.xslt x:prose extension</xsl:comment>
150  <xsl:choose>
151    <xsl:when test="contains($text,' ')">
152      <seriesInfo name="{substring-before($text,' ')}" value="{substring-after($text,' ')}"/>
153    </xsl:when>
154    <xsl:otherwise>
155      <seriesInfo name="" value="{$text}"/>
156    </xsl:otherwise>
157  </xsl:choose>
158</xsl:template>
159
160<xsl:template match="x:ref" mode="cleanup">
161  <xsl:variable name="val" select="."/>
162  <xsl:variable name="target" select="//*[@anchor and (@anchor=$val or x:anchor-alias/@value=$val)][not(ancestor::ed:del)]"/>
163  <xsl:choose>
164    <xsl:when test="$target">
165      <xsl:if test="count($target)!=1">
166        <xsl:message terminate="yes">FATAL: multiple x:ref targets found for <xsl:value-of select="$val"/>.</xsl:message>
167      </xsl:if>
168      <xsl:variable name="current" select="."/>
169      <xsl:for-each select="$target">
170        <!-- make it the context -->
171        <xsl:choose>
172          <xsl:when test="self::preamble">
173            <!-- it's not an element we can link to -->
174            <xsl:call-template name="warning">
175              <xsl:with-param name="inline" select="'no'"/>
176              <xsl:with-param name="msg">couldn't create the link as <xsl:value-of select="name()"/> does not support the anchor attribute.</xsl:with-param>
177            </xsl:call-template>
178            <xsl:value-of select="$current"/>
179          </xsl:when>
180          <xsl:otherwise>
181            <xref target="{$target/@anchor}" format="none"><xsl:value-of select="$current"/></xref>
182          </xsl:otherwise>
183        </xsl:choose>
184      </xsl:for-each>
185    </xsl:when>
186    <xsl:otherwise>
187      <xsl:call-template name="warning">
188        <xsl:with-param name="inline" select="'no'"/>
189        <xsl:with-param name="msg">internal link target for '<xsl:value-of select="."/>' does not exist.</xsl:with-param>
190      </xsl:call-template>
191      <xsl:value-of select="."/>
192    </xsl:otherwise>
193  </xsl:choose>
194</xsl:template>
195
196<xsl:template match="x:blockquote" mode="cleanup">
197  <t><list>
198    <xsl:apply-templates mode="cleanup" />
199  </list></t>
200</xsl:template>
201
202<xsl:template match="x:h" mode="cleanup">
203  <xsl:apply-templates mode="cleanup" />
204</xsl:template>
205
206<xsl:template match="x:highlight" mode="cleanup">
207  <xsl:apply-templates mode="cleanup" />
208</xsl:template>
209
210<xsl:template match="x:lt" mode="cleanup">
211  <t>
212    <xsl:apply-templates select="@hangText|@anchor" mode="cleanup"/>
213    <xsl:for-each select="t">
214      <xsl:apply-templates mode="cleanup"/>
215      <xsl:if test="position()!=last()">
216        <vspace blankLines="1"/>
217      </xsl:if>
218    </xsl:for-each>
219  </t>
220</xsl:template>
221
222<xsl:template match="x:note" mode="cleanup">
223  <t>
224    <list>
225      <xsl:apply-templates mode="cleanup"/>
226    </list>
227  </t>
228</xsl:template>
229
230<xsl:template match="x:q" mode="cleanup">
231  <xsl:text>"</xsl:text>
232  <xsl:apply-templates mode="cleanup"/>
233  <xsl:text>"</xsl:text>
234</xsl:template>
235
236<xsl:template match="x:dfn" mode="cleanup">
237  <!-- help xml2rfc to keep dfn and following text on the same page -->
238  <xsl:if test="not(preceding-sibling::x:dfn) and count(following-sibling::list)=1">
239    <xsl:processing-instruction name="rfc">needLines="4"</xsl:processing-instruction>
240  </xsl:if>
241  <xsl:apply-templates mode="cleanup"/>
242</xsl:template>
243
244<xsl:template match="x:sup" mode="cleanup">
245  <xsl:text>^</xsl:text>
246  <xsl:apply-templates mode="cleanup" />
247</xsl:template>
248
249<xsl:template match="x:span" mode="cleanup">
250  <xsl:apply-templates mode="cleanup" />
251</xsl:template>
252<xsl:template match="x:span/@anchor" mode="cleanup"/>
253
254<xsl:template match="author/@anchor" mode="cleanup"/>
255<xsl:template match="x:include-author" mode="cleanup">
256  <t>
257    <xsl:value-of select="/*/front/author[@anchor=current()/@target]"/>
258  </t>
259  <t>
260    (see Authors Section)
261  </t>
262</xsl:template>
263
264<!-- extended reference formatting -->
265
266<xsl:template match="xref[(@x:fmt or @x:sec or @x:rel) and not(node())]" mode="cleanup">
267  <xsl:call-template name="insert-iref-for-xref"/>
268  <xsl:variable name="node" select="$src//*[@anchor=current()/@target]" />
269
270  <xsl:variable name="sec">
271    <xsl:choose>
272      <xsl:when test="starts-with(@x:rel,'#') and not(@x:sec) and $node/x:source/@href">
273        <xsl:variable name="extdoc" select="document($node/x:source/@href)"/>
274        <xsl:for-each select="$extdoc//*[@anchor=substring-after(current()/@x:rel,'#')]">
275          <xsl:call-template name="get-section-number"/>
276        </xsl:for-each>
277      </xsl:when>
278      <xsl:otherwise>
279        <xsl:value-of select="@x:sec"/>
280      </xsl:otherwise>
281    </xsl:choose>
282  </xsl:variable>
283
284  <xsl:variable name="secterm">
285    <xsl:choose>
286      <!-- starts with letter? -->
287      <xsl:when test="translate(substring($sec,1,1),$ucase,'')=''">Appendix</xsl:when>
288      <xsl:otherwise>Section</xsl:otherwise>
289    </xsl:choose>
290  </xsl:variable>
291
292  <xsl:variable name="fmt">
293    <xsl:choose>
294      <xsl:when test="@x:fmt!=''"><xsl:value-of select="@x:fmt"/></xsl:when>
295      <xsl:when test="ancestor::artwork">,</xsl:when>
296      <xsl:otherwise>of</xsl:otherwise>
297    </xsl:choose>
298  </xsl:variable>
299
300  <xsl:choose>
301    <xsl:when test="$fmt=','">
302      <xref>
303        <xsl:apply-templates select="@target|@format|@pageno|text()|*" mode="cleanup"/>
304      </xref>
305      <xsl:text>, </xsl:text>
306      <xsl:value-of select="$secterm"/>
307      <xsl:text> </xsl:text>
308      <xsl:value-of select="$sec"/>
309    </xsl:when>
310    <xsl:when test="$fmt='sec'">
311      <xsl:value-of select="$secterm"/>
312      <xsl:text> </xsl:text>
313      <xsl:value-of select="$sec"/>
314    </xsl:when>
315    <xsl:when test="$fmt='number'">
316      <xsl:value-of select="$sec"/>
317    </xsl:when>
318    <xsl:when test="$fmt='()'">
319      <xref>
320        <xsl:apply-templates select="@target|@format|@pageno|text()|*" mode="cleanup"/>
321      </xref>
322      <xsl:text> (</xsl:text>
323      <xsl:value-of select="$secterm"/>
324      <xsl:text> </xsl:text>
325      <xsl:value-of select="$sec"/>
326      <xsl:text>)</xsl:text>
327    </xsl:when>
328    <xsl:when test="$fmt='of'">
329      <xsl:value-of select="$secterm"/>
330      <xsl:text> </xsl:text>
331      <xsl:value-of select="$sec"/>
332      <xsl:text> of </xsl:text>
333      <xref>
334        <xsl:apply-templates select="@target|@format|@pageno|text()|*" mode="cleanup"/>
335      </xref>
336    </xsl:when>
337    <xsl:when test="$fmt='anchor'">
338      <xsl:variable name="val">
339        <xsl:call-template name="referencename">
340          <xsl:with-param name="node" select="$node" />
341        </xsl:call-template>
342      </xsl:variable>
343      <!-- remove brackets -->
344      <xsl:value-of select="substring($val,2,string-length($val)-2)"/>
345    </xsl:when>
346    <xsl:otherwise>
347      <xsl:copy>
348        <xsl:apply-templates select="node()" mode="cleanup"/>
349      </xsl:copy>
350    </xsl:otherwise>
351  </xsl:choose>
352</xsl:template>
353
354<xsl:template match="xref[(@x:fmt or @x:sec or @x:rel) and node()]" mode="cleanup">
355  <xsl:call-template name="insert-iref-for-xref"/>
356  <xsl:choose>
357    <xsl:when test="@x:fmt='none'">
358      <xsl:apply-templates mode="cleanup"/>
359    </xsl:when>
360    <xsl:when test="not(@x:fmt)">
361      <xref>
362        <xsl:copy-of select="@target|@format"/>
363        <xsl:apply-templates mode="cleanup"/>
364      </xref>
365    </xsl:when>
366    <xsl:otherwise>
367      <xsl:message>Unsupported x:fmt attribute.</xsl:message>
368    </xsl:otherwise>
369  </xsl:choose>
370</xsl:template>
371
372<xsl:template match="xref[node() and (@target=//preamble/@anchor or @target=//spanx/@anchor)]" mode="cleanup">
373  <!-- remove the link -->
374  <xsl:apply-templates select="node()" mode="cleanup"/>
375</xsl:template>
376
377<xsl:template match="xref[not(node()) and (@target=//preamble/@anchor or @target=//spanx/@anchor)]" mode="cleanup">
378  <!-- fatal -->
379  <xsl:message terminate="yes">Broken xref <xsl:value-of select="@target"/> due to target being filtered out.</xsl:message>
380</xsl:template>
381
382<xsl:template match="xref" mode="cleanup" priority="0">
383  <xsl:call-template name="insert-iref-for-xref"/>
384  <xref>
385    <xsl:copy-of select="@target|@format"/>
386    <xsl:apply-templates mode="cleanup"/>
387  </xref>
388</xsl:template>
389
390<xsl:template name="insert-iref-for-xref">
391  <xsl:if test="$xml2rfc-ext-include-references-in-index='yesxxx' and $xml2rfc-ext-include-index='yes'">
392    <xsl:if test="@target=/rfc/back//reference/@anchor">
393      <iref item="{@target}"/>
394      <xsl:if test="@x:sec">
395        <xsl:choose>
396          <xsl:when test="translate(substring(@x:sec,1,1),$ucase,'')=''">
397            <iref item="{@target}" subitem="Appendix {@x:sec}"/>
398          </xsl:when>
399          <xsl:otherwise>
400            <iref item="{@target}" subitem="Section {@x:sec}"/>
401          </xsl:otherwise>
402        </xsl:choose>
403      </xsl:if>
404    </xsl:if>
405  </xsl:if>
406</xsl:template>
407
408<!-- drop index gen extension -->
409<xsl:template match="iref" mode="cleanup">
410  <xsl:if test="$xml2rfc-ext-include-index='yes'">
411    <iref>
412      <xsl:apply-templates select="@*|node()" mode="cleanup"/>
413    </iref>
414  </xsl:if>
415</xsl:template>
416
417
418<!-- issue tracking extensions -->
419
420<xsl:template match="@xml:lang" mode="cleanup"/>
421<xsl:template match="@xml:lang" />
422
423<xsl:template match="ed:*" mode="cleanup"/>
424<xsl:template match="ed:*" />
425
426<xsl:template match="@ed:*" mode="cleanup"/>
427<xsl:template match="@ed:*" />
428
429<xsl:template match="ed:annotation" mode="cleanup" />
430
431<xsl:template match="ed:replace" mode="cleanup">
432  <xsl:apply-templates mode="cleanup" />
433</xsl:template>
434
435<xsl:template match="ed:replace">
436  <xsl:apply-templates/>
437</xsl:template>
438
439<xsl:template match="ed:ins" mode="cleanup">
440  <xsl:apply-templates mode="cleanup"/>
441</xsl:template>
442
443<xsl:template match="ed:ins">
444  <xsl:apply-templates/>
445</xsl:template>
446
447<xsl:template match="ed:issue" mode="issues">
448  <section title="{@name}">
449    <xsl:variable name="sec">
450      <xsl:call-template name="get-section-number"/>
451    </xsl:variable>
452
453    <xsl:if test="$sec!=''">
454      <t>
455        In Section <xsl:value-of select="$sec"/>:
456      </t>
457    </xsl:if>
458   
459    <t>
460      Type: <xsl:value-of select="@type" />
461    </t>
462    <xsl:if test="@href">
463      <t>
464        <!-- temp. removed because of xml2rfc's handling of erefs when producing TXT-->
465        <!--<eref target="{@href}" /> -->
466        <xsl:text>&lt;</xsl:text>
467        <xsl:value-of select="@href"/>
468        <xsl:text>></xsl:text>
469        <xsl:if test="@alternate-href">
470          <xsl:text>, &lt;</xsl:text>
471          <xsl:value-of select="@alternate-href"/>
472          <xsl:text>></xsl:text>
473        </xsl:if>
474      </t>
475    </xsl:if>
476    <xsl:for-each select="ed:item">
477      <t>
478        <xsl:if test="@entered-by or @date">
479          <xsl:choose>
480            <xsl:when test="not(@entered-by)">
481              <xsl:value-of select="concat('(',@date,') ')" />
482            </xsl:when>
483            <xsl:when test="not(@date)">
484              <xsl:value-of select="concat(@entered-by,': ')" />
485            </xsl:when>
486            <xsl:otherwise>
487              <xsl:value-of select="concat(@entered-by,' (',@date,'): ')" />
488            </xsl:otherwise>
489          </xsl:choose>     
490        </xsl:if>
491        <xsl:if test="not(xhtml:p)">
492          <xsl:apply-templates select="node()" mode="issues"/>
493        </xsl:if>
494      </t>
495      <xsl:if test="xhtml:p|xhtml:pre">
496        <xsl:for-each select="node()">
497          <xsl:choose>
498            <xsl:when test="self::xhtml:p">
499              <t>
500                <xsl:apply-templates select="node()" mode="issues"/>
501              </t>
502            </xsl:when>
503            <xsl:when test="self::xhtml:pre">
504              <figure>
505                <artwork><xsl:apply-templates select="node()" mode="issues"/></artwork>
506              </figure>
507            </xsl:when>
508            <xsl:otherwise>
509              <t>
510                <xsl:apply-templates select="." mode="issues"/>
511              </t>
512            </xsl:otherwise>
513          </xsl:choose>
514        </xsl:for-each>
515      </xsl:if>
516    </xsl:for-each> 
517    <xsl:if test="ed:resolution">
518      <t>
519        <xsl:text>Resolution</xsl:text>
520        <xsl:if test="ed:resolution/@datetime"> (<xsl:value-of select="ed:resolution/@datetime"/>)</xsl:if>
521        <xsl:text>: </xsl:text>
522        <xsl:value-of select="ed:resolution" />
523      </t>
524    </xsl:if>
525  </section>
526</xsl:template>
527
528<xsl:template match="ed:issueref" mode="cleanup">
529  <xsl:apply-templates mode="cleanup"/>
530</xsl:template>
531
532<xsl:template match="*" mode="issues">
533  <xsl:apply-templates mode="issues"/>
534</xsl:template>
535
536<xsl:template match="xhtml:q" mode="issues">
537  <list><t>
538    <xsl:text>"</xsl:text>
539    <xsl:apply-templates mode="issues"/>
540    <xsl:text>"</xsl:text>
541    <xsl:if test="@cite">
542      <xsl:text> -- </xsl:text>
543      <eref target="{@cite}"><xsl:value-of select="@cite"/></eref>
544    </xsl:if>
545  </t></list>
546</xsl:template>
547
548<xsl:template match="xhtml:br" mode="issues">
549  <vspace/>
550</xsl:template>
551
552<xsl:template match="xhtml:del" mode="issues">
553  <xsl:text>&lt;del></xsl:text>
554    <xsl:apply-templates mode="issues"/>
555  <xsl:text>&lt;/del></xsl:text>
556</xsl:template>
557
558<xsl:template match="xhtml:em" mode="issues">
559  <spanx style="emph">
560    <xsl:apply-templates mode="issues"/>
561  </spanx>
562</xsl:template>
563
564<xsl:template match="xhtml:ins" mode="issues">
565  <xsl:text>&lt;ins></xsl:text>
566    <xsl:apply-templates mode="issues"/>
567  <xsl:text>&lt;/ins></xsl:text>
568</xsl:template>
569
570<xsl:template match="xhtml:tt" mode="issues">
571  <xsl:apply-templates mode="issues"/>
572</xsl:template>
573
574<xsl:template match="ed:eref" mode="issues">
575  <xsl:text>&lt;</xsl:text>
576  <xsl:value-of select="."/>
577  <xsl:text>&gt;</xsl:text>
578</xsl:template>
579
580<xsl:template match="ed:issueref" mode="issues">
581  <xsl:apply-templates mode="issues"/>
582</xsl:template>
583
584<xsl:template match="text()" mode="issues">
585  <xsl:value-of select="." />
586</xsl:template>
587
588
589
590<!-- markup inside artwork element -->
591
592<xsl:template match="figure[.//artwork//iref | .//artwork//xref]" mode="cleanup">
593  <!-- move up iref elements -->
594  <xsl:for-each select=".//artwork//xref">
595    <xsl:if test="not(ancestor::ed:del)">
596      <xsl:call-template name="insert-iref-for-xref"/>
597    </xsl:if>
598  </xsl:for-each>
599  <figure>
600    <xsl:apply-templates select="@*" mode="cleanup" />
601    <xsl:apply-templates select=".//artwork//iref" mode="cleanup"/>
602    <xsl:apply-templates select="iref|preamble|artwork|postamble|ed:replace|ed:ins|ed:del" mode="cleanup" />
603  </figure>
604</xsl:template>
605
606<xsl:template name="insert-begin-code"/>
607<xsl:template name="insert-end-code"/>
608<xsl:template match="@x:isCodeComponent" mode="cleanup"/>
609
610<xsl:template match="artwork" mode="cleanup">
611  <xsl:variable name="content2"><xsl:apply-templates select="."/></xsl:variable>
612  <xsl:variable name="content" select="translate($content2,'&#160;&#x2500;&#x2502;&#x2508;&#x250c;&#x2510;&#x2514;&#x2518;&#x251c;&#x2524;',' -|+++++++')"/>
613  <artwork>
614    <xsl:apply-templates select="@*" mode="cleanup" />
615    <xsl:if test="@x:isCodeComponent='yes'">
616      <xsl:if test="starts-with(.,'&#10;')">
617        <xsl:text>&#10;</xsl:text>
618      </xsl:if>
619      <xsl:value-of select="@x:indent-with"/>
620      <xsl:text>&lt;CODE BEGINS&gt;&#10;</xsl:text>
621    </xsl:if>
622    <xsl:if test="starts-with(.,'&#10;')">
623      <xsl:text>&#10;</xsl:text>
624      <xsl:value-of select="@x:indent-with"/>
625    </xsl:if>
626    <xsl:choose>
627      <xsl:when test="@x:indent-with!=''">
628        <xsl:call-template name="indent">
629          <xsl:with-param name="content" select="$content"/>
630          <xsl:with-param name="with" select="@x:indent-with"/>
631        </xsl:call-template>
632      </xsl:when>
633      <xsl:otherwise>
634        <xsl:value-of select="$content"/>
635      </xsl:otherwise>
636    </xsl:choose>
637    <xsl:if test="@x:isCodeComponent='yes'">&#10;&lt;CODE ENDS&gt;&#10;</xsl:if>
638  </artwork> 
639</xsl:template>
640
641<xsl:template match="@x:indent-with" mode="cleanup"/>
642
643<xsl:template name="indent">
644  <xsl:param name="content"/>
645  <xsl:param name="with"/>
646
647  <xsl:value-of select="substring($content,1,1)"/>
648  <xsl:if test="substring($content,1,1)='&#10;'">
649    <xsl:value-of select="$with"/>
650  </xsl:if>
651 
652  <xsl:choose>
653    <xsl:when test="$content=''" />
654    <xsl:otherwise>
655      <xsl:call-template name="indent">
656        <xsl:with-param name="content" select="substring($content,2)"/>
657        <xsl:with-param name="with" select="$with"/>
658      </xsl:call-template>
659    </xsl:otherwise>
660  </xsl:choose>
661 
662</xsl:template>
663
664<!-- email repetitions -->
665<xsl:template match="email" mode="cleanup">
666  <!-- combine in a single element -->
667  <xsl:if test="not(preceding-sibling::email)">
668    <email>
669      <xsl:for-each select="../email">
670        <xsl:value-of select="."/>
671        <xsl:if test="position()!=last()">
672          <xsl:text>, </xsl:text>
673        </xsl:if>
674      </xsl:for-each>
675    </email>
676  </xsl:if>
677</xsl:template>
678
679<!-- markup inside cref -->
680<xsl:template match="cref//eref" mode="cleanup">
681  <xsl:text>&lt;</xsl:text>
682  <xsl:value-of select="@target"/>
683  <xsl:text>&gt;</xsl:text>
684</xsl:template>
685
686<xsl:template match="cref//xref" mode="cleanup" priority="9">
687  <xsl:variable name="text">
688    <xsl:apply-templates select="."/>
689  </xsl:variable>
690  <xsl:value-of select="$text"/>
691</xsl:template>
692
693<!-- annotations -->
694<xsl:template match="@x:annotation" mode="cleanup">
695  <xsl:comment>
696    <xsl:value-of select="."/>
697  </xsl:comment>
698  <xsl:call-template name="warning">
699    <xsl:with-param name="inline" select="'no'"/>
700    <xsl:with-param name="msg">Dropping annotation on <xsl:value-of select="local-name(..)"/> element.</xsl:with-param>
701  </xsl:call-template>
702</xsl:template>
703
704<!-- artwork extensions -->
705<xsl:template match="artwork/@x:extraction-note" mode="cleanup"/>
706
707<!-- list formatting -->
708<xsl:template match="list/@x:indent" mode="cleanup"/>
709
710<!-- referencing extensions -->
711<xsl:template match="iref/@x:for-anchor" mode="cleanup"/>
712
713<!-- table styles -->
714<xsl:template match="texttable/@style" mode="cleanup"/>
715
716<!-- section numbering -->
717<xsl:template match="section/@x:fixed-section-number" mode="cleanup"/>
718
719<!-- GRRDL info stripped -->
720<xsl:template match="@grddl:transformation" mode="cleanup"/>
721
722<!-- maturity level stripped -->
723<xsl:template match="@x:maturity-level" mode="cleanup"/>
724
725<!-- normativity stripped -->
726<xsl:template match="@x:nrm" mode="cleanup"/>
727
728<!-- title extensions -->
729<xsl:template match="title/@x:quotes" mode="cleanup"/>
730
731<!-- RDF info stripped -->
732<xsl:template match="rdf:*" mode="cleanup"/>
733
734<!-- cases where xml2rfc does not allow anchors -->
735<xsl:template match="c/@anchor" mode="cleanup"/>
736<xsl:template match="preamble/@anchor" mode="cleanup"/>
737<xsl:template match="spanx/@anchor" mode="cleanup"/>
738
739</xsl:transform>
Note: See TracBrowser for help on using the repository browser.