source: draft-ietf-httpbis/latest/abnf2xml2rfc.xslt @ 1777

Last change on this file since 1777 was 1777, checked in by julian.reschke@…, 7 years ago

fix ABNF-to-appendix script to properly handle the preamble again

File size: 5.4 KB
Line 
1<xsl:transform
2  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
3  xmlns:xs="http://www.w3.org/2001/XMLSchema"
4  xmlns:x="http://purl.org/net/xml2rfc/ext"
5  version="2.0"
6  exclude-result-prefixes="xs">
7
8<xsl:output method="xml" omit-xml-declaration="yes" indent="no"/>
9
10<xsl:param name="abnf"/> 
11 
12<xsl:template match="/">
13  <xsl:variable name="src" select="."/>
14  <xsl:variable name="collected" select="unparsed-text($abnf)"/>
15
16  <xsl:variable name="all-lines" as="xs:string*" select="tokenize($collected, '\r?\n')"/>
17  <xsl:variable name="lines" select="$all-lines[normalize-space(.)!='']"/>
18 
19  <xsl:variable name="generated"><section title="Collected ABNF" anchor="collected.abnf">
20    <xsl:text>&#10;</xsl:text>
21    <figure>
22      <xsl:text>&#10;</xsl:text>
23      <artwork type="abnf" name="{$abnf}">
24        <xsl:for-each select="$lines[substring(.,1,2)!='; ']">
25       
26          <!-- Group by start character -->
27          <xsl:variable name="lineno" select="position()"/>
28          <xsl:variable name="sc1" select="substring(.,1,1)"/>
29          <xsl:variable name="sc0" select="x:laststartchar($lines, $lineno - 1)"/>
30          <xsl:if test="$sc1!=' ' and $sc0!=' ' and $sc1!=$sc0">
31            <xsl:text>&#10;</xsl:text>
32          </xsl:if>
33
34          <!-- Add cross-refs for terms -->
35          <xsl:analyze-string select="." regex='^([A-Za-z0-9\-]+) = ' flags="sm">
36            <xsl:matching-substring>
37              <xsl:variable name="term" select="regex-group(1)"/>
38              <xsl:choose>
39                <xsl:when test="$src//*[@anchor=$term] or $src//x:anchor-alias[@value=$term]">
40                  <x:ref><xsl:value-of select="$term"/></x:ref>
41                </xsl:when>
42                <xsl:otherwise>
43                  <xsl:value-of select="$term"/>
44                </xsl:otherwise>
45              </xsl:choose>
46              <xsl:text> = </xsl:text>
47            </xsl:matching-substring>
48            <xsl:non-matching-substring>
49              <xsl:value-of select="."/>
50            </xsl:non-matching-substring>
51          </xsl:analyze-string>
52
53          <xsl:text>&#10;</xsl:text>
54        </xsl:for-each>
55      </artwork>
56      <xsl:text>&#10;</xsl:text>
57    </figure> 
58    <xsl:text>&#10;</xsl:text>
59   
60    <xsl:variable name="diags">
61      <xsl:for-each select="$lines[substring(.,1,2)='; ']">
62        <xsl:variable name="prod" select="substring-before(substring-after(.,'; '),' defined but not used')"/>
63        <xsl:choose>
64          <xsl:when test="$prod!='' and $src//iref[@item='Header Fields' and @subitem=$prod]">
65            <!-- header field; expected not to be reference -->
66          </xsl:when>
67          <xsl:otherwise>
68            <xsl:value-of select="."/>
69            <xsl:text>&#10;</xsl:text>
70          </xsl:otherwise>
71        </xsl:choose>
72      </xsl:for-each>
73    </xsl:variable>
74   
75    <xsl:if test="$diags!=''">
76      <figure>
77        <preamble>ABNF diagnostics:</preamble>
78        <artwork type="inline">
79          <xsl:text>&#10;</xsl:text>
80          <xsl:value-of select="$diags"/>
81      </artwork></figure>
82    </xsl:if>
83  </section></xsl:variable>
84
85  <xsl:copy-of select="$generated"/>
86
87  <!-- check whether it's up-to-date... -->
88  <xsl:variable name="src">
89    <xsl:for-each select="//section[@anchor='collected.abnf']//artwork">
90      <xsl:value-of select="."/>
91    </xsl:for-each>
92  </xsl:variable>
93 
94  <xsl:variable name="new">
95    <xsl:value-of select="$generated//artwork"/>
96  </xsl:variable>
97 
98  <xsl:if test="not(//section[@anchor='collected.abnf']) or normalize-space($src) != normalize-space($new)">
99    <xsl:message>WARNING: appendix contained inside source document needs to be updated</xsl:message>
100    <xsl:call-template name="showdiff">
101      <xsl:with-param name="actual" select="normalize-space($src)"/>
102      <xsl:with-param name="expected" select="normalize-space($new)"/>
103    </xsl:call-template>
104  </xsl:if>
105</xsl:template>
106
107<xsl:template name="showdiff">
108  <xsl:param name="actual"/>
109  <xsl:param name="expected"/>
110  <xsl:param name="prev"/>
111 
112  <xsl:choose>
113    <xsl:when test="$actual=''">
114      <!-- done -->
115    </xsl:when>
116    <xsl:when test="substring($actual,1,1)=substring($expected,1,1)">
117      <xsl:call-template name="showdiff">
118        <xsl:with-param name="actual" select="substring($actual,2)"/>
119        <xsl:with-param name="expected" select="substring($expected,2)"/>
120        <xsl:with-param name="prev" select="concat($prev,substring($actual,1,1))"/>
121      </xsl:call-template>
122    </xsl:when>
123    <xsl:otherwise>
124      <xsl:message>WARNING: at position <xsl:value-of select="string-length($prev)"/></xsl:message>
125      <xsl:message>WARNING: prefix <xsl:value-of select="$prev"/></xsl:message>
126      <xsl:message>WARNING: actual text is: '<xsl:value-of select="substring($actual,1,20)"/>...' expected was: '<xsl:value-of select="substring($expected,1,20)"/>...'</xsl:message>
127    </xsl:otherwise>
128  </xsl:choose>
129</xsl:template>
130
131<xsl:function name="x:laststartchar">
132  <xsl:param name="lines"/>
133  <xsl:param name="position"/>
134 
135  <xsl:choose>
136    <xsl:when test="' '!=substring($lines[$position],1,1)">
137      <xsl:value-of select="substring($lines[$position],1,1)"/>
138    </xsl:when>
139    <xsl:otherwise>
140      <xsl:value-of select="x:laststartchar($lines, $position - 1)"/>
141    </xsl:otherwise>
142  </xsl:choose>
143</xsl:function>
144 
145 
146</xsl:transform>
Note: See TracBrowser for help on using the repository browser.