source: rfc2629xslt/clean-for-DTD.xslt @ 411

Last change on this file since 411 was 329, checked in by julian.reschke@…, 12 years ago

update to latest version of rfc2629.xslt

  • Property svn:eol-style set to native
File size: 19.5 KB
RevLine 
[6]1<!--
2    Strip rfc2629.xslt extensions, generating XML input for MTR's xml2rfc
3
[204]4    Copyright (c) 2006-2008, Julian Reschke (julian.reschke@greenbytes.de)
[6]5    All rights reserved.
6
7    Redistribution and use in source and binary forms, with or without
8    modification, are permitted provided that the following conditions are met:
9
10    * Redistributions of source code must retain the above copyright notice,
11      this list of conditions and the following disclaimer.
12    * Redistributions in binary form must reproduce the above copyright notice,
13      this list of conditions and the following disclaimer in the documentation
14      and/or other materials provided with the distribution.
15    * Neither the name of Julian Reschke nor the names of its contributors
16      may be used to endorse or promote products derived from this software
17      without specific prior written permission.
18
19    THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
20    AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
21    IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
22    ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR CONTRIBUTORS BE
23    LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
24    CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
25    SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
26    INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
27    CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
28    ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
29    POSSIBILITY OF SUCH DAMAGE.
30-->
31
32<xsl:transform xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
33                version="1.0"
34                xmlns:ed="http://greenbytes.de/2002/rfcedit"
35                xmlns:grddl="http://www.w3.org/2003/g/data-view#"
[272]36                xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#"
[6]37                xmlns:x="http://purl.org/net/xml2rfc/ext"
38                xmlns:xhtml="http://www.w3.org/1999/xhtml"
[272]39                exclude-result-prefixes="ed grddl rdf x xhtml"
[6]40>
41
42<!-- re-use some of the default RFC2629.xslt rules -->
43<xsl:import href="rfc2629.xslt"/>
44
45<!-- undo strip-space decls -->
46<xsl:preserve-space elements="*"/>
47
48<!-- generate DTD-valid output, override all values imported from rfc2629.xslt -->
49<xsl:output doctype-system="rfc2629.dtd" doctype-public="" method="xml" version="1.0" encoding="UTF-8" cdata-section-elements="artwork" />
50
51<!-- kick into cleanup mode -->
52<xsl:template match="/">
53  <xsl:text>&#10;</xsl:text>
54  <xsl:comment>
55    This XML document is the output of clean-for-DTD.xslt; a tool that strips
56    extensions to RFC2629(bis) from documents for processing with xml2rfc.
57</xsl:comment>
58  <xsl:apply-templates select="/" mode="cleanup"/>
59</xsl:template>
60
61<!-- rules for identity transformations -->
62
63<xsl:template match="processing-instruction()" mode="cleanup">
64  <xsl:text>&#10;</xsl:text>
[30]65  <xsl:copy/>
[6]66</xsl:template>
67
68<xsl:template match="comment()|@*" mode="cleanup"><xsl:copy/></xsl:template>
69
70<xsl:template match="text()" mode="cleanup"><xsl:copy/></xsl:template>
71
72<xsl:template match="/" mode="cleanup">
73        <xsl:copy><xsl:apply-templates select="node()" mode="cleanup" /></xsl:copy>
74</xsl:template>
75
76<xsl:template match="*" mode="cleanup">
77  <xsl:element name="{local-name()}">
78        <xsl:apply-templates select="node()|@*" mode="cleanup" />
79  </xsl:element>
80</xsl:template>
81
82
83<!-- remove PI extensions -->
84
85<xsl:template match="processing-instruction('rfc-ext')" mode="cleanup"/>
86
87<!-- add issues appendix -->
88
89<xsl:template match="back" mode="cleanup">
90  <back>
91    <xsl:apply-templates select="node()|@*" mode="cleanup" />
92    <xsl:if test="not(/*/@ed:suppress-issue-appendix='yes') and //ed:issue[@status='closed']">
93      <section title="Resolved issues (to be removed by RFC Editor before publication)">
94        <t>
95          Issues that were either rejected or resolved in this version of this
96          document.
97        </t>
98        <xsl:apply-templates select="//ed:issue[@status='closed']" mode="issues" />
99      </section>
100    </xsl:if>
101    <xsl:if test="not(/*/@ed:suppress-issue-appendix='yes') and //ed:issue[@status='open']">
102      <section title="Open issues (to be removed by RFC Editor prior to publication)">
103        <xsl:apply-templates select="//ed:issue[@status!='closed']" mode="issues" />
104      </section>
105    </xsl:if>
106  </back>
107</xsl:template>
108
109
110
111
112<!-- extensions -->
113
[272]114<xsl:template match="x:abnf-char-sequence" mode="cleanup">
115  <xsl:choose>
116    <xsl:when test="substring(.,1,1) != '&quot;' or substring(.,string-length(.),1) != '&quot;'">
117      <xsl:call-template name="error">
118        <xsl:with-param name="msg" select="'contents of x:abnf-char-sequence needs to be quoted.'" />
119      </xsl:call-template>
120    </xsl:when>
121    <xsl:otherwise>
122      <xsl:text>%x</xsl:text>
123      <xsl:call-template name="to-abnf-char-sequence">
124        <xsl:with-param name="chars" select="substring(.,2,string-length(.)-2)"/>
125      </xsl:call-template>
126    </xsl:otherwise>
127  </xsl:choose>
128</xsl:template>
129
[6]130<xsl:template match="x:anchor-alias" mode="cleanup"/>
131
132<xsl:template match="x:bcp14" mode="cleanup">
133  <xsl:apply-templates/>
134</xsl:template>
135
136<xsl:template match="x:assign-section-number" mode="cleanup"/> 
137<xsl:template match="x:link" mode="cleanup"/>
138<xsl:template match="x:source" mode="cleanup"/>
139
[285]140<xsl:template match="x:parse-xml" mode="cleanup">
141  <xsl:apply-templates/>
142</xsl:template>
143
[6]144<xsl:template match="x:ref" mode="cleanup">
145  <xsl:variable name="val" select="."/>
146  <xsl:variable name="target" select="//*[@anchor and (@anchor=$val or x:anchor-alias/@value=$val)]"/>
147  <xsl:choose>
148    <xsl:when test="$target">
149      <xsl:variable name="current" select="."/>
150      <xsl:for-each select="$target">
151        <!-- make it the context -->
152        <xsl:choose>
153          <xsl:when test="self::preamble">
154            <!-- it's not an element we can link to -->
155            <xsl:comment>clean-for-DTD.xslt warning: couldn't create the link as <xsl:value-of select="name()"/> does not support the anchor attribute.</xsl:comment>
156            <xsl:value-of select="$current"/>
157          </xsl:when>
158          <xsl:otherwise>
159            <xref target="{$target/@anchor}" format="none"><xsl:value-of select="$current"/></xref>
160          </xsl:otherwise>
161        </xsl:choose>
162      </xsl:for-each>
163    </xsl:when>
164    <xsl:otherwise>
165      <xsl:message>WARNING: internal link target for '<xsl:value-of select="."/>' does not exist.</xsl:message>
166      <xsl:value-of select="."/>
167    </xsl:otherwise>
168  </xsl:choose>
169</xsl:template>
170
171<xsl:template match="x:blockquote" mode="cleanup">
172  <t><list>
173    <xsl:apply-templates mode="cleanup" />
174  </list></t>
175</xsl:template>
176
177<xsl:template match="x:h" mode="cleanup">
178  <xsl:apply-templates mode="cleanup" />
179</xsl:template>
180
[329]181<xsl:template match="x:highlight" mode="cleanup">
182  <xsl:apply-templates mode="cleanup" />
183</xsl:template>
184
[6]185<xsl:template match="x:lt" mode="cleanup">
186  <t>
187    <xsl:apply-templates select="@hangText|@anchor" mode="cleanup"/>
188    <xsl:for-each select="t">
189      <xsl:apply-templates mode="cleanup"/>
190      <xsl:if test="position()!=last()">
191        <vspace blankLines="1"/>
192      </xsl:if>
193    </xsl:for-each>
194  </t>
195</xsl:template>
196
[329]197<xsl:template match="x:note" mode="cleanup">
198  <t>
199    <list>
200      <xsl:apply-templates mode="cleanup"/>
201    </list>
202  </t>
203</xsl:template>
204
[6]205<xsl:template match="x:q" mode="cleanup">
206  <xsl:text>"</xsl:text>
207  <xsl:apply-templates mode="cleanup"/>
208  <xsl:text>"</xsl:text>
209</xsl:template>
210
211<xsl:template match="x:dfn" mode="cleanup">
212  <xsl:apply-templates mode="cleanup"/>
213</xsl:template>
214
[246]215<xsl:template match="x:sup" mode="cleanup">
216  <xsl:text>^</xsl:text>
217  <xsl:apply-templates mode="cleanup" />
218</xsl:template>
219
[329]220<xsl:template match="author/@anchor" mode="cleanup"/>
221<xsl:template match="x:include-author" mode="cleanup">
222  <t>
223    <xsl:value-of select="/*/front/author[@anchor=current()/@target]"/>
224  </t>
225  <t>
226    (see Authors Section)
227  </t>
228</xsl:template>
229
[6]230<!-- extended reference formatting -->
231
232<xsl:template match="xref[@x:* and not(node())]" mode="cleanup">
233  <xsl:variable name="node" select="$src//*[@anchor=current()/@target]" />
[32]234
[6]235  <xsl:variable name="sec">
236    <xsl:choose>
237      <xsl:when test="starts-with(@x:rel,'#') and not(@x:sec) and $node/x:source/@href">
238        <xsl:variable name="extdoc" select="document($node/x:source/@href)"/>
239        <xsl:for-each select="$extdoc//*[@anchor=substring-after(current()/@x:rel,'#')]">
240          <xsl:call-template name="get-section-number"/>
241        </xsl:for-each>
242      </xsl:when>
243      <xsl:otherwise>
244        <xsl:value-of select="@x:sec"/>
245      </xsl:otherwise>
246    </xsl:choose>
247  </xsl:variable>
248
[32]249  <xsl:variable name="secterm">
250    <xsl:choose>
251      <!-- starts with letter? -->
252      <xsl:when test="translate(substring($sec,1,1),$ucase,'')=''">Appendix</xsl:when>
253      <xsl:otherwise>Section</xsl:otherwise>
254    </xsl:choose>
255  </xsl:variable>
256
[6]257  <xsl:variable name="fmt">
258    <xsl:choose>
259      <xsl:when test="@x:fmt!=''"><xsl:value-of select="@x:fmt"/></xsl:when>
260      <xsl:when test="ancestor::artwork">,</xsl:when>
261      <xsl:otherwise>of</xsl:otherwise>
262    </xsl:choose>
263  </xsl:variable>
264
265  <xsl:choose>
266    <xsl:when test="$fmt=','">
267      <xref>
268        <xsl:apply-templates select="@target|@format|@pageno|text()|*" mode="cleanup"/>
269      </xref>
[32]270      <xsl:text>, </xsl:text>
271      <xsl:value-of select="$secterm"/>
272      <xsl:text> </xsl:text>
[6]273      <xsl:value-of select="$sec"/>
274    </xsl:when>
275    <xsl:when test="$fmt='sec'">
[32]276      <xsl:value-of select="$secterm"/>
277      <xsl:text> </xsl:text>
[6]278      <xsl:value-of select="$sec"/>
279    </xsl:when>
280    <xsl:when test="$fmt='number'">
281      <xsl:value-of select="$sec"/>
282    </xsl:when>
283    <xsl:when test="$fmt='()'">
284      <xref>
285        <xsl:apply-templates select="@target|@format|@pageno|text()|*" mode="cleanup"/>
286      </xref>
[32]287      <xsl:text> (</xsl:text>
288      <xsl:value-of select="$secterm"/>
289      <xsl:text> </xsl:text>
[6]290      <xsl:value-of select="$sec"/>
291      <xsl:text>)</xsl:text>
292    </xsl:when>
293    <xsl:when test="$fmt='of'">
[32]294      <xsl:value-of select="$secterm"/>
295      <xsl:text> </xsl:text>
[6]296      <xsl:value-of select="$sec"/>
297      <xsl:text> of </xsl:text>
298      <xref>
299        <xsl:apply-templates select="@target|@format|@pageno|text()|*" mode="cleanup"/>
300      </xref>
301    </xsl:when>
302    <xsl:when test="$fmt='anchor'">
303      <xsl:variable name="val">
304        <xsl:call-template name="referencename">
305          <xsl:with-param name="node" select="$node" />
306        </xsl:call-template>
307      </xsl:variable>
308      <!-- remove brackets -->
309      <xsl:value-of select="substring($val,2,string-length($val)-2)"/>
310    </xsl:when>
311    <xsl:otherwise>
312      <xsl:copy>
313        <xsl:apply-templates select="node()" mode="cleanup"/>
314      </xsl:copy>
315    </xsl:otherwise>
316  </xsl:choose>
317</xsl:template>
318
319<xsl:template match="xref[@x:fmt and node()]" mode="cleanup">
320  <xsl:choose>
321    <xsl:when test="@x:fmt='none'">
322      <xsl:apply-templates mode="cleanup"/>
323    </xsl:when>
324    <xsl:when test="not(@x:fmt)">
325      <xref>
326        <xsl:copy-of select="@target|@format"/>
327        <xsl:apply-templates mode="cleanup"/>
328      </xref>
329    </xsl:when>
330    <xsl:otherwise>
331      <xsl:message>Unsupported x:fmt attribute.</xsl:message>
332    </xsl:otherwise>
333  </xsl:choose>
334</xsl:template>
335
336<xsl:template match="xref[node() and @target=//preamble/@anchor]" mode="cleanup">
337  <!-- remove the link -->
338  <xsl:apply-templates select="node()" mode="cleanup"/>
339</xsl:template>
340
341<xsl:template match="xref[not(node()) and @target=//preamble/@anchor]" mode="cleanup">
342  <!-- fatal -->
343  <xsl:message>Broken xref due to target being filtered out.</xsl:message>
344</xsl:template>
345
346<!-- issue tracking extensions -->
347
348<xsl:template match="@xml:lang" mode="cleanup"/>
349<xsl:template match="@xml:lang" />
350
351<xsl:template match="ed:*" mode="cleanup"/>
352<xsl:template match="ed:*" />
353
354<xsl:template match="@ed:*" mode="cleanup"/>
355<xsl:template match="@ed:*" />
356
357<xsl:template match="ed:annotation" mode="cleanup" />
358
359<xsl:template match="ed:replace" mode="cleanup">
360  <xsl:apply-templates mode="cleanup" />
361</xsl:template>
362
363<xsl:template match="ed:replace">
364  <xsl:apply-templates/>
365</xsl:template>
366
367<xsl:template match="ed:ins" mode="cleanup">
368  <xsl:apply-templates mode="cleanup"/>
369</xsl:template>
370
371<xsl:template match="ed:ins">
372  <xsl:apply-templates/>
373</xsl:template>
374
375<xsl:template match="ed:issue" mode="issues">
376  <section title="{@name}">
377    <xsl:variable name="sec">
378      <xsl:call-template name="get-section-number"/>
379    </xsl:variable>
380
381    <xsl:if test="$sec!=''">
382      <t>
383        In Section <xsl:value-of select="$sec"/>:
384      </t>
385    </xsl:if>
386   
387    <t>
388      Type: <xsl:value-of select="@type" />
389    </t>
390    <xsl:if test="@href">
391      <t>
392        <!-- temp. removed because of xml2rfc's handling of erefs when producing TXT-->
393        <!--<eref target="{@href}" /> -->
394        <xsl:text>&lt;</xsl:text>
395        <xsl:value-of select="@href"/>
396        <xsl:text>></xsl:text>
397        <xsl:if test="@alternate-href">
398          <xsl:text>, &lt;</xsl:text>
399          <xsl:value-of select="@alternate-href"/>
400          <xsl:text>></xsl:text>
401        </xsl:if>
402      </t>
403    </xsl:if>
404    <xsl:for-each select="ed:item">
405      <t>
406        <xsl:if test="@entered-by or @date">
407          <xsl:choose>
408            <xsl:when test="not(@entered-by)">
409              <xsl:value-of select="concat('(',@date,') ')" />
410            </xsl:when>
411            <xsl:when test="not(@date)">
412              <xsl:value-of select="concat(@entered-by,': ')" />
413            </xsl:when>
414            <xsl:otherwise>
415              <xsl:value-of select="concat(@entered-by,' (',@date,'): ')" />
416            </xsl:otherwise>
417          </xsl:choose>     
418        </xsl:if>
419        <xsl:if test="not(xhtml:p)">
420          <xsl:apply-templates select="node()" mode="issues"/>
421        </xsl:if>
422      </t>
423      <xsl:if test="xhtml:p|xhtml:pre">
424        <xsl:for-each select="node()">
425          <xsl:choose>
426            <xsl:when test="self::xhtml:p">
427              <t>
428                <xsl:apply-templates select="node()" mode="issues"/>
429              </t>
430            </xsl:when>
431            <xsl:when test="self::xhtml:pre">
432              <figure>
433                <artwork><xsl:apply-templates select="node()" mode="issues"/></artwork>
434              </figure>
435            </xsl:when>
436            <xsl:otherwise>
437              <t>
438                <xsl:apply-templates select="." mode="issues"/>
439              </t>
440            </xsl:otherwise>
441          </xsl:choose>
442        </xsl:for-each>
443      </xsl:if>
444    </xsl:for-each>
445    <xsl:if test="ed:resolution">
446      <t>
447        <xsl:text>Resolution</xsl:text>
448        <xsl:if test="ed:resolution/@datetime"> (<xsl:value-of select="ed:resolution/@datetime"/>)</xsl:if>
449        <xsl:text>: </xsl:text>
450        <xsl:value-of select="ed:resolution" />
451      </t>
452    </xsl:if>
453  </section>
454</xsl:template>
455
456<xsl:template match="ed:issueref" mode="cleanup">
457  <xsl:apply-templates mode="cleanup"/>
458</xsl:template>
459
460<xsl:template match="*" mode="issues">
461  <xsl:apply-templates mode="issues"/>
462</xsl:template>
463
464<xsl:template match="xhtml:q" mode="issues">
465  <list><t>
466    <xsl:text>"</xsl:text>
467    <xsl:apply-templates mode="issues"/>
468    <xsl:text>"</xsl:text>
469    <xsl:if test="@cite">
470      <xsl:text> -- </xsl:text>
471      <eref target="{@cite}"><xsl:value-of select="@cite"/></eref>
472    </xsl:if>
473  </t></list>
474</xsl:template>
475
476<xsl:template match="xhtml:br" mode="issues">
477  <vspace/>
478</xsl:template>
479
480<xsl:template match="xhtml:del" mode="issues">
481  <xsl:text>&lt;del></xsl:text>
482    <xsl:apply-templates mode="issues"/>
483  <xsl:text>&lt;/del></xsl:text>
484</xsl:template>
485
486<xsl:template match="xhtml:em" mode="issues">
487  <spanx style="emph">
488    <xsl:apply-templates mode="issues"/>
489  </spanx>
490</xsl:template>
491
492<xsl:template match="xhtml:ins" mode="issues">
493  <xsl:text>&lt;ins></xsl:text>
494    <xsl:apply-templates mode="issues"/>
495  <xsl:text>&lt;/ins></xsl:text>
496</xsl:template>
497
498<xsl:template match="xhtml:tt" mode="issues">
499  <xsl:apply-templates mode="issues"/>
500</xsl:template>
501
502<xsl:template match="ed:eref" mode="issues">
503  <xsl:text>&lt;</xsl:text>
504  <xsl:value-of select="."/>
505  <xsl:text>&gt;</xsl:text>
506</xsl:template>
507
508<xsl:template match="ed:issueref" mode="issues">
509  <xsl:apply-templates mode="issues"/>
510</xsl:template>
511
512<xsl:template match="text()" mode="issues">
513  <xsl:value-of select="." />
514</xsl:template>
515
516
517
518<!-- markup inside artwork element -->
519
520<xsl:template match="figure[.//artwork//iref]" mode="cleanup">
521  <!-- move up iref elements -->
522  <figure>
523    <xsl:apply-templates select="@*" mode="cleanup" />
524    <xsl:apply-templates select=".//artwork//iref" mode="cleanup"/>
525    <xsl:apply-templates select="iref|preamble|artwork|postamble" mode="cleanup" />
526  </figure>
527</xsl:template>
528
529<xsl:template match="artwork" mode="cleanup">
[329]530  <xsl:variable name="content2"><xsl:apply-templates select="."/></xsl:variable>
531  <xsl:variable name="content" select="translate($content2,'&#160;&#x2500;&#x2502;&#x2508;&#x250c;&#x2510;&#x2514;&#x2518;&#x251c;&#x2524;',' -|+++++++')"/>
[6]532  <artwork>
533    <xsl:apply-templates select="@*" mode="cleanup" />
534    <xsl:if test="starts-with(.,'&#10;')">
535      <xsl:text>&#10;</xsl:text>
[329]536      <xsl:value-of select="@x:indent-with"/>
[6]537    </xsl:if>
[329]538    <xsl:choose>
539      <xsl:when test="@x:indent-with!=''">
540        <xsl:call-template name="indent">
541          <xsl:with-param name="content" select="$content"/>
542          <xsl:with-param name="with" select="@x:indent-with"/>
543        </xsl:call-template>
544      </xsl:when>
545      <xsl:otherwise>
546        <xsl:value-of select="$content"/>
547      </xsl:otherwise>
548    </xsl:choose>
[6]549  </artwork> 
550</xsl:template>
551
[329]552<xsl:template match="@x:indent-with" mode="cleanup"/>
553
554<xsl:template name="indent">
555  <xsl:param name="content"/>
556  <xsl:param name="with"/>
557
558  <xsl:value-of select="substring($content,1,1)"/>
559  <xsl:if test="substring($content,1,1)='&#10;'">
560    <xsl:value-of select="$with"/>
561  </xsl:if>
562 
563  <xsl:choose>
564    <xsl:when test="$content=''" />
565    <xsl:otherwise>
566      <xsl:call-template name="indent">
567        <xsl:with-param name="content" select="substring($content,2)"/>
568        <xsl:with-param name="with" select="$with"/>
569      </xsl:call-template>
570    </xsl:otherwise>
571  </xsl:choose>
572 
573</xsl:template>
574
[272]575<!-- email repititions -->
576<xsl:template match="email" mode="cleanup">
577  <!-- combine in a single element -->
578  <xsl:if test="not(preceding-sibling::email)">
579    <email>
580      <xsl:for-each select="../email">
581        <xsl:value-of select="."/>
582        <xsl:if test="position()!=last()">
583          <xsl:text>, </xsl:text>
584        </xsl:if>
585      </xsl:for-each>
586    </email>
587  </xsl:if>
588</xsl:template>
589
[204]590<!-- markup inside cref -->
591<xsl:template match="cref//eref" mode="cleanup">
592  <xsl:text>&lt;</xsl:text>
593  <xsl:value-of select="@target"/>
594  <xsl:text>&gt;</xsl:text>
595</xsl:template>
[6]596
597<!-- artwork extensions -->
598<xsl:template match="artwork/@x:extraction-note" mode="cleanup"/>
599
600<!-- list formatting -->
601<xsl:template match="list/@x:indent" mode="cleanup"/>
602
603<!-- referencing extensions -->
604<xsl:template match="iref/@x:for-anchor" mode="cleanup"/>
605
606<!-- table styles -->
607<xsl:template match="texttable/@style" mode="cleanup"/>
608
609<!-- anchor extensions -->
610<xsl:template match="preamble/@anchor" mode="cleanup"/>
611
612<!-- section numbering -->
613<xsl:template match="section/@x:fixed-section-number" mode="cleanup"/>
614
615<!-- GRRDL info stripped -->
616<xsl:template match="@grddl:transformation" mode="cleanup"/>
617
[308]618<!-- maturity level stripped -->
619<xsl:template match="@x:maturity-level" mode="cleanup"/>
620
[272]621<!-- RDF info stripped -->
622<xsl:template match="rdf:*" mode="cleanup"/>
623
[6]624</xsl:transform>
Note: See TracBrowser for help on using the repository browser.