source: rfc2629xslt/clean-for-DTD.xslt @ 1217

Last change on this file since 1217 was 981, checked in by julian.reschke@…, 9 years ago

bump up document dates, update to latest version of rfc2629.xslt

  • Property svn:eol-style set to native
File size: 23.5 KB
Line 
1<!--
2    Strip rfc2629.xslt extensions, generating XML input for MTR's xml2rfc
3
4    Copyright (c) 2006-2010, Julian Reschke (julian.reschke@greenbytes.de)
5    All rights reserved.
6
7    Redistribution and use in source and binary forms, with or without
8    modification, are permitted provided that the following conditions are met:
9
10    * Redistributions of source code must retain the above copyright notice,
11      this list of conditions and the following disclaimer.
12    * Redistributions in binary form must reproduce the above copyright notice,
13      this list of conditions and the following disclaimer in the documentation
14      and/or other materials provided with the distribution.
15    * Neither the name of Julian Reschke nor the names of its contributors
16      may be used to endorse or promote products derived from this software
17      without specific prior written permission.
18
19    THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
20    AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
21    IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
22    ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR CONTRIBUTORS BE
23    LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
24    CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
25    SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
26    INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
27    CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
28    ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
29    POSSIBILITY OF SUCH DAMAGE.
30-->
31
32<xsl:transform xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
33                version="1.0"
34                xmlns:ed="http://greenbytes.de/2002/rfcedit"
35                xmlns:grddl="http://www.w3.org/2003/g/data-view#"
36                xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#"
37                xmlns:x="http://purl.org/net/xml2rfc/ext"
38                xmlns:xhtml="http://www.w3.org/1999/xhtml"
39                exclude-result-prefixes="ed grddl rdf x xhtml"
40>
41
42<!-- re-use some of the default RFC2629.xslt rules -->
43<xsl:import href="rfc2629.xslt"/>
44
45<!-- undo strip-space decls -->
46<xsl:preserve-space elements="*"/>
47
48<!-- generate DTD-valid output, override all values imported from rfc2629.xslt -->
49<xsl:output doctype-system="rfc2629.dtd" doctype-public="" method="xml" version="1.0" encoding="UTF-8" cdata-section-elements="artwork" />
50
51<!-- kick into cleanup mode -->
52<xsl:template match="/">
53  <xsl:text>&#10;</xsl:text>
54  <xsl:comment>
55    This XML document is the output of clean-for-DTD.xslt; a tool that strips
56    extensions to RFC2629(bis) from documents for processing with xml2rfc.
57</xsl:comment>
58  <xsl:apply-templates select="/" mode="cleanup"/>
59</xsl:template>
60
61<!-- rules for identity transformations -->
62
63<xsl:template match="processing-instruction()" mode="cleanup">
64  <xsl:text>&#10;</xsl:text>
65  <xsl:copy/>
66</xsl:template>
67
68<xsl:template match="comment()|@*" mode="cleanup"><xsl:copy/></xsl:template>
69
70<xsl:template match="text()" mode="cleanup"><xsl:copy/></xsl:template>
71
72<xsl:template match="/" mode="cleanup">
73        <xsl:copy><xsl:apply-templates select="node()" mode="cleanup" /></xsl:copy>
74</xsl:template>
75
76<xsl:template match="*" mode="cleanup">
77  <xsl:element name="{local-name()}">
78        <xsl:apply-templates select="node()|@*" mode="cleanup" />
79  </xsl:element>
80</xsl:template>
81
82
83<!-- remove PI extensions -->
84
85<xsl:template match="processing-instruction('rfc-ext')" mode="cleanup"/>
86<xsl:template match="processing-instruction('BEGININC')" mode="cleanup"/>
87<xsl:template match="processing-instruction('ENDINC')" mode="cleanup"/>
88
89<!-- add issues appendix -->
90
91<xsl:template match="back" mode="cleanup">
92  <back>
93    <xsl:apply-templates select="node()|@*" mode="cleanup" />
94    <xsl:if test="not(/*/@ed:suppress-issue-appendix='yes') and //ed:issue[@status='closed']">
95      <section title="Resolved issues (to be removed by RFC Editor before publication)">
96        <t>
97          Issues that were either rejected or resolved in this version of this
98          document.
99        </t>
100        <xsl:apply-templates select="//ed:issue[@status='closed']" mode="issues" />
101      </section>
102    </xsl:if>
103    <xsl:if test="not(/*/@ed:suppress-issue-appendix='yes') and //ed:issue[@status='open']">
104      <section title="Open issues (to be removed by RFC Editor prior to publication)">
105        <xsl:apply-templates select="//ed:issue[@status!='closed']" mode="issues" />
106      </section>
107    </xsl:if>
108  </back>
109</xsl:template>
110
111
112
113
114<!-- extensions -->
115
116<xsl:template match="x:abnf-char-sequence" mode="cleanup">
117  <xsl:choose>
118    <xsl:when test="substring(.,1,1) != '&quot;' or substring(.,string-length(.),1) != '&quot;'">
119      <xsl:call-template name="error">
120        <xsl:with-param name="msg" select="'contents of x:abnf-char-sequence needs to be quoted.'" />
121      </xsl:call-template>
122    </xsl:when>
123    <xsl:otherwise>
124      <xsl:text>%x</xsl:text>
125      <xsl:call-template name="to-abnf-char-sequence">
126        <xsl:with-param name="chars" select="substring(.,2,string-length(.)-2)"/>
127      </xsl:call-template>
128    </xsl:otherwise>
129  </xsl:choose>
130</xsl:template>
131
132<xsl:template match="x:anchor-alias" mode="cleanup"/>
133
134<xsl:template match="x:bcp14" mode="cleanup">
135  <xsl:apply-templates/>
136</xsl:template>
137
138<xsl:template match="x:assign-section-number" mode="cleanup"/> 
139<xsl:template match="x:link" mode="cleanup"/>
140<xsl:template match="x:source" mode="cleanup"/>
141
142<xsl:template match="x:parse-xml" mode="cleanup">
143  <xsl:apply-templates/>
144</xsl:template>
145
146<xsl:template match="x:prose" mode="cleanup">
147  <xsl:variable name="text" select="."/>
148  <xsl:comment>Converted from rfc2629.xslt x:prose extension</xsl:comment>
149  <xsl:choose>
150    <xsl:when test="contains($text,' ')">
151      <seriesInfo name="{substring-before($text,' ')}" value="{substring-after($text,' ')}"/>
152    </xsl:when>
153    <xsl:otherwise>
154      <seriesInfo name="" value="{$text}"/>
155    </xsl:otherwise>
156  </xsl:choose>
157</xsl:template>
158
159<xsl:template match="x:ref" mode="cleanup">
160  <xsl:variable name="val" select="."/>
161  <xsl:variable name="target" select="//*[@anchor and (@anchor=$val or x:anchor-alias/@value=$val)][not(ancestor::ed:del)]"/>
162  <xsl:choose>
163    <xsl:when test="$target">
164      <xsl:if test="count($target)!=1">
165        <xsl:message terminate="yes">FATAL: multiple x:ref targets found for <xsl:value-of select="$val"/>.</xsl:message>
166      </xsl:if>
167      <xsl:variable name="current" select="."/>
168      <xsl:for-each select="$target">
169        <!-- make it the context -->
170        <xsl:choose>
171          <xsl:when test="self::preamble">
172            <!-- it's not an element we can link to -->
173            <xsl:call-template name="warning">
174              <xsl:with-param name="inline" select="'no'"/>
175              <xsl:with-param name="msg">couldn't create the link as <xsl:value-of select="name()"/> does not support the anchor attribute.</xsl:with-param>
176            </xsl:call-template>
177            <xsl:value-of select="$current"/>
178          </xsl:when>
179          <xsl:otherwise>
180            <xref target="{$target/@anchor}" format="none"><xsl:value-of select="$current"/></xref>
181          </xsl:otherwise>
182        </xsl:choose>
183      </xsl:for-each>
184    </xsl:when>
185    <xsl:otherwise>
186      <xsl:call-template name="warning">
187        <xsl:with-param name="inline" select="'no'"/>
188        <xsl:with-param name="msg">internal link target for '<xsl:value-of select="."/>' does not exist.</xsl:with-param>
189      </xsl:call-template>
190      <xsl:value-of select="."/>
191    </xsl:otherwise>
192  </xsl:choose>
193</xsl:template>
194
195<xsl:template match="x:blockquote" mode="cleanup">
196  <t><list>
197    <xsl:apply-templates mode="cleanup" />
198  </list></t>
199</xsl:template>
200
201<xsl:template match="x:h" mode="cleanup">
202  <xsl:apply-templates mode="cleanup" />
203</xsl:template>
204
205<xsl:template match="x:highlight" mode="cleanup">
206  <xsl:apply-templates mode="cleanup" />
207</xsl:template>
208
209<xsl:template match="x:lt" mode="cleanup">
210  <t>
211    <xsl:apply-templates select="@hangText|@anchor" mode="cleanup"/>
212    <xsl:for-each select="t">
213      <xsl:apply-templates mode="cleanup"/>
214      <xsl:if test="position()!=last()">
215        <vspace blankLines="1"/>
216      </xsl:if>
217    </xsl:for-each>
218  </t>
219</xsl:template>
220
221<xsl:template match="x:note" mode="cleanup">
222  <t>
223    <list>
224      <xsl:apply-templates mode="cleanup"/>
225    </list>
226  </t>
227</xsl:template>
228
229<xsl:template match="x:q" mode="cleanup">
230  <xsl:text>"</xsl:text>
231  <xsl:apply-templates mode="cleanup"/>
232  <xsl:text>"</xsl:text>
233</xsl:template>
234
235<xsl:template match="x:dfn" mode="cleanup">
236  <!-- help xml2rfc to keep dfn and following text on the same page -->
237  <xsl:if test="not(preceding-sibling::x:dfn) and count(following-sibling::list)=1">
238    <xsl:processing-instruction name="rfc">needLines="4"</xsl:processing-instruction>
239  </xsl:if>
240  <xsl:apply-templates mode="cleanup"/>
241</xsl:template>
242
243<xsl:template match="x:sup" mode="cleanup">
244  <xsl:text>^</xsl:text>
245  <xsl:apply-templates mode="cleanup" />
246</xsl:template>
247
248<xsl:template match="x:span" mode="cleanup">
249  <xsl:apply-templates mode="cleanup" />
250</xsl:template>
251<xsl:template match="x:span/@anchor" mode="cleanup"/>
252
253<xsl:template match="author/@anchor" mode="cleanup"/>
254<xsl:template match="x:include-author" mode="cleanup">
255  <t>
256    <xsl:value-of select="/*/front/author[@anchor=current()/@target]"/>
257  </t>
258  <t>
259    (see Authors Section)
260  </t>
261</xsl:template>
262
263<!-- extended reference formatting -->
264
265<xsl:template match="xref[(@x:fmt or @x:sec or @x:rel) and not(node())]" mode="cleanup">
266  <xsl:call-template name="insert-iref-for-xref"/>
267  <xsl:variable name="node" select="$src//*[@anchor=current()/@target]" />
268
269  <xsl:variable name="sec">
270    <xsl:choose>
271      <xsl:when test="starts-with(@x:rel,'#') and not(@x:sec) and $node/x:source/@href">
272        <xsl:variable name="extdoc" select="document($node/x:source/@href)"/>
273        <xsl:for-each select="$extdoc//*[@anchor=substring-after(current()/@x:rel,'#')]">
274          <xsl:call-template name="get-section-number"/>
275        </xsl:for-each>
276      </xsl:when>
277      <xsl:otherwise>
278        <xsl:value-of select="@x:sec"/>
279      </xsl:otherwise>
280    </xsl:choose>
281  </xsl:variable>
282
283  <xsl:variable name="secterm">
284    <xsl:choose>
285      <!-- starts with letter? -->
286      <xsl:when test="translate(substring($sec,1,1),$ucase,'')=''">Appendix</xsl:when>
287      <xsl:otherwise>Section</xsl:otherwise>
288    </xsl:choose>
289  </xsl:variable>
290
291  <xsl:variable name="fmt">
292    <xsl:choose>
293      <xsl:when test="@x:fmt!=''"><xsl:value-of select="@x:fmt"/></xsl:when>
294      <xsl:when test="ancestor::artwork">,</xsl:when>
295      <xsl:otherwise>of</xsl:otherwise>
296    </xsl:choose>
297  </xsl:variable>
298
299  <xsl:choose>
300    <xsl:when test="$fmt=','">
301      <xref>
302        <xsl:apply-templates select="@target|@format|@pageno|text()|*" mode="cleanup"/>
303      </xref>
304      <xsl:text>, </xsl:text>
305      <xsl:value-of select="$secterm"/>
306      <xsl:text> </xsl:text>
307      <xsl:value-of select="$sec"/>
308    </xsl:when>
309    <xsl:when test="$fmt='sec'">
310      <xsl:value-of select="$secterm"/>
311      <xsl:text> </xsl:text>
312      <xsl:value-of select="$sec"/>
313    </xsl:when>
314    <xsl:when test="$fmt='number'">
315      <xsl:value-of select="$sec"/>
316    </xsl:when>
317    <xsl:when test="$fmt='()'">
318      <xref>
319        <xsl:apply-templates select="@target|@format|@pageno|text()|*" mode="cleanup"/>
320      </xref>
321      <xsl:text> (</xsl:text>
322      <xsl:value-of select="$secterm"/>
323      <xsl:text> </xsl:text>
324      <xsl:value-of select="$sec"/>
325      <xsl:text>)</xsl:text>
326    </xsl:when>
327    <xsl:when test="$fmt='of'">
328      <xsl:value-of select="$secterm"/>
329      <xsl:text> </xsl:text>
330      <xsl:value-of select="$sec"/>
331      <xsl:text> of </xsl:text>
332      <xref>
333        <xsl:apply-templates select="@target|@format|@pageno|text()|*" mode="cleanup"/>
334      </xref>
335    </xsl:when>
336    <xsl:when test="$fmt='anchor'">
337      <xsl:variable name="val">
338        <xsl:call-template name="referencename">
339          <xsl:with-param name="node" select="$node" />
340        </xsl:call-template>
341      </xsl:variable>
342      <!-- remove brackets -->
343      <xsl:value-of select="substring($val,2,string-length($val)-2)"/>
344    </xsl:when>
345    <xsl:otherwise>
346      <xsl:copy>
347        <xsl:apply-templates select="node()" mode="cleanup"/>
348      </xsl:copy>
349    </xsl:otherwise>
350  </xsl:choose>
351</xsl:template>
352
353<xsl:template match="xref[(@x:fmt or @x:sec or @x:rel) and node()]" mode="cleanup">
354  <xsl:call-template name="insert-iref-for-xref"/>
355  <xsl:choose>
356    <xsl:when test="@x:fmt='none'">
357      <xsl:apply-templates mode="cleanup"/>
358    </xsl:when>
359    <xsl:when test="not(@x:fmt)">
360      <xref>
361        <xsl:copy-of select="@target|@format"/>
362        <xsl:apply-templates mode="cleanup"/>
363      </xref>
364    </xsl:when>
365    <xsl:otherwise>
366      <xsl:message>Unsupported x:fmt attribute.</xsl:message>
367    </xsl:otherwise>
368  </xsl:choose>
369</xsl:template>
370
371<xsl:template match="xref[node() and (@target=//preamble/@anchor or @target=//spanx/@anchor)]" mode="cleanup">
372  <!-- remove the link -->
373  <xsl:apply-templates select="node()" mode="cleanup"/>
374</xsl:template>
375
376<xsl:template match="xref[not(node()) and (@target=//preamble/@anchor or @target=//spanx/@anchor)]" mode="cleanup">
377  <!-- fatal -->
378  <xsl:message terminate="yes">Broken xref <xsl:value-of select="@target"/> due to target being filtered out.</xsl:message>
379</xsl:template>
380
381<xsl:template match="xref" mode="cleanup" priority="0">
382  <xsl:call-template name="insert-iref-for-xref"/>
383  <xref>
384    <xsl:copy-of select="@target|@format"/>
385    <xsl:apply-templates mode="cleanup"/>
386  </xref>
387</xsl:template>
388
389<xsl:template name="insert-iref-for-xref">
390  <xsl:if test="$xml2rfc-ext-include-references-in-index='yesxxx'">
391    <xsl:if test="@target=/rfc/back//reference/@anchor">
392      <iref item="{@target}"/>
393      <xsl:if test="@x:sec">
394        <xsl:choose>
395          <xsl:when test="translate(substring(@x:sec,1,1),$ucase,'')=''">
396            <iref item="{@target}" subitem="Appendix {@x:sec}"/>
397          </xsl:when>
398          <xsl:otherwise>
399            <iref item="{@target}" subitem="Section {@x:sec}"/>
400          </xsl:otherwise>
401        </xsl:choose>
402      </xsl:if>
403    </xsl:if>
404  </xsl:if>
405</xsl:template>
406
407<!-- issue tracking extensions -->
408
409<xsl:template match="@xml:lang" mode="cleanup"/>
410<xsl:template match="@xml:lang" />
411
412<xsl:template match="ed:*" mode="cleanup"/>
413<xsl:template match="ed:*" />
414
415<xsl:template match="@ed:*" mode="cleanup"/>
416<xsl:template match="@ed:*" />
417
418<xsl:template match="ed:annotation" mode="cleanup" />
419
420<xsl:template match="ed:replace" mode="cleanup">
421  <xsl:apply-templates mode="cleanup" />
422</xsl:template>
423
424<xsl:template match="ed:replace">
425  <xsl:apply-templates/>
426</xsl:template>
427
428<xsl:template match="ed:ins" mode="cleanup">
429  <xsl:apply-templates mode="cleanup"/>
430</xsl:template>
431
432<xsl:template match="ed:ins">
433  <xsl:apply-templates/>
434</xsl:template>
435
436<xsl:template match="ed:issue" mode="issues">
437  <section title="{@name}">
438    <xsl:variable name="sec">
439      <xsl:call-template name="get-section-number"/>
440    </xsl:variable>
441
442    <xsl:if test="$sec!=''">
443      <t>
444        In Section <xsl:value-of select="$sec"/>:
445      </t>
446    </xsl:if>
447   
448    <t>
449      Type: <xsl:value-of select="@type" />
450    </t>
451    <xsl:if test="@href">
452      <t>
453        <!-- temp. removed because of xml2rfc's handling of erefs when producing TXT-->
454        <!--<eref target="{@href}" /> -->
455        <xsl:text>&lt;</xsl:text>
456        <xsl:value-of select="@href"/>
457        <xsl:text>></xsl:text>
458        <xsl:if test="@alternate-href">
459          <xsl:text>, &lt;</xsl:text>
460          <xsl:value-of select="@alternate-href"/>
461          <xsl:text>></xsl:text>
462        </xsl:if>
463      </t>
464    </xsl:if>
465    <xsl:for-each select="ed:item">
466      <t>
467        <xsl:if test="@entered-by or @date">
468          <xsl:choose>
469            <xsl:when test="not(@entered-by)">
470              <xsl:value-of select="concat('(',@date,') ')" />
471            </xsl:when>
472            <xsl:when test="not(@date)">
473              <xsl:value-of select="concat(@entered-by,': ')" />
474            </xsl:when>
475            <xsl:otherwise>
476              <xsl:value-of select="concat(@entered-by,' (',@date,'): ')" />
477            </xsl:otherwise>
478          </xsl:choose>     
479        </xsl:if>
480        <xsl:if test="not(xhtml:p)">
481          <xsl:apply-templates select="node()" mode="issues"/>
482        </xsl:if>
483      </t>
484      <xsl:if test="xhtml:p|xhtml:pre">
485        <xsl:for-each select="node()">
486          <xsl:choose>
487            <xsl:when test="self::xhtml:p">
488              <t>
489                <xsl:apply-templates select="node()" mode="issues"/>
490              </t>
491            </xsl:when>
492            <xsl:when test="self::xhtml:pre">
493              <figure>
494                <artwork><xsl:apply-templates select="node()" mode="issues"/></artwork>
495              </figure>
496            </xsl:when>
497            <xsl:otherwise>
498              <t>
499                <xsl:apply-templates select="." mode="issues"/>
500              </t>
501            </xsl:otherwise>
502          </xsl:choose>
503        </xsl:for-each>
504      </xsl:if>
505    </xsl:for-each> 
506    <xsl:if test="ed:resolution">
507      <t>
508        <xsl:text>Resolution</xsl:text>
509        <xsl:if test="ed:resolution/@datetime"> (<xsl:value-of select="ed:resolution/@datetime"/>)</xsl:if>
510        <xsl:text>: </xsl:text>
511        <xsl:value-of select="ed:resolution" />
512      </t>
513    </xsl:if>
514  </section>
515</xsl:template>
516
517<xsl:template match="ed:issueref" mode="cleanup">
518  <xsl:apply-templates mode="cleanup"/>
519</xsl:template>
520
521<xsl:template match="*" mode="issues">
522  <xsl:apply-templates mode="issues"/>
523</xsl:template>
524
525<xsl:template match="xhtml:q" mode="issues">
526  <list><t>
527    <xsl:text>"</xsl:text>
528    <xsl:apply-templates mode="issues"/>
529    <xsl:text>"</xsl:text>
530    <xsl:if test="@cite">
531      <xsl:text> -- </xsl:text>
532      <eref target="{@cite}"><xsl:value-of select="@cite"/></eref>
533    </xsl:if>
534  </t></list>
535</xsl:template>
536
537<xsl:template match="xhtml:br" mode="issues">
538  <vspace/>
539</xsl:template>
540
541<xsl:template match="xhtml:del" mode="issues">
542  <xsl:text>&lt;del></xsl:text>
543    <xsl:apply-templates mode="issues"/>
544  <xsl:text>&lt;/del></xsl:text>
545</xsl:template>
546
547<xsl:template match="xhtml:em" mode="issues">
548  <spanx style="emph">
549    <xsl:apply-templates mode="issues"/>
550  </spanx>
551</xsl:template>
552
553<xsl:template match="xhtml:ins" mode="issues">
554  <xsl:text>&lt;ins></xsl:text>
555    <xsl:apply-templates mode="issues"/>
556  <xsl:text>&lt;/ins></xsl:text>
557</xsl:template>
558
559<xsl:template match="xhtml:tt" mode="issues">
560  <xsl:apply-templates mode="issues"/>
561</xsl:template>
562
563<xsl:template match="ed:eref" mode="issues">
564  <xsl:text>&lt;</xsl:text>
565  <xsl:value-of select="."/>
566  <xsl:text>&gt;</xsl:text>
567</xsl:template>
568
569<xsl:template match="ed:issueref" mode="issues">
570  <xsl:apply-templates mode="issues"/>
571</xsl:template>
572
573<xsl:template match="text()" mode="issues">
574  <xsl:value-of select="." />
575</xsl:template>
576
577
578
579<!-- markup inside artwork element -->
580
581<xsl:template match="figure[.//artwork//iref | .//artwork//xref]" mode="cleanup">
582  <!-- move up iref elements -->
583  <xsl:for-each select=".//artwork//xref">
584    <xsl:if test="not(ancestor::ed:del)">
585      <xsl:call-template name="insert-iref-for-xref"/>
586    </xsl:if>
587  </xsl:for-each>
588  <figure>
589    <xsl:apply-templates select="@*" mode="cleanup" />
590    <xsl:apply-templates select=".//artwork//iref" mode="cleanup"/>
591    <xsl:apply-templates select="iref|preamble|artwork|postamble|ed:replace|ed:ins|ed:del" mode="cleanup" />
592  </figure>
593</xsl:template>
594
595<xsl:template name="insert-begin-code"/>
596<xsl:template name="insert-end-code"/>
597<xsl:template match="@x:isCodeComponent" mode="cleanup"/>
598
599<xsl:template match="artwork" mode="cleanup">
600  <xsl:variable name="content2"><xsl:apply-templates select="."/></xsl:variable>
601  <xsl:variable name="content" select="translate($content2,'&#160;&#x2500;&#x2502;&#x2508;&#x250c;&#x2510;&#x2514;&#x2518;&#x251c;&#x2524;',' -|+++++++')"/>
602  <artwork>
603    <xsl:apply-templates select="@*" mode="cleanup" />
604    <xsl:if test="@x:isCodeComponent='yes'">
605      <xsl:if test="starts-with(.,'&#10;')">
606        <xsl:text>&#10;</xsl:text>
607      </xsl:if>
608      <xsl:value-of select="@x:indent-with"/>
609      <xsl:text>&lt;CODE BEGINS&gt;&#10;</xsl:text>
610    </xsl:if>
611    <xsl:if test="starts-with(.,'&#10;')">
612      <xsl:text>&#10;</xsl:text>
613      <xsl:value-of select="@x:indent-with"/>
614    </xsl:if>
615    <xsl:choose>
616      <xsl:when test="@x:indent-with!=''">
617        <xsl:call-template name="indent">
618          <xsl:with-param name="content" select="$content"/>
619          <xsl:with-param name="with" select="@x:indent-with"/>
620        </xsl:call-template>
621      </xsl:when>
622      <xsl:otherwise>
623        <xsl:value-of select="$content"/>
624      </xsl:otherwise>
625    </xsl:choose>
626    <xsl:if test="@x:isCodeComponent='yes'">&#10;&lt;CODE ENDS&gt;&#10;</xsl:if>
627  </artwork> 
628</xsl:template>
629
630<xsl:template match="@x:indent-with" mode="cleanup"/>
631
632<xsl:template name="indent">
633  <xsl:param name="content"/>
634  <xsl:param name="with"/>
635
636  <xsl:value-of select="substring($content,1,1)"/>
637  <xsl:if test="substring($content,1,1)='&#10;'">
638    <xsl:value-of select="$with"/>
639  </xsl:if>
640 
641  <xsl:choose>
642    <xsl:when test="$content=''" />
643    <xsl:otherwise>
644      <xsl:call-template name="indent">
645        <xsl:with-param name="content" select="substring($content,2)"/>
646        <xsl:with-param name="with" select="$with"/>
647      </xsl:call-template>
648    </xsl:otherwise>
649  </xsl:choose>
650 
651</xsl:template>
652
653<!-- email repetitions -->
654<xsl:template match="email" mode="cleanup">
655  <!-- combine in a single element -->
656  <xsl:if test="not(preceding-sibling::email)">
657    <email>
658      <xsl:for-each select="../email">
659        <xsl:value-of select="."/>
660        <xsl:if test="position()!=last()">
661          <xsl:text>, </xsl:text>
662        </xsl:if>
663      </xsl:for-each>
664    </email>
665  </xsl:if>
666</xsl:template>
667
668<!-- markup inside cref -->
669<xsl:template match="cref//eref" mode="cleanup">
670  <xsl:text>&lt;</xsl:text>
671  <xsl:value-of select="@target"/>
672  <xsl:text>&gt;</xsl:text>
673</xsl:template>
674
675<xsl:template match="cref//xref" mode="cleanup" priority="9">
676  <xsl:variable name="text">
677    <xsl:apply-templates select="."/>
678  </xsl:variable>
679  <xsl:value-of select="$text"/>
680</xsl:template>
681
682<!-- annotations -->
683<xsl:template match="@x:annotation" mode="cleanup">
684  <xsl:comment>
685    <xsl:value-of select="."/>
686  </xsl:comment>
687  <xsl:call-template name="warning">
688    <xsl:with-param name="inline" select="'no'"/>
689    <xsl:with-param name="msg">Dropping annotation on <xsl:value-of select="local-name(..)"/> element.</xsl:with-param>
690  </xsl:call-template>
691</xsl:template>
692
693<!-- artwork extensions -->
694<xsl:template match="artwork/@x:extraction-note" mode="cleanup"/>
695
696<!-- list formatting -->
697<xsl:template match="list/@x:indent" mode="cleanup"/>
698
699<!-- referencing extensions -->
700<xsl:template match="iref/@x:for-anchor" mode="cleanup"/>
701
702<!-- table styles -->
703<xsl:template match="texttable/@style" mode="cleanup"/>
704
705<!-- section numbering -->
706<xsl:template match="section/@x:fixed-section-number" mode="cleanup"/>
707
708<!-- GRRDL info stripped -->
709<xsl:template match="@grddl:transformation" mode="cleanup"/>
710
711<!-- maturity level stripped -->
712<xsl:template match="@x:maturity-level" mode="cleanup"/>
713
714<!-- normativity stripped -->
715<xsl:template match="@x:nrm" mode="cleanup"/>
716
717<!-- title extensions -->
718<xsl:template match="title/@x:quotes" mode="cleanup"/>
719
720<!-- RDF info stripped -->
721<xsl:template match="rdf:*" mode="cleanup"/>
722
723<!-- cases where xml2rfc does not allow anchors -->
724<xsl:template match="preamble/@anchor" mode="cleanup"/>
725<xsl:template match="spanx/@anchor" mode="cleanup"/>
726
727</xsl:transform>
Note: See TracBrowser for help on using the repository browser.